nav[aria-label="Primary Navigation"] { padding: 0; & ul { list-style: none; width: 100%; display: flex; flex-direction: row; justify-content: start; align-items: start; gap: 30px; padding: 0; & li { margin: 0; } & ul li { list-style: none; } } }
Bayesian Optimization - Semiconductor Example

flo_kussener
This example serves as an introduction to Bayesian optimization and how it works in JMP.
It is based on a semiconductor use case and illustrates several key concepts that make Bayesian optimization so effective:
- Multiple responses
- Changing the range of variation for factors
- Customizing options
Ex3_Wafer BayesOpt.jmp
Comments

flo_kussener
For non USA/English SE, please note that you have to be in English setting, otherwise you will have some issues with response limits.
Capture d'écran 2026-03-30 172810.png
Florian_Vogt
Hi, great example. I today realized a new error when running the next run script:
Does anybody know a fix?
Ben_BarrIngh
They updated in 19.1 to no longer have individual group scripts, I originally had everything group together to make it neater but this is no longer needed. I think Stephane rearranged this for @flo_kussener , but I've fixed it, just copy the attached script and put it in the dashboard script.
Clear Log();

// ===========================================================================================================================================================
// GLOBAL VARIABLES -- GLOBAL VARIABLES -- GLOBAL VARIABLES -- GLOBAL VARIABLES -- GLOBAL VARIABLES -- GLOBAL VARIABLES -- GLOBAL VARIABLES -- GLOBAL VARIABLE
// ===========================================================================================================================================================
dt = Current Data Table();
nIteration = 0;
nRandomSeed = 12345;
nGraphHeight = 490;
nGraphWidth = 230;

// ===========================================================================================================================================================
// MEMORY -- MEMORY -- MEMORY -- MEMORY -- MEMORY -- MEMORY -- MEMORY -- MEMORY -- MEMORY -- MEMORY -- MEMORY -- MEMORY -- MEMORY -- MEMORY -- MEMORY -- MEMOR
// ===========================================================================================================================================================
oAssArrayR = Associative Array();
oAssArrayP = Associative Array();
oAssArrayF = Associative Array();
oAssArrayMin = Associative Array();
oAssArrayMax = Associative Array();
nStartRows = 0;
nMaxIteration = 30;

// ===========================================================================================================================================================
// CONSTANTES -- CONSTANTES -- CONSTANTES -- CONSTANTES -- CONSTANTES -- CONSTANTES -- CONSTANTES -- CONSTANTES -- CONSTANTES -- CONSTANTES -- CONSTANTES -- C
// ===========================================================================================================================================================
Cst_Col_Responses = "Responses";
Cst_Col_Parameters = "Parameters";
Cst_Col_ReasonAdded = "Reason Added";
Cst_Col_Iteration = "Iteration";
//
Cst_Prop_Coding = "Coding";
Cst_Prop_ResponseLimits = "Response Limits";
//
Cst_BOStartUp = "BO Start Up";
Cst_BOStartUpScripts = "BO Start Up Scripts";
//
Cst_Maximize = "Maximize";
Cst_Minimize = "Minimize";
Cst_MatchTarget = "Match Target";
Cst_NoneTarget = "None";

// ===========================================================================================================================================================
// PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- P
// ===========================================================================================================================================================
Expr_AutoRunTillBestPoint = Expr(
	Show( "I - Expr_AutoRunTillBestPoint" );
	
	For( i = 1, i <= nMaxIteration, i++,
		Expr_BayesOpt;
		sReasonAdded = Column( dt, Cst_Col_ReasonAdded )[N Rows( dt )];
		If( sReasonAdded == "Repeat Best",
			Expr_HighlightBestPoint;
			Break();
		);
		Wait( 1.0 );
	);
	
	Show( "0 - Expr_AutoRunTillBestPoint" );
);

Expr_HighlightBestPoint = Expr(
	Show( "I - Expr_HighlightBestPoint" );
	
	lst_RowsToBeHighlighted = {};
	sReasonAdded = Column( dt, Cst_Col_ReasonAdded )[N Rows( dt )];
	If( sReasonAdded == "Repeat Best",
		For( i = 1, i < N Rows( dt ), i++,
			nCounter = 0;
			For( k = 1, k <= N Items( Lst_FactorsColumns ), k++,
				If( Column( dt, Lst_FactorsColumns[k] )[i] == Column( dt, Lst_FactorsColumns[k] )[N Rows( dt )],
					nCounter++;
				);
				If( nCounter == N Items( Lst_FactorsColumns ),
					Insert Into( lst_RowsToBeHighlighted, i )
				);
			);
		);
	);
	dt << << Clear Select << Select Rows( lst_RowsToBeHighlighted ) << Colors( "Green" );
	dt << << Clear Select;
	
	Show( "O - Expr_HighlightBestPoint" );
);

Expr_ReadInputDataFromJMPTable = Expr(
	Show( "I - Expr_ReadInputDataFromJMPTable" );
	
	// Check column grouping names
	Lst_ColumnGroups = dt << get column groups names;
	For Each( {value, index}, {Cst_Col_Responses, Cst_Col_Parameters},
		nColIdx = 0;
		For( i = 1, i <= N Items( Lst_ColumnGroups ), i++,
			If( value == Lst_ColumnGroups[i],
				nColIdx = i;
				Break();
			)
		);
		If( nColIdx == 0,
			New Window( "Message", modal, H List Box( Spacer Box( size( 5, 0 ) ), Text Box( "[" || value || "] grouping not found" ) ) )
		);
	);

	
	// Get column lists
	Lst_ResponsesColumns = dt << get column group( Cst_Col_Responses );
	Lst_FactorsColumns = dt << get column group( Cst_Col_Parameters );
	
	// Create Associative Arrays with all the relevant properties
	For( i = 1, i <= N Items( Lst_FactorsColumns ), i++,
		oAssArrayP[Lst_FactorsColumns[i]] = Column( dt, Lst_FactorsColumns[i] ) << Get Property( Cst_Prop_Coding )
	);
	For( i = 1, i <= N Items( Lst_ResponsesColumns ), i++,
		oAssArrayR[Lst_ResponsesColumns[i]] = Column( dt, Lst_ResponsesColumns[i] ) << Get Property( Cst_Prop_ResponseLimits );
		oAssArrayMin[Lst_ResponsesColumns[i]] = Col Minimum( Column( dt, Lst_ResponsesColumns[i] ) );
		oAssArrayMax[Lst_ResponsesColumns[i]] = Col Maximum( Column( dt, Lst_ResponsesColumns[i] ) );
		If( Char( oAssArrayR[Lst_ResponsesColumns[i]]["Upper"] ) != "",
			If( oAssArrayR[Lst_ResponsesColumns[i]]["Upper"] > oAssArrayMax[Lst_ResponsesColumns[i]],
				oAssArrayMax[Lst_ResponsesColumns[i]] = oAssArrayR[Lst_ResponsesColumns[i]]["Upper"]
			)
		);
		If( Char( oAssArrayR[Lst_ResponsesColumns[i]]["Lower"] ) != "",
			If( oAssArrayR[Lst_ResponsesColumns[i]]["Lower"] < oAssArrayMin[Lst_ResponsesColumns[i]],
				oAssArrayMin[Lst_ResponsesColumns[i]] = oAssArrayR[Lst_ResponsesColumns[i]]["Lower"]
			)
		);
	);
	nStartRows = N Rows( dt );

	Show( "O - Expr_ReadInputDataFromJMPTable" );
);

Expr_ResetTable = Expr(
	Show( "I - Expr_ResetTable" );
	
	// Delete rows, except the starting ones
	dt << clear select();
	dt << select rows( 1 :: nStartRows );
	Wait( 0.1 );
	dt << invert row selection;
	dt << delete rows;

	// Delete the BO Start scripts
	dtscriptlists = dt << Get Table Script Names;
	filteredList = {};
	For( i = 1, i <= N Items( dtscriptlists ), i++,
		If( Contains( dtscriptlists[i], Cst_BOStartUp ),
			Insert Into( filteredList, dtscriptlists[i] )
		)
	);
	dt << Delete Scripts( filteredlist );
	nIteration = 0;
	
	// Reset Coding property for factors
	For( i = 1, i <= N Items( Lst_FactorsColumns ), i++,
		minVal = Num( oAssArrayP[Lst_FactorsColumns[i]][1] );
		maxVal = Num( oAssArrayP[Lst_FactorsColumns[i]][2] );
		Eval(
			Substitute(
					Expr(
						Column( dt, Lst_FactorsColumns[i] ) << Set Property( Cst_Prop_Coding, {_Min, _Max} )
					),
				Expr( _Min ), minVal,
				Expr( _Max ), maxVal
			)
		);
	);
	
	// Reset Response Limits properties for responses
/*For( i = 1, i <= N Items( Lst_ResponsesColumns ), i++,
		sGoal = oAssArrayR[Lst_ResponsesColumns[i]]["Goal"];
		nImportance = oAssArrayR[Lst_ResponsesColumns[i]]["Importance"];
		nLower = oAssArrayR[Lst_ResponsesColumns[i]]["Lower"];
		nMiddle = oAssArrayR[Lst_ResponsesColumns[i]]["Middle"];
		nUpper = oAssArrayR[Lst_ResponsesColumns[i]]["Upper"];
		If( sGoal == Cst_Maximize,
			nMinDesirability = 0.066;
			nAvgDesirability = 0.5;
			nMaxDesirability = 0.9819;
		);
		If( sGoal == Cst_Minimize,
			nMinDesirability = 0.9816;
			nAvgDesirability = 0.5;
			nMaxDesirability = 0.066;
		);
		If( sGoal == Cst_MatchTarget,
			nMinDesirability = 0.0183;
			nAvgDesirability = 1.0;
			nMaxDesirability = 0.0183;
		);
		If( sGoal == Cst_NoneTarget,
			nMinDesirability = .;
			nAvgDesirability = .;
			nMaxDesirability = .;
		);
		Eval(
			Substitute(
				Expr(
					Column( dt, Lst_ResponsesColumns[i] ) << Set Property(
						Cst_Prop_ResponseLimits,
						Lower( _Lower, _minDesirability ),
						Middle( _Middle, _avgDesirability ),
						Upper( _Upper, _maxDesirability ),
						Goal( _Goal ),
						Importance( _Importance )
					)
				),
				Expr( _Lower ), nLower,
				Expr( _minDesirability ), nMinDesirability,
				Expr( _Middle ), nMiddle, 
				Expr( _avgDesirability ), nAvgDesirability,
				Expr( _Upper ), nUpper,
				Expr( _maxDesirability ), nMaxDesirability,
				Expr( _Goal ), sGoal,
				Expr( _Importance ), nImportance
			)
		);
	);*/
	
	Show( "O - Expr_ResetTable" );
);

Expr_Chart_Factors = Expr(
	Show( "I - Expr_Chart_Factors" );
	
	// Depending on the numbr of factors
	Lst_FactorsColumns = dt << get column group( Cst_Col_Parameters );
	If( N Items( Lst_FactorsColumns ) == 3, 
		// 3 FACTORS => SCATTERPLOT
		// Build the list of factors
		Lst_FactorsColumns = dt << get column group( Cst_Col_Parameters );
		expFactors = Expr( Y() );
		For( i = 1, i <= N Items( Lst_FactorsColumns ), i++,
			Insert Into( expFactors, Parse( "Column(dt, \!"" || Char( Lst_FactorsColumns[i] ) || "\!")" ) )
		);
		
		// Draw the scatterplot
		Eval(
			Substitute(
					Expr(
						Scatterplot 3D(
							_ListOfFactors,
							Frame3D( Set Grab Handles( 1 ), Set Marker Quality( 0.4762 ), Set Marker Scale( 10 ) ),
							Show Controls( 0 )
						)
					),
				Expr( _ListOfFactors ), Name Expr( expFactors ), 

			)
		);
	);
	Show( "O - Expr_Chart_Factors" );
);

Expr_Chart_Responses = Expr(
	Show( "I - Expr_Chart_Responses" );
	
	Lst_ResponsesColumns = dt << get column group( Cst_Col_Responses );
	
	// 1. Build the Graph Builder container
	exprResponsesChart = Expr(
		Graph Builder(
			Transform Column( "Row", Formula( Col Sequence( :"@Exclude"n, :"@Filter"n ) ) ),
			Size( nGraphHeight, nGraphWidth ),
			Show Control Panel( 0 ),
			Show Legend( 0 ),
			Fit to Window( "On" ),
			Continuous Color Theme( "White to Blue" ),
			Graph Spacing( 2 ),

		)
	);
	Show( "I - Expr_Chart_Responses - 1" );
	
	// 2. Add the Variable section
	expVariables = Expr( Variables() );
	Insert Into( expVariables, Parse( "X( Column(dt, \!"" || "Iteration" || "\!") )" ) );
	For( i = 1, i <= N Items( Lst_ResponsesColumns ), i++,
		Insert Into( expVariables, Parse( "Y( Column(dt, \!"" || Char( Lst_ResponsesColumns[i] ) || "\!") )" ) )
	);
	Insert Into( expVariables, Parse( "Color( :Row )" ) );
	Insert Into( exprResponsesChart, Name Expr( expVariables ) );
	Show( "I - Expr_Chart_Responses - 2" );
	
	// 3. Add the Element section
	For( i = 1, i <= N Items( Lst_ResponsesColumns ), i++,
		expElements = Expr( Elements() );
		Insert Into( expElements, Parse( "Position(1, " || Char( i ) || ")" ) );
		Insert Into( expElements, Parse( "Line( X, Y, Legend( " || Char( 6 + i ) || " ))" ) );
		Insert Into( expElements, Parse( "Points( X, Y, Legend( " || Char( 6 + N Items( Lst_ResponsesColumns ) + i ) || " ))" ) );
		Insert Into( exprResponsesChart, Name Expr( expElements ) );
	);
	Show( "I - Expr_Chart_Responses - 3" );

	// 4. Add the SendToReport section
	exprSendToReport = Expr( SendToReport() );
	For( i = 1, i <= N Items( Lst_ResponsesColumns ), i++, 
		// 4.1.Delete Outline Box title
		expDispatch = Expr( Dispatch() );
		Insert Into( expDispatch, Parse( "{}" ) );
		Insert Into( expDispatch, Parse( "\!"Graph Builder\!"" ) );
		Insert Into( expDispatch, Parse( "OutlineBox" ) );
		Insert Into( expDispatch, Parse( "{Set Title( \!"\!" ), Image Export Display( Normal )}" ) );
		Insert Into( exprSendToReport, Name Expr( expDispatch ) );
		Show( "I - Expr_Chart_Responses - 4.1." || Char( i ) );
		
		expDispatch = Expr( Dispatch() );
		sGoal = Char( oAssArrayR[Lst_ResponsesColumns[i]]["Goal"] );
		If( sGoal == Cst_Minimize, 
			// 4.2.MINIMIZE CASE
			// Color in green what is above the lower ref line, add the other optional ref lines
			Insert Into( expDispatch, Parse( "{}" ) );
			Insert Into( expDispatch, Parse( "\!"" || Char( Lst_ResponsesColumns[i] ) || "\!"" ) );
			Insert Into( expDispatch, Parse( "ScaleBox" ) );
			exprRefLine = Expr( {} );
			// Update min/max
			Insert Into( exprRefLine, Parse( "Max(" || Char( 1.05 * Num( oAssArrayMax[Lst_ResponsesColumns[i]] ) ) || ")" ) );
			Insert Into( exprRefLine, Parse( "Min(" || Char( 0.95 * Num( oAssArrayMin[Lst_ResponsesColumns[i]] ) ) || ")" ) );
			// Add ref lines
			Insert Into(
				exprRefLine,
				Parse(
					"Add Ref Line({" || Char( Num( oAssArrayMin[Lst_ResponsesColumns[i]] ) ) || ", " || Char(
						Num( oAssArrayR[Lst_ResponsesColumns[i]]["Upper"] )
					) || "}, \!"Solid\!", \!"Green\!", \!"\!", 1, 0.25 )"
				)
			);
			Insert Into(
				exprRefLine,
				Parse(
					"Add Ref Line(" || Char( Num( oAssArrayR[Lst_ResponsesColumns[i]]["Upper"] ) ) ||
					", \!"Solid\!", \!"BlueCyan\!", \!"Lower\!", 2, 1 )"
				)
			);
			nValue = .;
			Try( nValue = Char( oAssArrayR[Lst_ResponsesColumns[i]]["Middle"] ) );
			If( !Is Missing( nValue ),
				Insert Into( exprRefLine, Parse( "Add Ref Line(" || Char( nValue ) || ", \!"Dotted\!", \!"BlueCyan\!", \!"Middle\!", 1, 1 )" ) )
			);
			sValue = .;
			Try( sValue = Char( oAssArrayR[Lst_ResponsesColumns[i]]["Lower"] ) );
			If( !Is Missing( nValue ),
				Insert Into( exprRefLine, Parse( "Add Ref Line(" || Char( nValue ) || ", \!"Dotted\!", \!"BlueCyan\!", \!"Upper\!", 1, 1 )" ) )
			);
			Insert Into( expDispatch, Name Expr( exprRefLine ) );
		);
		Show( "I - Expr_Chart_Responses - 4.2." || Char( i ) );
		
		If( sGoal == Cst_Maximize, 
			// 4.3.MAXIMIZE CASE
			// Color in green what is above the lower ref line, add the other optional ref lines
			Insert Into( expDispatch, Parse( "{}" ) );
			Insert Into( expDispatch, Parse( "\!"" || Char( Lst_ResponsesColumns[i] ) || "\!"" ) );
			Insert Into( expDispatch, Parse( "ScaleBox" ) );
			exprRefLine = Expr( {} );
			// Update min/max
			Insert Into( exprRefLine, Parse( "Max(" || Char( 1.05 * Num( oAssArrayMax[Lst_ResponsesColumns[i]] ) ) || ")" ) );
			Insert Into( exprRefLine, Parse( "Min(" || Char( 0.95 * Num( oAssArrayMin[Lst_ResponsesColumns[i]] ) ) || ")" ) );
			// Add ref lines
			Insert Into(
				exprRefLine,
				Parse(
					"Add Ref Line({" || Char( Num( oAssArrayR[Lst_ResponsesColumns[i]]["Lower"] ) ) || ", " || Char(
						Num( oAssArrayMax[Lst_ResponsesColumns[i]] )
					) || "}, \!"Solid\!", \!"Green\!", \!"\!", 1, 0.25 )"
				)
			);
			Insert Into(
				exprRefLine,
				Parse(
					"Add Ref Line(" || Char( Num( oAssArrayR[Lst_ResponsesColumns[i]]["Lower"] ) ) ||
					", \!"Solid\!", \!"BlueCyan\!", \!"Lower\!", 2, 1 )"
				)
			);
			nValue = .;
			Try( nValue = oAssArrayR[Lst_ResponsesColumns[i]]["Middle"] );
			If( !Is Missing( nValue ),
				Insert Into( exprRefLine, Parse( "Add Ref Line(" || Char( nValue ) || ", \!"Dotted\!", \!"BlueCyan\!", \!"Middle\!", 1, 1 )" ) )
			);
			nValue = .;
			Try( nValue = oAssArrayR[Lst_ResponsesColumns[i]]["Upper"] );
			If( !Is Missing( nValue ),
				Insert Into( exprRefLine, Parse( "Add Ref Line(" || Char( nValue ) || ", \!"Dotted\!", \!"BlueCyan\!", \!"Upper\!", 1, 1 )" ) )
			);
			Show( exprRefLine );
			Insert Into( expDispatch, Name Expr( exprRefLine ) );
		);
		Show( "I - Expr_Chart_Responses - 4.3." || Char( i ) );
		
		If( sGoal == Cst_MatchTarget, 
			// 4.4.MATCH TARGET CASE
			// Color in green what is between the lower and upper ref line
			Insert Into( expDispatch, Parse( "{}" ) );
			Insert Into( expDispatch, Parse( "\!"" || Char( Lst_ResponsesColumns[i] ) || "\!"" ) );
			Insert Into( expDispatch, Parse( "ScaleBox" ) );
			exprRefLine = Expr( {} );
			// Update min/max
			Insert Into( exprRefLine, Parse( "Max(" || Char( 1.05 * oAssArrayMax[Lst_ResponsesColumns[i]] ) || ")" ) );
			Insert Into( exprRefLine, Parse( "Min(" || Char( 0.95 * oAssArrayMin[Lst_ResponsesColumns[i]] ) || ")" ) );
			// Add ref lines
			Insert Into(
				exprRefLine,
				Parse(
					"Add Ref Line({" || Char( oAssArrayR[Lst_ResponsesColumns[i]]["Lower"] ) || ", " || Char(
						oAssArrayR[Lst_ResponsesColumns[i]]["Upper"]
					) || "}, \!"Solid\!", \!"Green\!", \!"\!", 1, 0.25 )"
				)
			);
			Insert Into(
				exprRefLine,
				Parse(
					"Add Ref Line(" || Char( oAssArrayR[Lst_ResponsesColumns[i]]["Lower"] ) || ", \!"Solid\!", \!"BlueCyan\!", \!"Lower\!", 2, 1 )"
				)
			);
			If( Char( oAssArrayR[Lst_ResponsesColumns[i]]["Middle"] ) != "",
				Insert Into(
					exprRefLine,
					Parse(
						"Add Ref Line(" || Char( oAssArrayR[Lst_ResponsesColumns[i]]["Middle"] ) ||
						", \!"Dotted\!", \!"BlueCyan\!", \!"Middle\!", 1, 1 )"
					)
				)
			);
			Insert Into(
				exprRefLine,
				Parse(
					"Add Ref Line(" || Char( oAssArrayR[Lst_ResponsesColumns[i]]["Upper"] ) || ", \!"Solid\!", \!"BlueCyan\!", \!"Upper\!", 2, 1 )"
				)
			);
			Insert Into( expDispatch, Name Expr( exprRefLine ) );
		);
		Insert Into( exprSendToReport, Name Expr( expDispatch ) );
		Show( "I - Expr_Chart_Responses - 4.4." || Char( i ) );
	);
	
	expLegend400 = Expr( Dispatch() );
	Insert Into( expLegend400, Parse( "{}" ) );
	Insert Into( expLegend400, Parse( "\!"400\!"" ) );
	Insert Into( expLegend400, Parse( "ScaleBox" ) );
	expLegendCollection = Expr( {} );
	For( i = 1, i <= N Items( Lst_ResponsesColumns ), i++,
		expLegend = Expr( Legend Model() );
		Insert Into( expLegend, Parse( Char( 6 + i ) ) );
		//Insert Into( expLegend, Parse( "Type Properties( 0, \!"H Line\!", {Line Color( 1 )} )" ));
		//Insert Into( expLegend, Parse( "Properties( 0, {Line Color( 1 )}, Item ID( \!"Mean(" || Char( Lst_ResponsesColumns[i] ) || ")\!", 1 ) )" ));
		Insert Into( expLegend, Parse( "Type Properties( 0, \!"Gradient\!",{gradient( {Max Lightness( 0.7586 )})} )" ) );
		Insert Into( expLegend, Parse( "Properties( 0, {gradient( {Max Lightness( 0.7586 )})}, Item ID( \!"Row\!", 1 ) )" ) );
		Insert Into( expLegendCollection, Name Expr( expLegend ) );
	);
	Insert Into( expLegend400, Name Expr( expLegendCollection ) );
	Insert Into( exprSendToReport, Name Expr( expLegend400 ) );
	Show( "I - Expr_Chart_Responses - 4.5" );
	
	exprGraphTitle = Expr( Dispatch() );
	Insert Into( exprGraphTitle, Parse( "{}" ) );
	Insert Into( exprGraphTitle, Parse( "\!"graph title\!"" ) );
	Insert Into( exprGraphTitle, Parse( "TextEditBox" ) );
	Insert Into( exprGraphTitle, Parse( "{Set Text( \!"\!" )} " ) );
	Insert Into( exprSendToReport, Name Expr( exprGraphTitle ) );
	Insert Into( exprResponsesChart, Name Expr( exprSendToReport ) );
	Show( "I - Expr_Chart_Responses - 4.6" );
	
	Eval(
		Substitute( Expr( exprResponsesChart ),
			Expr( _expVariables ), Name Expr( expVariables ),
			Expr( _ListOfFactors ), Name Expr( expFactors ), 

		)
	);
	Show( "I - Expr_Chart_Responses - 5" );
	
	Show( "O - Expr_Chart_Responses" );
);

Expr_BayesOpt = Expr(
	Show( "I - Expr_BayesOpt" );
	
	// Build the list of factors
	Lst_FactorsColumns = dt << get column group( Cst_Col_Parameters );
	expFactors = Expr( X() );
	For( i = 1, i <= N Items( Lst_FactorsColumns ), i++,
		Insert Into( expFactors, Parse( "Column(dt, \!"" || Char( Lst_FactorsColumns[i] ) || "\!")" ) )
	);
	
	// Build the list of responses
	Lst_ResponsesColumns = dt << get column group( Cst_Col_Responses );
	expResponses = Expr( Y() );
	For( i = 1, i <= N Items( Lst_ResponsesColumns ), i++,
		Insert Into( expResponses, Parse( "Column(dt, \!"" || Char( Lst_ResponsesColumns[i] ) || "\!")" ) )
	);
	
	// Call teh Bayesian Optimization platform and simulate a mouse click to get the current batch
	Random Reset( nRandomSeed );
	Eval(
		Substitute(
				Expr(
					bayesoprep = Bayesian Optimization(
						_ListOfResponses,
						_ListOfFactors,
						Iteration( Column( dt, Cst_Col_Iteration ) ),
						Continuous Correlation Type( "Matern 5" ),
						Nominal Correlation Type( "Equal Correlations" ),
						Ordinal Correlation Type( "Equal Correlations" ),
						Model Based Augmentation RSquare Threshold( 0.25 ),
						Batch Size( 1 ),
						Candidate Set Size( 3000 )
					)
				),
			Expr( _ListOfResponses ), Name Expr( expResponses ),
			Expr( _ListOfFactors ), Name Expr( expFactors ), 

		)
	);
	Report( bayesoprep )[Tab Page Box( 2 ), "Current Batch", Button Box( 1 )] << click( 1 );
	bayesoprep << close window;
	
	/*// Group scripts
	scripts = dt << get table script names;
	group = {};
	For Each( {s}, scripts, If( Contains( s, Cst_BOStartUp ), Insert Into( group, s ) ) );
	dt << group scripts( Cst_BOStartUpScripts, group );*/
	
	// Run experiment
	bRunExperimentMode = !(Btn_Mode << Get);
	If( bRunExperimentMode,
		Expr_Run_Experiment;
		
		nIteration = nIteration + 1;
		If( nIteration > 0, 
			// Update the Responses chart
			dash["Dashboard", Tab Page Box( 1 ), "Responses", "Graph Builder"] << delete;
			olb_Responses << append( Expr_Chart_Responses );

			// Update the Bayesian Optimization report
			Try(
				dash["Dashboard", Tab Page Box( 1 ), "Bayesian Optimization", Outline Box( 2 )];
				oScrollBoxExist = 1;
			,
				oScrollBoxExist = 0
			);
			If( oScrollBoxExist,
				dash["Dashboard", Tab Page Box( 1 ), "Bayesian Optimization", Outline Box( 2 )] << delete
			);
			sScriptName = "Bayes Opt Start Up Script for Next Batch";
			Random Reset( nRandomSeed );
			olb_BayesOpt << append( dt << Run Script( sScriptName ) );
			
			// Update the position of the cursors in the "All Responses Profiler"
			pf = dash["Dashboard", Tab Page Box( 1 ), "Bayesian Optimization", Outline Box( 2 ), Tab Page Box( 1 ),
			"Bayesian Optimization Model Summary", "All Responses Profiler"] << get scriptable object;
			Lst_FactorsColumns = dt << get column group( Cst_Col_Parameters );
			For( i = 1, i <= N Items( Lst_FactorsColumns ), i++,
				Eval(
					Substitute(
							Expr(
								pf << Term Value( _Column1( _Column2[N Rows( dt )], Lock( 0 ), Show( 1 ) ) )
							),
						Expr( _Column1 ), Column( dt, Lst_FactorsColumns[i] ),
						Expr( _Column2 ), Column( dt, Lst_FactorsColumns[i] ), 

					)
				)
			);
		);
	);
	
	// Recode + Color rows of the "Reason Added" column
	dt << Begin Data Update;
	For( i = 1, i <= N Rows( dt ), i++,
		sValue = Column( dt, Cst_Col_ReasonAdded )[i];
		Write( sValue );
		If( sValue == "Max Expected Improvement",
			Column( dt, Cst_Col_ReasonAdded )[i] = "Exploitation"
		);
		If( sValue == "Max Desirability",
			Column( dt, Cst_Col_ReasonAdded )[i] = "Exploitation"
		);
		If( sValue == "MaxPro Space Filling",
			Column( dt, Cst_Col_ReasonAdded )[i] = "Exploration"
		);
		If( sValue == "Replicate Best Training Run",
			Column( dt, Cst_Col_ReasonAdded )[i] = "Repeat Best"
		);
	);
	Column( dt, Cst_Col_ReasonAdded ) << Set Property(
		"Value Colors",
		{"Exploitation" = "BlueCyan", "Exploration" = "Red", "Historical" = "Black", "Repeat Best" = "Green", Color Cell by Value( 1 )}
	);
	dt << Color or Mark by Column( Column( dt, Cst_Col_ReasonAdded ), Color( 1 ), Marker( 0 ) );
	dt << End Data Update;

	Show( "O - Expr_BayesOpt" );
);

Expr_Run_Experiment = Expr(
	Show( "I - Expr_Run_Experiment" );
	
	// Get current row
	Wait( 0.1 );
	nCurRow = N Rows( dt );
	
	// For each response
	Lst_ResponsesColumns = dt << get column group( Cst_Col_Responses );
	For( i = 1, i <= N Items( Lst_ResponsesColumns ), i++, 
		// Store the result of the formula
		Eval( Eval Expr( nCurVal = Column( dt, Expr( "Pred Formula " || Char( Lst_ResponsesColumns[i] ) ) )[nCurRow] ) );
		Column( dt, Lst_ResponsesColumns[i] )[nCurRow] = nCurVal;
		
		// Update min/max values
		If( nCurVal < oAssArrayMin[Lst_ResponsesColumns[i]],
			oAssArrayMin[Lst_ResponsesColumns[i]] = nCurVal
		);
		If( nCurVal > oAssArrayMax[Lst_ResponsesColumns[i]],
			oAssArrayMax[Lst_ResponsesColumns[i]] = nCurVal
		);
	);
	
	// Color the row using Reason Added column coloring
	dt << Color or Mark by Column( Column( dt, Cst_Col_ReasonAdded ), Color( 1 ), Marker( 0 ) );
	
	Show( "O - Expr_Run_Experiment" );
);

// ===========================================================================================================================================================
// LAYOUT -- LAYOUT -- LAYOUT -- LAYOUT -- LAYOUT -- LAYOUT -- LAYOUT -- LAYOUT -- LAYOUT -- LAYOUT -- LAYOUT -- LAYOUT -- LAYOUT -- LAYOUT -- LAYOUT -- LAYOU
// ===========================================================================================================================================================

Expr_Build_Dashboard_Framework = Expr(
	Show( "I - Expr_Build_Dashboard_Framework" );
	
	Eval(
		Eval Expr(
			dash = New Window( "JMP",
				Outline Box( "Dashboard", Tab Box( tpb_dashboard = Tab Page Box( Title( "Bayesian Optimization Example" ) ) ) )
			);
			dash << Show Window( 0 );
		)
	);
	
	Show( "O - Expr_Build_Dashboard_Framework" );
);

Expr_Build_TabPageBox_Content = Expr(
	Show( "I - Expr_Build_TabPageBox_Content" );
	
	tpb_dashboard << Append(
		tpb_dashboard << Set Font Style( "Bold" );
		H Splitter Box(
			//Size( 1897, 871 ),
			<<Dockable( 1 ),
			<<Sizes( {0.80, 0.10, 0.10} ),
			V List Box(
				H List Box(
					Btn_NextRun = Button Box( "Next Run", Expr_BayesOpt ),
					Btn_Mode = Button Box( "Auto Mode",
						If( Btn_Mode << Get,
							Btn_Mode << Set Button Name( "Manual" ),
							Btn_Mode << Set Button Name( "Auto Mode" )
						)
					),
					Btn_RunExperiment = Button Box( "Run Experiment", Expr_Run_Experiment ),
					Btn_ResetTable = Button Box( "Reset", Expr_ResetTable ),
					Btn_AutoRunTillBest = Button Box( "Auto Run Till Best", Expr_AutoRunTillBestPoint )
				),
				olb_Dataset = Outline Box( "Dataset" )
			),
			V Splitter Box(
				//Size( 482, 871 ),
				<<Dockable( 1 ),
				<<Sizes( {0.7, 0.3} ),
				olb_Factors = Outline Box( "ScatterPlot 3D" ),
				tpb_Responses = Tab Page Box()
			),
			olb_BayesOpt = Outline Box( "Bayesian Optimization" )
		);
	);
	
	// Draw charts
	tpb_Responses << Title( "Responses vs. Iterations" ) << Icon( "GBElementLine" ) << Set Base Font( "Title" ) << Set Font Name( "Segoe UI" ) <<
	Set Font Style( "Bold" ) << Set Font Size( 12 ) << Moveable( 1 );
	tpb_Responses << append( olb_Responses = Outline Box( "Responses" ) );
	olb_Responses << append( Expr_Chart_Responses );
	olb_Factors << append( Expr_Chart_Factors );
	
	// Action buttons
	Btn_Mode << Style( "Toggle" );
	Btn_NextRun << set icon( "GBElementPoints" ) << set icon location( "left" );
	Btn_Mode << set icon( "PreviewPrevPage" ) << set icon location( "left" );
	Btn_RunExperiment << set icon( "JSLDebuggerPref" ) << set icon location( "left" );
	Btn_ResetTable << set icon( "Error" ) << set icon location( "left" );
	Btn_AutoRunTillBest << set icon( "PreviewPrevPage" ) << set icon location( "left" );
	olb_Dataset << append( dt2 = dt << New Data Box() );
	dt2 << Set Row ID Width( 50 );
	olb_BayesOpt << Close( 1 );
	
	Show( "O - Expr_Build_TabPageBox_Content" );
);  

// ===========================================================================================================================================================
// PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- PROGRAM -- P
// ===========================================================================================================================================================

Expr_ReadInputDataFromJMPTable;
Expr_ResetTable;
Expr_Build_Dashboard_Framework;
Expr_Build_TabPageBox_Content;
dash << Show Window( 1 );