963110_zh-TW

liliconcom

直方圖上的特定參考線

早安,

在使用列選擇器時，如何為分佈平台的直方圖新增參考線（均值線）？我希望為 10 個變數中的每一個都添加這條線，顯然不想手動添加。

先感謝您。

讓-呂克

基礎資料分析與建模數據探索與視覺化回覆：直方圖上的具體參考線

你的選擇不多：

• 將規格限值列屬性的目標值設為平均值，並在圖表中啟用這些值。您需要預先計算這些值並將其設為列屬性，但“匯總”+“管理規格限值”功能應該可以完成此操作。
• JSL：使用列切換處理程序，程式會在列變更時更新參考行。
• JSL：建立能夠更新參考線的圖形腳本
• 使用其他平台，例如 Graph Builder，您可以輕鬆地將線條新增為單獨的元素。

回覆：直方圖上的具體參考線

以下是一些 JSL 選項的範例（實作這些選項的方法有很多種）：

圖形腳本選項範例：

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

dist = dt << Distribution(
	Continuous Distribution(
		Column(:height),
		Always use column properties(1),
		Process Capability(0)
	),
	Column Switcher(:height, {:height, :weight})
);


Report(dist)[FrameBox(1)] << Add Graphics Script(Function({this},
	m = ((this << Top Parent)[OutlineBox("Summary Statistics"), Number Col Box(1)] << get)[1];
	Pen Color("Purple");
	Pen Size(5);
	H Line(m);
));

列切換處理程序範例：

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

dist = dt << Distribution(
	Continuous Distribution(
		Column(:height),
		Always use column properties(1),
		Process Capability(0)
	)
);

cw = dist << Column Switcher(:height, {:height, :weight});
post = Function({previousColumn, currentColumn, switcher},
	prevm = Col Mean(previousColumn);
	m = Col Mean(currentColumn);
	axisbox = Report(dist)[axis box(1)];
	Try(axisbox << Remove Ref Line(prevm));
	axisbox << Add Ref Line(m, "Dashed", blue, "Mean", 2);
	wait(0);
);
handler = cw << Make Column Switch Handler(Empty(), post);