948994_it-IT

liliconcom

Come faccio a definire le colonne degli effetti una sola volta in una variabile da utilizzare nel modello?

Ciao a tutti-

Sto impazzendo cercando di capirlo. Credo che la risposta risieda in una qualche magica combinazione di Eval() e Expr(), ma non riesco a trovarla.

Ho un elenco di colonne che voglio definire all'inizio dello script e poi utilizzare come effetti del modello, come mostrato di seguito. Come faccio a far sì che il modello riconosca l'elenco come un elenco di colonne da utilizzare come effetti? Grazie!

JMP 19.1.0

dt = Current Data Table();
effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle, :dil_2_nacl, :dil_2_proclin};

Local( {obj},
obj = dt << Fit Model(
Y( :manual result 34.2),
Effects( effect_list),
Target Level( "neg" ),
Personality( "Nominal Logistic" ),
Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) ),
By( :genotype )
);

Automazione e scriptingOggetto: Come definire le colonne degli effetti una sola volta in una variabile da utilizzare nel modello?

Può essere complicato. Ecco un modo per farlo:

effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle, :dil_2_nacl, :dil_2_proclin};


eff_expr=expr(Effects());

for each({effect, i}, effect_list, 
	Insert Into(eff_expr, name expr(effect))
);

Substitute(
		Expr(Fit Model(
			Y( :manual result 34.2 ),
			EEE,
			Target Level( "neg" ),
			Personality( "Nominal Logistic" ),
			Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) ),
			By( :genotype )
		)),
	Expr( EEE ), Name Expr( eff_expr )
);

Oggetto: Come definire le colonne degli effetti una sola volta in una variabile da utilizzare nel modello?

Non sono sicuro che Fit Model funzioni con Effects({columns}) (alcune piattaforme lo fanno), ma è più sicuro eliminare l'elenco -> puoi costruire la parte Effects come un'espressione.

Ecco un'altra opzione

dt = Current Data Table();
effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle,
:dil_2_nacl, :dil_2_proclin};

effect_expr = Substitute(effect_list, List(), Expr(Effects))

obj = Eval(EvalExpr(
	dt << Fit Model(
		Y(:manual result 34.2),
		Expr(NameExpr(effect_expr)),
		Target Level("neg"),
		Personality("Nominal Logistic"),
		Run(Likelihood Ratio Tests(1), Wald Tests(0)),
		By(:genotype)
	);	
));

Oggetto: Come definire le colonne degli effetti una sola volta in una variabile da utilizzare nel modello?

Ha funzionato, grazie!