926367_zh-TW

liliconcom

將圖表以相同的比例和解析度匯出為 PPT 文件

你好，

我想用 JSL 產生報告（.ppt）。

我想匯出 2 個圖表：5 個組別和 3 組。

我希望每組的大小是 250*250，所以 5 組圖應該是 1250*250，3 組圖應該是 750*250。

我使用“儲存簡報”功能匯出圖表。

5組圖的大小與我手動匯出的圖的大小相同，但3組圖的大小不同。 3組圖的大小被壓縮了，只有75%。

如何匯出多個比例尺和解析度相同的圖表？

NonLeakage_graph = dt << Graph Builder(
	Size( 1250, 250 ),
	Variables( X( :Lot ), Y( :drift% ), Group X( :Label ), Color( :Lot ) ),
	Elements( Box Plot( X, Y, Legend( 1 ) ) ),
	By( :Rel_Test ),
	SendToReport(
		Dispatch( {}, "drift%", ScaleBox,
			{Format( "Percent", 12, 0 ), Min( -0.25 ), Max( 0.25 ), Inc( 0.05 ), 
			 Minor Ticks( 0 ), Add Ref Line( 0.2, "Solid", "Red", "20%", 1 ),
			 Add Ref Line( -0.2, "Solid", "Red", "-20%", 1 )}
		)
	)
);


NonLeakage = NonLeakage_graph << Report;
save_path = "D:\Reliability Qual\reliability report template\jmp_example.pptx";


For( i = 1, i <= N Items( NonLeakage ), i++,
	If( File Exists( save_path ),
		NonLeakage[i] << Save Presentation( save_path, Append );
	,
		NonLeakage[i] << Save Presentation( save_path );
	)
);
NonLeakage << Close Window;


dt << Clear Row States; 
dt << Select Where( (Contains( {"0cyc", "0hrs"}, :ReadPoint )) | (!Contains( {"IGSS", "IGSSR", "IDSS"}, :Label )) );
dt << Hide( 1 ) << Exclude( 1 ); 
dt << Clear Selection;

dt << Select Where( (!Contains( {"0cyc", "0hrs"}, :ReadPoint )) & (Contains( {"IGSS", "IGSSR", "IDSS"}, :Label )) );

Summarize( dt, l_groups = By( :Rel_Test ) );

Leakage_graph=dt << Graph Builder(
	SendToByGroup( {:Rel_Test == "H3TRB"} ),
	Size( 750, 250 ),
	Variables( X( :Lot ), Y( :drift% ), Group X( :Label ), Color( :Lot ) ),
	Elements( Box Plot( X, Y, Legend( 1 ) ) ),
	By( :Rel_Test ),
		SendToReport(
			Dispatch( {}, "drift%", ScaleBox,
				{Format( "Fixed Dec", 12, 0 ), Min( 0 ), Max( 20 ), Inc( 5 ),
				Minor Ticks( 0 ), Add Ref Line( 10, "Solid", "Red", "10", 1 )}
			)
		)
	);

Leakage = Leakage_graph << Report;
Leakage << Save Presentation( "D:\Reliability Qual\reliability report template\jmp_example.pptx",append );

自動化和腳本編寫數據探索與視覺化回覆：將圖表以相同的比例和解析度匯出到 PPT

問題：
如何控制 FrameBox 的大小？
https://community.jmp.com/t5/Discussions/Graph-builder-Frame-size-JSL/mp/702694/highlight/true#M88706

有一個願望：
能夠產生具有特定繪圖大小的圖表的功能

點讚數表示大家強烈要求解決這個問題。

回覆：將圖表以相同的比例和解析度匯出到 PPT

你好呀，

這樣行不通。在JMP裡一切看起來都正常，但匯出到PPT後，圖表的比例尺就不一樣了。

回覆：將圖表以相同的比例和解析度匯出到 PPT

嗨@LT ，

你說的好像沒錯。但是，問題並不像我想的那樣。
借助第一個連結中的提示，你可以取得很多成就——甚至比我寫第一條回覆時想像的還要多。

這段程式碼會建立符合指定比例的圖表：
三個幀，尺寸分別為 250x250 和 750x250
以及 5 個 250x250 -> 1250x250 的幀。

將圖形複製到剪貼簿並貼上到圖形程式中後，可以看到所有子圖的大小都相同。

程式碼也指出了實際問題所在：

無論 PNG 或 JPG 影像的大小如何，都可以根據一些隱藏的規則在簡報中進行縮放。
我擔心「儲存簡報」功能不允許使用者調整這些規則。

解決方法：您可以使用腳本（例如透過 JMP 中的 Python 介面）來指定簡報中插入的圖形的大小和位置。

或者，您也可以發送電子郵件至 support@jmp.com以獲得更多建議。
或許在「儲存簡報」中有一個隱藏設定…

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class Families.jmp" );
 fn = "$TEMP/jmp_example.pptx"
biv = bivariate( y( :weight ), x( :height ) );
rbiv = biv << report;
rbiv << Save Presentation(fn );

For each( {selection}, {{13, 14, 15}, {13, 14, 15, 16, 17}},
	Eval(
		Eval Expr(
			gb = Graph Builder(
				Fit to Window( "Off" ),
				Variables(
					X( :height ),
					Y( :weight ),
					Group X( :age ),
					Overlay( :age )
				),
				Elements(
					Points( X, Y ),
					Smoother( X, Y )
				),
				Local Data Filter(
					Conditional,
					Add Filter(
						columns( :age ),
						Where( :age == Expr( selection ) )
					)
				)
	
			)
		)
	);

	fb = Report( gb )[FrameBox( 1 )];
	fb << Frame size( 250, 250 );
// show(fb << get size);
	gb << save presentation( fn, Append );
);

Web( fn );