963110_ko-KR

liliconcom

히스토그램의 특정 기준선

좋은 아침이에요,

열 선택기를 사용할 때 분포 플랫폼의 히스토그램에 기준선(평균선)을 추가하려면 어떻게 해야 하나요? 10개 변수 각각에 대해 이 선을 추가하고 싶은데, 당연히 수동으로 추가하는 것은 피하고 싶습니다.

미리 감사드립니다.

장 뤽

기초 데이터 분석 및 모델링데이터 탐색 및 시각화제목: 히스토그램의 특정 참조선 관련

선택지는 몇 가지밖에 없습니다.

• 사양 한계 열 속성의 목표값을 평균으로 설정하고 그래프에 해당 값을 표시하도록 설정하세요. 이 값들은 미리 계산하여 열 속성에 설정해야 하지만, 요약 메뉴에서 사양 한계를 관리하면 이 작업을 수행할 수 있습니다.
• JSL: 열 변경 시 참조 행을 업데이트하는 열 전환 핸들러를 사용합니다.
• JSL: 참조선을 업데이트할 수 있는 그래픽 스크립트를 생성합니다.
• 그래프 빌더와 같은 다른 플랫폼을 사용하면 선을 별도의 요소로 쉽게 추가할 수 있습니다.

제목: 히스토그램의 특정 참조선 관련

다음은 JSL 옵션의 몇 가지 예입니다(이러한 옵션을 사용하는 방법은 매우 다양합니다).

그래픽 스크립트 옵션의 예시:

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

dist = dt << Distribution(
	Continuous Distribution(
		Column(:height),
		Always use column properties(1),
		Process Capability(0)
	),
	Column Switcher(:height, {:height, :weight})
);


Report(dist)[FrameBox(1)] << Add Graphics Script(Function({this},
	m = ((this << Top Parent)[OutlineBox("Summary Statistics"), Number Col Box(1)] << get)[1];
	Pen Color("Purple");
	Pen Size(5);
	H Line(m);
));

컬럼 전환 핸들러의 예시:

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

dist = dt << Distribution(
	Continuous Distribution(
		Column(:height),
		Always use column properties(1),
		Process Capability(0)
	)
);

cw = dist << Column Switcher(:height, {:height, :weight});
post = Function({previousColumn, currentColumn, switcher},
	prevm = Col Mean(previousColumn);
	m = Col Mean(currentColumn);
	axisbox = Report(dist)[axis box(1)];
	Try(axisbox << Remove Ref Line(prevm));
	axisbox << Add Ref Line(m, "Dashed", blue, "Mean", 2);
	wait(0);
);
handler = cw << Make Column Switch Handler(Empty(), post);