948994_ko-KR

liliconcom

모델에서 사용할 변수에 효과 열을 한 번만 정의하려면 어떻게 해야 하나요?

안녕하세요 여러분-

이 문제를 해결하려고 애쓰다 보니 미칠 것 같습니다. Eval()과 Expr()의 어떤 마법 같은 조합에 해답이 있을 것 같은데, 도저히 방법을 모르겠습니다.

스크립트 시작 부분에 다음과 같이 열 목록을 정의하고, 모델 효과로 사용하기 위해 참조하려고 합니다. 모델이 이 목록을 효과로 사용할 열 목록으로 인식하도록 하려면 어떻게 해야 할까요? 감사합니다!

JMP 19.1.0

dt = Current Data Table();
effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle, :dil_2_nacl, :dil_2_proclin};

Local( {obj},
obj = dt << Fit Model(
Y( :manual result 34.2),
Effects( effect_list),
Target Level( "neg" ),
Personality( "Nominal Logistic" ),
Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) ),
By( :genotype )
);

자동화 및 스크립팅제목: 모델에서 사용할 변수에 효과 열을 한 번만 정의하는 방법은 무엇인가요?

이건 좀 까다로울 수 있습니다. 한 가지 방법은 다음과 같습니다.

effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle, :dil_2_nacl, :dil_2_proclin};


eff_expr=expr(Effects());

for each({effect, i}, effect_list, 
	Insert Into(eff_expr, name expr(effect))
);

Substitute(
		Expr(Fit Model(
			Y( :manual result 34.2 ),
			EEE,
			Target Level( "neg" ),
			Personality( "Nominal Logistic" ),
			Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) ),
			By( :genotype )
		)),
	Expr( EEE ), Name Expr( eff_expr )
);

제목: 모델에서 사용할 변수에 효과 열을 한 번만 정의하는 방법은 무엇인가요?

Fit Model이 Effects({columns})와 함께 작동할지는 확실하지 않지만 (일부 플랫폼에서는 가능함), 목록을 없애는 것이 더 안전합니다. Effects 부분을 표현식으로 구성할 수 있습니다.

여기 또 다른 옵션이 하나 더 있습니다.

dt = Current Data Table();
effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle,
:dil_2_nacl, :dil_2_proclin};

effect_expr = Substitute(effect_list, List(), Expr(Effects))

obj = Eval(EvalExpr(
	dt << Fit Model(
		Y(:manual result 34.2),
		Expr(NameExpr(effect_expr)),
		Target Level("neg"),
		Personality("Nominal Logistic"),
		Run(Likelihood Ratio Tests(1), Wald Tests(0)),
		By(:genotype)
	);	
));

제목: 모델에서 사용할 변수에 효과 열을 한 번만 정의하는 방법은 무엇인가요?

이 방법이 효과가 있었어요! 감사합니다!