963110_it-IT

liliconcom

Una linea di riferimento specifica su un istogramma

Buongiorno,

Come faccio ad aggiungere una linea di riferimento (la linea della media) all'istogramma della piattaforma di distribuzione quando utilizzo un selettore di colonne? Vorrei questa linea per ciascuna delle 10 variabili, ovviamente senza doverla aggiungere manualmente.

Grazie in anticipo.

Jean-Luc

Analisi e modellazione di base dei datiEsplorazione e visualizzazione dei datiOggetto: Linea di riferimento specifica su un istogramma

Hai poche opzioni:

• Imposta la proprietà della colonna "Target del limite di specifica" come media e abilitala nei grafici. Dovrai calcolarli in anticipo e impostarli nelle proprietà della colonna, ma la funzione "Riepilogo + Gestione limiti di specifica" dovrebbe essere in grado di farlo.
• JSL: utilizzare Column Switch Handler che aggiorna le righe di riferimento al variare della colonna
• JSL: Crea uno script grafico in grado di aggiornare la linea di riferimento
• Utilizza piattaforme diverse come Graph Builder, in cui puoi aggiungere facilmente la linea come elemento separato

Oggetto: Linea di riferimento specifica su un istogramma

Di seguito sono riportati alcuni esempi delle opzioni JSL (esistono molti modi diversi per farlo):

Esempio per l'opzione di script grafico:

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

dist = dt << Distribution(
	Continuous Distribution(
		Column(:height),
		Always use column properties(1),
		Process Capability(0)
	),
	Column Switcher(:height, {:height, :weight})
);


Report(dist)[FrameBox(1)] << Add Graphics Script(Function({this},
	m = ((this << Top Parent)[OutlineBox("Summary Statistics"), Number Col Box(1)] << get)[1];
	Pen Color("Purple");
	Pen Size(5);
	H Line(m);
));

Esempio per il gestore del cambio di colonna:

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

dist = dt << Distribution(
	Continuous Distribution(
		Column(:height),
		Always use column properties(1),
		Process Capability(0)
	)
);

cw = dist << Column Switcher(:height, {:height, :weight});
post = Function({previousColumn, currentColumn, switcher},
	prevm = Col Mean(previousColumn);
	m = Col Mean(currentColumn);
	axisbox = Report(dist)[axis box(1)];
	Try(axisbox << Remove Ref Line(prevm));
	axisbox << Add Ref Line(m, "Dashed", blue, "Mean", 2);
	wait(0);
);
handler = cw << Make Column Switch Handler(Empty(), post);