963110_es-ES

liliconcom

Una línea de referencia específica en un histograma

Buen día,

¿Cómo puedo añadir una línea de referencia (la línea de la media) al histograma de la plataforma de distribución al usar un selector de columnas? Quiero esta línea para cada una de las 10 variables, obviamente sin tener que añadirla manualmente.

Gracias de antemano.

Juan-Luc

Análisis y modelado de datos básicosExploración y visualización de datosRe: Línea de referencia específica en un histograma

Tienes pocas opciones:

• Establezca el objetivo de la propiedad de columna del límite de especificación como la media y habilítelos en los gráficos. Deberá calcularlos previamente y establecerlos en las propiedades de columna, pero la opción Resumen + administrar límites de especificación debería poder hacerlo.
• JSL: utilice un controlador de cambio de columna que actualice las líneas de referencia a medida que cambian las columnas.
• JSL: Crea un script gráfico capaz de actualizar la línea de referencia.
• Utilice plataformas diferentes como Graph Builder, en las que puede agregar fácilmente la línea como un elemento separado.

Re: Línea de referencia específica en un histograma

A continuación se muestran algunos ejemplos de las opciones de JSL (hay muchas maneras diferentes de hacerlo):

Ejemplo de la opción de script gráfico:

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

dist = dt << Distribution(
	Continuous Distribution(
		Column(:height),
		Always use column properties(1),
		Process Capability(0)
	),
	Column Switcher(:height, {:height, :weight})
);


Report(dist)[FrameBox(1)] << Add Graphics Script(Function({this},
	m = ((this << Top Parent)[OutlineBox("Summary Statistics"), Number Col Box(1)] << get)[1];
	Pen Color("Purple");
	Pen Size(5);
	H Line(m);
));

Ejemplo para el controlador de cambio de columna:

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

dist = dt << Distribution(
	Continuous Distribution(
		Column(:height),
		Always use column properties(1),
		Process Capability(0)
	)
);

cw = dist << Column Switcher(:height, {:height, :weight});
post = Function({previousColumn, currentColumn, switcher},
	prevm = Col Mean(previousColumn);
	m = Col Mean(currentColumn);
	axisbox = Report(dist)[axis box(1)];
	Try(axisbox << Remove Ref Line(prevm));
	axisbox << Add Ref Line(m, "Dashed", blue, "Mean", 2);
	wait(0);
);
handler = cw << Make Column Switch Handler(Empty(), post);