934241_it-IT

liliconcom

Aggiungi linee verticali al Generatore di grafici nella casella di riepilogo H

CIAO,

Voglio inserire più grafici in un unico grafico e utilizzare il Generatore di Grafici insieme alle Caselle di Elenco V e H. Voglio aggiungere linee verticali ai grafici. Ho trovato l' esempio di @jthi , tuttavia ho problemi non appena ci sono più grafici.

L'esempio seguente funziona con un singolo grafico, ma quando rimuovo il commento dal secondo grafico, ottengo un asse aggiuntivo tra i grafici (vedi sotto). Come posso risolvere questo problema?

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

//gender_list = {"F", "M" };
gender_list = {"F"};

For( i = 1, i < N Items( gender_list ) + 1, i++,
	gender = gender_list[i];
	dt_gender = dt << Subset(
		Filtered Rows( :sex == gender ),
		Include All Columns//Name :sex 
		);
		
	Match ( gender,
		"F", data = Column ("height"),
		"M", data = Column ("weight")
	);
	
	Match ( gender,
		"F", ref_line = 60,
		"M", ref_line = 100
	);

	plot = New Window ( gender,
		H List Box(
			gb1 = dt_gender << Graph Builder(
				Size(529, 457),
				Show Control Panel(0),
				Variables(X(data)),
				Elements(Histogram(X, Legend(3)))
			),	
			axisbox = Report(gb1)[AxisBox(1)],
			axisbox << Add Ref Line(ref_line, "Dotted", red, gender, 2),
			/*gb2 = dt_gender << Graph Builder(
				Size(529, 457),
				Show Control Panel(0),
				Variables(X(data)),
				Elements(Histogram(X, Legend(3)))
			),	*/
			//axisbox = Report(gb2)[AxisBox(1)],
			//axisbox << Add Ref Line(ref_line, "Dotted", red, gender, 2),
		),
	);
);

Automazione e scriptingEsplorazione e visualizzazione dei datiRe: Aggiungi linee verticali a Graph Builder nella casella di riepilogo H

In una nuova finestra è possibile elencare diversi oggetti di visualizzazione separandoli con virgole:

gb = graph Box ();
new window("test",
Text Box ("Hello"),
gb [Axis Box (2)]
)

crea una nuova finestra con la casella di testo e una casella Asse.

Se vuoi aggiungere dei "comandi" a questo elenco, devi "chiudere" i comandi con ";".

Nel tuo caso è:

Scopri di più...

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

//gender_list = {"F", "M" };
gender_list = {"F"};

For( i = 1, i < N Items( gender_list ) + 1, i++,
	gender = gender_list[i];
	dt_gender = dt << Subset(
		Filtered Rows( :sex == gender ),
		Include All Columns//Name :sex 
		);
		
	Match ( gender,
		"F", data = Column ("height"),
		"M", data = Column ("weight")
	);
	
	Match ( gender,
		"F", ref_line = 60,
		"M", ref_line = 100
	);

	plot = New Window ( gender,
		H List Box(
			gb1 = dt_gender << Graph Builder(
				Size(529, 457),
				Show Control Panel(0),
				Variables(X(data)),
				Elements(Histogram(X, Legend(3)))
			),	
			axisbox = Report(gb1)[AxisBox(1)];
			axisbox << Add Ref Line(ref_line, "Dotted", red, gender, 2);
			gb2 = dt_gender << Graph Builder(
				Size(529, 457),
				Show Control Panel(0),
				Variables(X(data)),
				Elements(Histogram(X, Legend(3)))
			),	
			axisbox = Report(gb2)[AxisBox(1)];
			axisbox << Add Ref Line(ref_line, "Dotted", red, gender, 2);
		),
	);
);

.

Re: Aggiungi linee verticali a Graph Builder nella casella di riepilogo H

Ho provato ad aggiungere uno screenshot, ma la funzione Copia/Incolla sembra ancora non funzionare nella Community
@Ryan_Gilmore ?

Re: Aggiungi linee verticali a Graph Builder nella casella di riepilogo H

Suggerirei di spostare il codice aggiungendo linee di riferimento all'esterno della Nuova finestra, poiché è più facile (a mio parere) aggiornarlo e modificarlo (puoi anche fare come ha suggerito hogi).

Ecco un'idea iniziale di come scriverei questo (non tutte queste sono tecniche di base, ma possono dare qualche idea su cosa si può fare)

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

plot_width = 400;
plot_height = 300;

aa_genders = Associative Array();
aa_genders["F"] = ["data" => "height", "ref_line" => 60];
aa_genders["M"] = ["data" => "weight", "ref_line" => 100];


For Each({{cur_gender, specs}}, aa_genders,
	dt_gender = dt << Subset(
		Filtered Rows(:sex == cur_gender),
		Include All Columns,
		Invisible
	);
	
	hlb = H List Box(
		gb1 = dt_gender << Graph Builder(
			Size(plot_width, plot_height),
			Show Control Panel(0),
			Variables(X(Eval(specs["data"]))),
			Elements(Histogram(X, Legend(3)))
		),
		gb2 = dt_gender << Graph Builder(
			Size(plot_width, plot_height),
			Show Control Panel(0),
			Variables(X(Eval(specs["data"]))),
			Elements(Histogram(X, Legend(3)))
		)
	);
	
	axisbox = Report(gb1)[AxisBox(1)];
	axisbox << Add Ref Line(specs["ref_line"], "Dotted", red, cur_gender, 2);
	
	axisbox = Report(gb2)[AxisBox(1)];
	axisbox << Add Ref Line(specs["ref_line"], "Dotted", red, cur_gender, 2);

	aa_genders[cur_gender]["dt"] = dt_gender;
	aa_genders[cur_gender]["report"] = New Window(cur_gender,
		hlb
	);
);