948994_de-DE

liliconcom

Wie definiere ich Effektspalten einmalig in einer Variablen zur Verwendung im Modell?

Hallo zusammen!

Ich verzweifle noch daran, das herauszufinden. Ich glaube, die Lösung liegt in einer magischen Kombination von Eval() und Expr(), aber ich komme einfach nicht drauf.

Ich habe eine Liste von Spalten, die ich am Anfang des Skripts definieren und anschließend als Modelleffekte verwenden möchte (siehe unten). Wie kann ich dem Modell mitteilen, dass es diese Liste als Spaltenliste erkennt? Vielen Dank!

JMP 19.1.0

dt = Current Data Table();
effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle, :dil_2_nacl, :dil_2_proclin};

Local( {obj},
obj = dt << Fit Model(
Y( :manual result 34.2),
Effects( effect_list),
Target Level( "neg" ),
Personality( "Nominal Logistic" ),
Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) ),
By( :genotype )
);

Automatisierung und SkripterstellungBetreff: Wie definiere ich Effektspalten einmalig in einer Variablen zur Verwendung im Modell?

Das kann knifflig sein. Hier ist eine Möglichkeit, es zu tun:

effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle, :dil_2_nacl, :dil_2_proclin};


eff_expr=expr(Effects());

for each({effect, i}, effect_list, 
	Insert Into(eff_expr, name expr(effect))
);

Substitute(
		Expr(Fit Model(
			Y( :manual result 34.2 ),
			EEE,
			Target Level( "neg" ),
			Personality( "Nominal Logistic" ),
			Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) ),
			By( :genotype )
		)),
	Expr( EEE ), Name Expr( eff_expr )
);

Betreff: Wie definiere ich Effektspalten einmalig in einer Variablen zur Verwendung im Modell?

Ich bin mir nicht sicher, ob Fit Model mit Effects({columns}) funktionieren würde (auf manchen Plattformen ist das der Fall), aber es ist sicherer, die Liste zu entfernen -> Sie können den Effects-Teil als Ausdruck erstellen.

Hier ist noch eine weitere Option.

dt = Current Data Table();
effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle,
:dil_2_nacl, :dil_2_proclin};

effect_expr = Substitute(effect_list, List(), Expr(Effects))

obj = Eval(EvalExpr(
	dt << Fit Model(
		Y(:manual result 34.2),
		Expr(NameExpr(effect_expr)),
		Target Level("neg"),
		Personality("Nominal Logistic"),
		Run(Likelihood Ratio Tests(1), Wald Tests(0)),
		By(:genotype)
	);	
));

Betreff: Wie definiere ich Effektspalten einmalig in einer Variablen zur Verwendung im Modell?

Das hat funktioniert – vielen Dank!