963110_fr-FR

liliconcom

Droite de référence particulière sur un histogramme

Bonjour,

Comment ajouter une ligne de référence (celle de la moyenne) sur l'histogramme de la plateforme distribution lorsque l'on a un sélecteur de colonnes, je souhaite avoir cette ligne pour chacune des  10  variables, évidemment sans avoir à la rajouter à la main ?

Par avance merci.

Jean-Luc

Basic Data Analysis and ModelingData Exploration and Visualization Re: Droite de référence particulière sur un histogramme

Vous avez peu d'options :

• Définissez la valeur cible de la propriété de colonne « limite de spécification » sur la moyenne et activez-les dans les graphiques. Vous devrez calculer ces valeurs au préalable et les définir dans les propriétés de colonne, mais l'option « Résumé » + « Gérer les limites de spécification » devrait permettre de le faire.
• JSL : utiliser un gestionnaire de changement de colonne qui met à jour les lignes de référence lors des changements de colonne.
• JSL : Créer un script graphique capable de mettre à jour la ligne de référence
• Utilisez une plateforme différente telle que Graph Builder, dans laquelle vous pouvez facilement ajouter la ligne en tant qu'élément séparé.

Re: Droite de référence particulière sur un histogramme

Vous trouverez ci-dessous quelques exemples d'options JSL (il existe de nombreuses façons différentes de procéder) :

Exemple pour l'option de script graphique :

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

dist = dt << Distribution(
	Continuous Distribution(
		Column(:height),
		Always use column properties(1),
		Process Capability(0)
	),
	Column Switcher(:height, {:height, :weight})
);


Report(dist)[FrameBox(1)] << Add Graphics Script(Function({this},
	m = ((this << Top Parent)[OutlineBox("Summary Statistics"), Number Col Box(1)] << get)[1];
	Pen Color("Purple");
	Pen Size(5);
	H Line(m);
));

Exemple pour le gestionnaire de changement de colonne :

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

dist = dt << Distribution(
	Continuous Distribution(
		Column(:height),
		Always use column properties(1),
		Process Capability(0)
	)
);

cw = dist << Column Switcher(:height, {:height, :weight});
post = Function({previousColumn, currentColumn, switcher},
	prevm = Col Mean(previousColumn);
	m = Col Mean(currentColumn);
	axisbox = Report(dist)[axis box(1)];
	Try(axisbox << Remove Ref Line(prevm));
	axisbox << Add Ref Line(m, "Dashed", blue, "Mean", 2);
	wait(0);
);
handler = cw << Make Column Switch Handler(Empty(), post);