936189_es-ES

liliconcom

Windows 11 > JMP 19 > Script para asignar un gradiente continuo > Problema al pasar el rango del gradiente a la propiedad de la columna

Hola comunidad de JMP,

Escribí un script sencillo para asignar un degradado de color a las columnas de valores continuos basándose en el cuartil 0,05 de los valores de las columnas.

Names Default To Here(1);

dt = current data table ();

scol = dt << Get Selected Columns ();

For (i = 1, i <= N items (scol), i++,
	column (dt, scol[i]) << Format("Fixed Dec", 12, 3);
	low_mark = Col Quantile(column (dt, scol[i]), 0.05);
	high_mark = Col Quantile(column (dt, scol[i]), 0.95);
	
	if(abs(low_mark) > high_mark, bound = -low_mark, bound = high_mark);
	
	range_list = {-bound, bound, 0};
	
	column (dt, scol[i]) << Set Property ("Color Gradient", 
										{"Blue White Red", Range (Eval list (range_list)),
										Color cell by value (1)})
	
	
);

Si bien funciona al asignar los colores correctos, JMP devuelve un error cuando posteriormente edito el degradado manualmente (ver más abajo):

Por lo tanto, necesito un método para pasar los valores del rango del gradiente sin que se produzca un error al realizar ediciones manuales posteriores.

Gracias.

Mejor,

TS

Automatización y secuencias de comandosRe: Windows 11 > JMP 19 > Script para asignar un gradiente continuo > Problema al pasar el rango del gradiente a la propiedad de la columna

Te falta la evaluación de expresiones.

Names Default To Here(1);

dt = Current Data Table();

scol = dt << Get Selected Columns("String");

For Each({colname}, scol,
	Column(dt, colname) << Format("Fixed Dec", 12, 3);
	low_mark = Col Quantile(Column(dt, colname), 0.05);
	high_mark = Col Quantile(Column(dt, colname), 0.95);
	
	If(Abs(low_mark) > high_mark,
		bound = -low_mark,
		bound = high_mark
	);
	
	range_list = Eval List({-bound, bound, 0});

	Eval(EvalExpr(
		Column(dt, colname) << Set Property(
			"Color Gradient",
			{"Blue White Red", Range(Expr(range_list)), Color cell by value(1)}
		)		
	));
);