963110_zh-CN

liliconcom

直方图上的特定参考线

早上好，

在使用列选择器时，如何向分布平台的直方图添加参考线（均值线）？我希望为 10 个变量中的每一个都添加这条线，显然不想手动添加。

先感谢您。

让-吕克

基础数据分析与建模数据探索与可视化回复：直方图上的具体参考线

你的选择不多：

• 将规格限值列属性的目标值设置为均值，并在图表中启用这些值。您需要预先计算这些值并将其设置为列属性，但“汇总”+“管理规格限值”功能应该可以完成此操作。
• JSL：使用列切换处理程序，该程序会在列更改时更新引用行。
• JSL：创建能够更新参考线的图形脚本
• 使用其他平台，例如 Graph Builder，您可以轻松地将线条添加为单独的元素。

回复：直方图上的具体参考线

以下是一些 JSL 选项的示例（实现这些选项的方法有很多种）：

图形脚本选项示例：

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

dist = dt << Distribution(
	Continuous Distribution(
		Column(:height),
		Always use column properties(1),
		Process Capability(0)
	),
	Column Switcher(:height, {:height, :weight})
);


Report(dist)[FrameBox(1)] << Add Graphics Script(Function({this},
	m = ((this << Top Parent)[OutlineBox("Summary Statistics"), Number Col Box(1)] << get)[1];
	Pen Color("Purple");
	Pen Size(5);
	H Line(m);
));

列切换处理程序示例：

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

dist = dt << Distribution(
	Continuous Distribution(
		Column(:height),
		Always use column properties(1),
		Process Capability(0)
	)
);

cw = dist << Column Switcher(:height, {:height, :weight});
post = Function({previousColumn, currentColumn, switcher},
	prevm = Col Mean(previousColumn);
	m = Col Mean(currentColumn);
	axisbox = Report(dist)[axis box(1)];
	Try(axisbox << Remove Ref Line(prevm));
	axisbox << Add Ref Line(m, "Dashed", blue, "Mean", 2);
	wait(0);
);
handler = cw << Make Column Switch Handler(Empty(), post);