948994_fr-FR

liliconcom

Comment définir les colonnes d'effet une fois dans une variable pour l'utiliser dans un modèle ?

Salut tout le monde-

Je suis à bout de nerfs à force d'essayer de comprendre. Je suis persuadé que la solution réside dans une combinaison magique de Eval() et Expr(), mais je n'arrive pas à la trouver.

J'ai une liste de colonnes que je souhaite définir au début du script, puis utiliser comme effets de modèle, comme indiqué ci-dessous. Comment faire pour que le modèle reconnaisse cette liste comme une liste de colonnes à utiliser comme effets ? Merci !

JMP 19.1.0

dt = Current Data Table();
effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle, :dil_2_nacl, :dil_2_proclin};

Local( {obj},
obj = dt << Fit Model(
Y( :manual result 34.2),
Effects( effect_list),
Target Level( "neg" ),
Personality( "Nominal Logistic" ),
Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) ),
By( :genotype )
);

Automatisation et scriptageRe: Comment définir les colonnes d'effet une seule fois dans une variable pour l'utiliser dans un modèle ?

Cela peut s'avérer délicat. Voici une façon de procéder :

effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle, :dil_2_nacl, :dil_2_proclin};


eff_expr=expr(Effects());

for each({effect, i}, effect_list, 
	Insert Into(eff_expr, name expr(effect))
);

Substitute(
		Expr(Fit Model(
			Y( :manual result 34.2 ),
			EEE,
			Target Level( "neg" ),
			Personality( "Nominal Logistic" ),
			Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) ),
			By( :genotype )
		)),
	Expr( EEE ), Name Expr( eff_expr )
);

Re: Comment définir les colonnes d'effet une seule fois dans une variable pour l'utiliser dans un modèle ?

Je ne suis pas sûr que Fit Model fonctionne avec Effects({columns}) (certaines plateformes le font), mais il est plus sûr de supprimer la liste -> vous pouvez construire la partie Effects sous forme d'expression.

Voici une autre option

dt = Current Data Table();
effect_list = {:run date, :reader, :sample bank, :plate dispense system, :dil_2_bot cap, :dil_2_bottle,
:dil_2_nacl, :dil_2_proclin};

effect_expr = Substitute(effect_list, List(), Expr(Effects))

obj = Eval(EvalExpr(
	dt << Fit Model(
		Y(:manual result 34.2),
		Expr(NameExpr(effect_expr)),
		Target Level("neg"),
		Personality("Nominal Logistic"),
		Run(Likelihood Ratio Tests(1), Wald Tests(0)),
		By(:genotype)
	);	
));

Re: Comment définir les colonnes d'effet une seule fois dans une variable pour l'utiliser dans un modèle ?

Ça a fonctionné, merci !