944670_zh-CN

liliconcom

帮助设置自定义“图例”的相对位置

各位JSL脚本编写者，大家好！

我正在编写一个脚本，目的是在图表中添加自定义“图例”。请参见下方截图。

我通过在图表中右键单击，选择“自定义...”>，然后向图表添加脚本，添加了线条和文本。以下 JSL 代码生成了如上所示的“图例”。

Pen Color( "Red" );
Pen Size( 2 );
Line Style( "Solid" );
Line( [20, 100], [65, 65] );
Text( {120, 64}, "Weight" );
Pen Color( "Blue" );
Pen Size( 2 );
Line( [20, 100], [60, 60] );
Text( {120, 59}, "Height" );

但我真正想要的是如何让图例行和文本的位置相对于“重量差异 [g]”列中的最大值（例如 90%）进行调整。数据表和脚本也已附上（无法运行的脚本已注释掉）。我原本以为可以用类似 Eval(Substitute(Expr(...), Expr(__pos__), pos) 的 JSL 函数来实现，但我一直收到“无效矩阵标记”的错误。例如，我尝试了以下代码：

Names Default To Here( 1 );

pos = Col Max( :"Weight diff[g]"n );

Eval(
	Substitute(
			Expr(
				Graph Builder(
					Size( 510, 510 ),
					Show Legend( 0 ),
					Graph Spacing( 4 ),
					Variables(
						X( :"MeasTime [s]"n ),
						Y( :"Weight diff [g]"n ),
						Y( :"Height diff [mm]"n, Position( 1 ), Side( "Right" ) )
					),
					Elements( Line( X, Y( 1 ), Legend( 5 ) ), Line( X, Y( 2 ), Legend( 6 ) ) ),
					SendToReport(
						Dispatch( {}, "MeasTime [s]", ScaleBox, {Inc( 100 )} ),
						Dispatch( {}, "Graph Builder", FrameBox,
							{Add Graphics Script(
								5,
								Description( "" ),
								Pen Color( "Red" );
								Pen Size( 2 );
								Line Style( "Solid" );
								Line( [20, 100], [__pos__, __pos__] );
								Text( {120, 64}, "Weight" );
								Pen Color( "Blue" );
								Pen Size( 2 );
								Line( [20, 100], [60, 60] );
								Text( {120, 59}, "Height" );
							)}
						)
					)
				)
			),
		Expr( __pos__ ), Eval( Round( 0.9 * pos, 0 ) )
	)
);

我甚至尝试将 `Line()` 函数的 y 坐标用 `{ }` 包裹起来，例如：`Line( [20, 100],[{_pos__,__pos__}])`，但仍然出现同样的错误。我更倾向于使用像 `pos` 这样的变量，从列中获取，而不是使用绝对值，因为列值可能会变化，我需要图表对象（例如线条和文本）能够相对于所绘制的坐标系移动。

关于如何解决这个错误或者我遗漏了什么，有什么建议吗？这种方法应该可行，但我就是不明白为什么。

谢谢！，

DS

自动化和脚本编写数据探索与可视化大规模定制回复：关于自定义“图例”相对位置的帮助

Y Range()和Y Origin()很可能就是你需要的。

回复：关于自定义“图例”相对位置的帮助

嗨@jthi ，

谢谢你的提示！稍作修改后，就帮了我很大的忙，完全满足了我的需求，谢谢！

也感谢您的快速回复！

DS

回复：关于自定义“图例”相对位置的帮助

如果其他读者感兴趣，我已将 JSL 代码（见下文）修改为：

Names Default To Here( 1 );

x1=300;
y2=36.7;

Graph Builder(
	Size( 510, 510 ),
	Show Legend( 0 ),
	Graph Spacing( 4 ),
	Variables( X( :"MeasTime [s]"n ), Y( :"Weight diff [g]"n ), Y( :"Height diff [mm]"n, Position( 1 ), Side( "Right" ) ) ),
	Elements( Line( X, Y( 1 ), Legend( 5 ) ), Line( X, Y( 2 ), Legend( 6 ) ) ),
	SendToReport(
		Dispatch( {}, "MeasTime [s]", ScaleBox, {Inc( 100 )} ),
		Dispatch( {}, "Graph Builder", FrameBox,
			{Add Graphics Script(
				5,
				Description( "" ),
				Pen Color( "Black" );
				Line Style( "Dashed" );
				Line( {x1,YOrigin()}, {x1,y2}, {XOrigin(),y2}, {x1,y2} );
				Pen Color( "Red" );
				Pen Size( 2 );
				Line Style( "Solid" );
				Line( {XOrigin()+30, 0.9*YRange()}, {XOrigin()+130, 0.9*YRange()} );
				Text( {XOrigin()+150, 0.9*YRange()-1}, "Weight" );
				Pen Color( "Blue" );
				Pen Size( 2 );
				Line( {XOrigin()+30, 0.85*YRange()}, {XOrigin()+130, 0.85*YRange()} );
				Text( {XOrigin()+150, 0.85*YRange()-1}, "Height" );
			)}
		)
	)
);

由此产生以下输出：

这些演示正是我想要做的——创建相对的“图例”和特定的参考线，这些参考线不会贯穿图表的整个长度/高度。

希望这能帮助其他想做类似事情的人。

希望这对其他人有所帮助！

DS

回复：关于自定义“图例”相对位置的帮助

您可能需要对图形脚本中的 x1 和 y2 进行评估，以避免各种可能令人烦恼的问题。

查看更多...

Names Default To Here(1);

x1 = 300;
y2 = 36.7;

dt = Current Data Table();
gb = Eval(Substitute(
		Expr(dt << Graph Builder(
			Size(510, 510),
			Show Legend(0),
			Graph Spacing(4),
			Variables(X(:"MeasTime [s]"n), Y(:"Weight diff [g]"n), Y(:"Height diff [mm]"n, Position(1), Side("Right"))),
			Elements(Line(X, Y(1), Legend(5)), Line(X, Y(2), Legend(6))),
			SendToReport(
				Dispatch({}, "MeasTime [s]", ScaleBox, {Inc(100)}),
				Dispatch({}, "Graph Builder", FrameBox,
					{Add Graphics Script(
						5,
						Description(""),
						Pen Color("Black");
						Line Style("Dashed");
						Line({_x1_, Y Origin()}, {_x1_, _y2_}, {X Origin(), _y2_}, {_x1_, _y2_});
						Pen Color("Red");
						Pen Size(2);
						Line Style("Solid");
						Line({X Origin() + 30, 0.9 * Y Range()}, {X Origin() + 130, 0.9 * Y Range()});
						Text({X Origin() + 150, 0.9 * Y Range() - 1}, "Weight");
						Pen Color("Blue");
						Pen Size(2);
						Line({X Origin() + 30, 0.85 * Y Range()}, {X Origin() + 130, 0.85 * Y Range()});
						Text({X Origin() + 150, 0.85 * Y Range() - 1}, "Height");
					)}
				)
			)
		)),
		Expr(_x1_), x1,
		Expr(_y2_), y2
	)
);