948994_zh-CN

liliconcom

如何在模型中使用某个变量定义效应列？

大家好-

我快要疯了，一直想不明白。我觉得答案在于 Eval() 和 Expr() 的某种神奇组合，但我就是搞不明白。

我需要在脚本开头定义一个列列表，然后将其作为模型效应引用，如下所示。如何让模型识别这个列表并将其用作效应呢？谢谢！

JMP 19.1.0

dt = Current Data Table();
effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle, :dil_2_nacl, :dil_2_proclin};

Local( {obj},
obj = dt << Fit Model(
Y( :manual result 34.2),
Effects( effect_list),
Target Level( "neg" ),
Personality( "Nominal Logistic" ),
Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) ),
By( :genotype )
);

自动化和脚本编写回复：如何在模型中使用变量定义一次效应列？

这可能有点棘手。以下是一种方法：

effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle, :dil_2_nacl, :dil_2_proclin};


eff_expr=expr(Effects());

for each({effect, i}, effect_list, 
	Insert Into(eff_expr, name expr(effect))
);

Substitute(
		Expr(Fit Model(
			Y( :manual result 34.2 ),
			EEE,
			Target Level( "neg" ),
			Personality( "Nominal Logistic" ),
			Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) ),
			By( :genotype )
		)),
	Expr( EEE ), Name Expr( eff_expr )
);

回复：如何在模型中使用变量定义一次效应列？

我不确定 Fit Model 是否能与 Effects({columns}) 一起使用（有些平台可以），但最好去掉列表 -> 您可以将 Effects 部分构建为表达式。

这里还有一种选择

dt = Current Data Table();
effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle,
:dil_2_nacl, :dil_2_proclin};

effect_expr = Substitute(effect_list, List(), Expr(Effects))

obj = Eval(EvalExpr(
	dt << Fit Model(
		Y(:manual result 34.2),
		Expr(NameExpr(effect_expr)),
		Target Level("neg"),
		Personality("Nominal Logistic"),
		Run(Likelihood Ratio Tests(1), Wald Tests(0)),
		By(:genotype)
	);	
));

回复：如何在模型中使用变量定义一次效应列？

成功了——谢谢！