948994_es-ES

liliconcom

¿Cómo defino las columnas de efectos una sola vez en una variable para usarlas en el modelo?

Hola a todos-

Me estoy volviendo loco intentando resolver esto. Creo que la respuesta reside en alguna combinación mágica de Eval() y Expr(), pero no logro dar con ella.

Tengo una lista de columnas que quiero definir al principio del script y que luego usaré como efectos del modelo, como se muestra a continuación. ¿Cómo puedo hacer que el modelo reconozca esta lista como una lista de columnas para usar como efectos? ¡Gracias!

JMP 19.1.0

dt = Current Data Table();
effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle, :dil_2_nacl, :dil_2_proclin};

Local( {obj},
obj = dt << Fit Model(
Y( :manual result 34.2),
Effects( effect_list),
Target Level( "neg" ),
Personality( "Nominal Logistic" ),
Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) ),
By( :genotype )
);

Automatización y secuencias de comandosRe: ¿Cómo defino las columnas de efectos una sola vez en una variable para usarlas en el modelo?

Esto puede ser complicado. Aquí tienes una forma de hacerlo:

effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle, :dil_2_nacl, :dil_2_proclin};


eff_expr=expr(Effects());

for each({effect, i}, effect_list, 
	Insert Into(eff_expr, name expr(effect))
);

Substitute(
		Expr(Fit Model(
			Y( :manual result 34.2 ),
			EEE,
			Target Level( "neg" ),
			Personality( "Nominal Logistic" ),
			Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) ),
			By( :genotype )
		)),
	Expr( EEE ), Name Expr( eff_expr )
);

Re: ¿Cómo defino las columnas de efectos una sola vez en una variable para usarlas en el modelo?

No estoy seguro de si Fit Model funcionaría con Effects({columns}) (algunas plataformas lo hacen), pero es más seguro eliminar la lista -> puedes construir la parte de Effects como una expresión.

Aquí hay una opción más

dt = Current Data Table();
effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle,
:dil_2_nacl, :dil_2_proclin};

effect_expr = Substitute(effect_list, List(), Expr(Effects))

obj = Eval(EvalExpr(
	dt << Fit Model(
		Y(:manual result 34.2),
		Expr(NameExpr(effect_expr)),
		Target Level("neg"),
		Personality("Nominal Logistic"),
		Run(Likelihood Ratio Tests(1), Wald Tests(0)),
		By(:genotype)
	);	
));

Re: ¿Cómo defino las columnas de efectos una sola vez en una variable para usarlas en el modelo?

¡Esto funcionó, gracias!