960626_it-IT

liliconcom

È possibile creare uno script per Graph Builder in modo da portare le linee di riferimento in primo piano?

Esiste un modo, tramite JSL, per spostare le linee di riferimento in primo piano nel grafico, in modo che siano chiaramente visibili sopra i punti dati?
So che posso fare clic con il pulsante destro del mouse, personalizzare le singole caselle del riquadro e riordinare manualmente gli elementi nell'elenco, ma vorrei farlo tramite JSL, se possibile.

Apprezzerei qualsiasi suggerimento o feedback.
Grazie,
Re

Codice per replicare il grafico sopra.

names default to here(1);<BR />dt = open ( "$SAMPLE_DATA/Aircraft Incidents.jmp" );<BR />dt << Graph Builder(
	Size( 964, 585 ),
	Show Control Panel( 0 ),
	Graph Spacing( 3 ),
	Spacing Borders( 1 ),
	Variables( X( :Event Date ), X( :Amateur Built ), Y( :Latitude ) ),
	Elements(
		Position( 1, 1 ),
		Points( X, Y, Legend( 94 ) ),
		Smoother( X, Y, Legend( 95 ) )
	),
	Elements(
		Position( 2, 1 ),
		Points( X, Y, Legend( 96 ) ),
		Box Plot( X, Y, Legend( 97 ), Outliers( 0 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"Latitude",
			ScaleBox,
			{Min( 0 ), Max( 110.494221427167 ), Inc( 20 ), Minor Ticks( 3 ),
			Add Ref Line( 42.1037140060617, "Solid", "Red", "", 1 )}
		),
		Dispatch(
			{},
			"Graph Builder",
			FrameBox,
			{Marker Size( 4 ), Marker Drawing Mode( "Outlined" )}
		),
		Dispatch(
			{},
			"Graph Builder",
			FrameBox( 2 ),
			{Marker Size( 4 ), Marker Drawing Mode( "Outlined" )}
		)
	)
)

Automazione e scriptingPersonalizzazione di massaOggetto: È possibile creare uno script per Graph Builder in modo da portare le linee di riferimento in primo piano?

Se modifichi l'ordine all'interno della personalizzazione del grafico, JMP aggiungerà l'ordine delle linee di riferimento al tuo script (almeno in JMP19). Puoi quindi cercarlo nell'indice degli script per farti un'idea di cosa potresti fare.

Oggetto: È possibile creare uno script per Graph Builder in modo da portare le linee di riferimento in primo piano?

Questo script modificato funziona?

Graph Builder(
	Size( 964, 585 ),
	Show Control Panel( 0 ),
	Graph Spacing( 3 ),
	Spacing Borders( 1 ),
	Variables( X( :Event Date ), X( :Amateur Built ), Y( :Latitude ) ),
	Elements(
		Position( 1, 1 ),
		Points( X, Y, Legend( 94 ) ),
		Smoother( X, Y, Legend( 95 ) )
	),
	Elements(
		Position( 2, 1 ),
		Points( X, Y, Legend( 96 ) ),
		Box Plot( X, Y, Legend( 97 ), Outliers( 0 ) )
	),
	SendToReport(
		Dispatch( {}, "Latitude", ScaleBox,
			{Min( 0 ), Max( 110.494221427167 ), Inc( 20 ), Minor Ticks( 3 ),
			Add Ref Line( 42.1037140060617, "Solid", "Red", "", 1 )}
		),
		Dispatch( {}, "Graph Builder", FrameBox,
			{Marker Size( 4 ), Marker Drawing Mode( "Outlined" ),
			Reference Line Order( 3 )}
		),
		Dispatch( {}, "Graph Builder", FrameBox( 2 ),
			{Marker Size( 4 ), Marker Drawing Mode( "Outlined" ),
			Reference Line Order( 3 )}
		)
	)
);

In tal caso, ho semplicemente cliccato sul triangolo rosso nella parte superiore di GB e selezionato Salva script > Appunti dopo aver modificato interattivamente l'ordine di rendering in modo che le linee di riferimento seguissero i marcatori.

Oggetto: È possibile creare uno script per Graph Builder in modo da portare le linee di riferimento in primo piano?

@jthi e @Mark_Bailey - Grazie a entrambi.
Quelle risposte mi hanno portato a questo

r = current report();

frameBoxList = r << XPath( "//FrameBox" );

// Giving a large enough number as input to Reference Line Order( ) 
// to ensure reference lines are brought to the front. 
frameBoxList << Reference Line Order( 100 );

// Or alternatively, I found seg count() which returns the number <BR />// of segs in a frame so could use that to set specific count for each one if needed. 
frameBoxList[1] << seg count();