938868_ja-JP

liliconcom

カスタムウィンドウ内でデータテーブルの複数のセルを簡単かつ直感的に編集できます。

テーブルボックス内で、ユーザーが複数のセルを選択（または選択したように見せる）できる方法はありますか？あるいは、代わりに使える別のオブジェクトはありますか？使用例として、下の画像の2行目から始まるポンプタグを、左側のテーブルから右側のテーブルに移動したい場合を考えてみましょう。コピーして貼り付けるセルのブロックをどのように選択すればよいでしょうか？

もっと見る...

New Window( "Editing a data table",
	Show Menu( 0 ), Show Toolbars( 0 ),
	h list box(
		Table Box(
			String Col Edit Box( "PI Point", Repeat( { "" }, 5 ) || Transform Each({v},as list(transpose(1::15)),"Pump1-" || char(v)) ),
			String Col Edit Box( "Friendly Name", Repeat( { "" }, 5 ) || Transform Each({v},as list(transpose(1::15)),"Name " || char(v)) )
		),
		spacer box(20,20),
		Table Box(
			String Col Edit Box( "PI Point", {"sinusoid"} || Repeat( { "" }, 14 ) || {"Valve1", "Valve2", "Valve3"} ),
			String Col Edit Box( "Friendly Name", Repeat( { "" }, 15) || {"Inlet", "Outlet", "Recirc"} )
		)
	)
);

値のコピーと貼り付けをスクリプト化するのは簡単ですが、ユーザーはデータの取得元と貼り付け先を指定する必要があります。

実際の使用例

GitHub の課題で議論されたように、 Had/OSISoft PI Toolsアドインのインターフェースを改善し、タグとフレンドリー名を入力するテキストボックスをデータテーブルに置き換えたいと考えています。ユーザーは、JMP テーブルやスプレッドシートにタグのリストを持っていることが多く、それをアドインのユーザー インターフェースにすばやくコピー/ペーストしたいと考えています。テーブル全体を一度にコピーするのは簡単ですが、変更が必要な場合は、リストの一部だけを置き換えたい場合があります。

Table Boxオブジェクトでは、ユーザーが複数のセルを選択できないようですが、他に方法はありますか？以前は、データテーブルウィンドウ全体をユーザー定義ウィンドウ内に埋め込むことができると思っていたのですが、それは夢だったのかもしれません。

今のところ一番良いアイデアは、マウスオーバー時に選択されたセルに四角形を描画するようなロジックを使うことですが、まずはもっと簡単な解決策がないか調べてみたいと思っています。

自動化とスクリプト作成Re: カスタムウィンドウ内でデータテーブルの複数のセルを簡単かつ直感的に編集する方法

コマンドは<< 新しいデータボックスです:

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
new window("data box", dt << new data box)

Re: カスタムウィンドウ内でデータテーブルの複数のセルを簡単かつ直感的に編集する方法

@hogi さん、ありがとうございます！まさにそれです！！

これらはかなり良いユーザーエクスペリエンスを提供していると思います。

再現コード：

もっと見る...

names default to here(1);

dt1 = New Table( "dt1", invisible,
	Add Rows( 20 ),
	New Column( "PI Point", Character, "Nominal", Set Values(
		Repeat( { "" }, 5 ) || Transform Each({v},as list(transpose(1::15)),"Pump1-" || char(v))
	) ),
	New Column( "Friendly Name", Character, "Nominal", Set Values( 
		Repeat( { "" }, 5 ) || Transform Each({v},as list(transpose(1::15)),"Name " || char(v))
	) )
);

dt2 = New Table( "dt1", invisible,
	Add Rows( 20 ),
	New Column( "PI Point", Character, "Nominal", Set Values(
		{"sinusoid"} || Repeat( { "" }, 14 ) || {"Valve1", "Valve2", "Valve3"}
	) ),
	New Column( "Friendly Name", Character, "Nominal", Set Values( 
		Repeat( { "" }, 15) || {"Inlet", "Outlet", "Recirc"}
	) )
);

new window("data box",
	Show Menu( 0 ), Show Toolbars( 0 ),
	h list box(
		ntb1 = dt1 << New Data Box;
		ntb1 << close side panels;
		ntb1 << Set Row ID Width( 50 );
		ntb1 << Set Width(200);
		ntb1 << Set Height(450);
		ntb1,
		spacer box( Size( 20, 20 )),
		ntb2 = dt2 << New Data Box;
		ntb2 << close side panels;
		ntb2 << Set Row ID Width( 50 );
		ntb2 << Set Width(200);
		ntb2 << Set Height(450);
		ntb2
	),
	<< On close(
		try( dt1 << Close Window );
		try( dt2 << Close Window );
	)
);

テーブルを描画した後に、ボックス内の列幅をどのように変更するかなど、まだ解決していない部分もありますが、それはまた別の機会にお話しします！