926367_es-ES

liliconcom

exportar gráficos a PPT con la misma escala y resolución

Hola,

Quiero JSL para generar un informe (.ppt).

Hay 2 parcelas que quiero exportar: 5 grupos y 3 grupos.

Quiero que cada grupo tenga 250*250, por lo que la gráfica de 5 grupos debe ser 1250*250 y la gráfica de 3 grupos debe ser 750*250.

Utilizo Guardar presentación para exportar gráficos.

El tamaño de 5 grupos es el mismo que el de los gráficos exportados manualmente, pero el de 3 grupos no. El tamaño de 3 grupos es reducido, solo al 75 %.

¿Cómo puedo exportar varios gráficos con la misma escala y resolución?

NonLeakage_graph = dt << Graph Builder(
	Size( 1250, 250 ),
	Variables( X( :Lot ), Y( :drift% ), Group X( :Label ), Color( :Lot ) ),
	Elements( Box Plot( X, Y, Legend( 1 ) ) ),
	By( :Rel_Test ),
	SendToReport(
		Dispatch( {}, "drift%", ScaleBox,
			{Format( "Percent", 12, 0 ), Min( -0.25 ), Max( 0.25 ), Inc( 0.05 ), 
			 Minor Ticks( 0 ), Add Ref Line( 0.2, "Solid", "Red", "20%", 1 ),
			 Add Ref Line( -0.2, "Solid", "Red", "-20%", 1 )}
		)
	)
);


NonLeakage = NonLeakage_graph << Report;
save_path = "D:\Reliability Qual\reliability report template\jmp_example.pptx";


For( i = 1, i <= N Items( NonLeakage ), i++,
	If( File Exists( save_path ),
		NonLeakage[i] << Save Presentation( save_path, Append );
	,
		NonLeakage[i] << Save Presentation( save_path );
	)
);
NonLeakage << Close Window;


dt << Clear Row States; 
dt << Select Where( (Contains( {"0cyc", "0hrs"}, :ReadPoint )) | (!Contains( {"IGSS", "IGSSR", "IDSS"}, :Label )) );
dt << Hide( 1 ) << Exclude( 1 ); 
dt << Clear Selection;

dt << Select Where( (!Contains( {"0cyc", "0hrs"}, :ReadPoint )) & (Contains( {"IGSS", "IGSSR", "IDSS"}, :Label )) );

Summarize( dt, l_groups = By( :Rel_Test ) );

Leakage_graph=dt << Graph Builder(
	SendToByGroup( {:Rel_Test == "H3TRB"} ),
	Size( 750, 250 ),
	Variables( X( :Lot ), Y( :drift% ), Group X( :Label ), Color( :Lot ) ),
	Elements( Box Plot( X, Y, Legend( 1 ) ) ),
	By( :Rel_Test ),
		SendToReport(
			Dispatch( {}, "drift%", ScaleBox,
				{Format( "Fixed Dec", 12, 0 ), Min( 0 ), Max( 20 ), Inc( 5 ),
				Minor Ticks( 0 ), Add Ref Line( 10, "Solid", "Red", "10", 1 )}
			)
		)
	);

Leakage = Leakage_graph << Report;
Leakage << Save Presentation( "D:\Reliability Qual\reliability report template\jmp_example.pptx",append );

Automatización y scriptingExploración y visualización de datosRe: exportar gráficos a PPT con la misma escala y resolución

El problema:
¿Cómo controlar el tamaño del FrameBox?
https://community.jmp.com/t5/Discussions/Graph-builder-Frame-size-JSL/mp/702694/highlight/true#M88706

Hay un deseo:
Funcionalidad para generar Parcelas con Tamaño de Parcela Específico

La cantidad de Kudos indica una fuerte demanda para solucionar el problema.

Re: exportar gráficos a PPT con la misma escala y resolución

Hola,

Esto no funciona. Todo se ve bien en JMP, pero después de exportar a PPT, las escalas de los gráficos son diferentes.

Re: exportar gráficos a PPT con la misma escala y resolución

Hola @LT ,

Parece que tienes razón. Sin embargo, el problema no está donde yo creía.
Con los consejos del primer enlace puedes lograr mucho, incluso más de lo que creía posible cuando escribí mi primera respuesta.

Este código crea gráficos con las proporciones solicitadas:
Tres marcos con 250x250 -> 750x250
y cinco cuadros con 250x250 -> 1250x250.

Cuando copia los gráficos al portapapeles y los pega en un programa de gráficos, puede ver que todos los subgráficos tienen el mismo tamaño.

El código también apunta al problema real:

Independientemente del tamaño de la imagen PNG o JPG, se puede escalar en la presentación de acuerdo con algunas reglas ocultas.
Temo que la función << guardar presentación no permita al usuario ajustar estas reglas.

Una solución alternativa: puede utilizar scripts (por ejemplo, a través de la interfaz Python en JMP) para especificar el tamaño y la posición de los gráficos insertados en la presentación.

Alternativamente, puede enviar un correo electrónico a support@jmp.com para obtener más sugerencias.
Quizás haya una configuración oculta en << guardar presentación ...

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class Families.jmp" );
 fn = "$TEMP/jmp_example.pptx"
biv = bivariate( y( :weight ), x( :height ) );
rbiv = biv << report;
rbiv << Save Presentation(fn );

For each( {selection}, {{13, 14, 15}, {13, 14, 15, 16, 17}},
	Eval(
		Eval Expr(
			gb = Graph Builder(
				Fit to Window( "Off" ),
				Variables(
					X( :height ),
					Y( :weight ),
					Group X( :age ),
					Overlay( :age )
				),
				Elements(
					Points( X, Y ),
					Smoother( X, Y )
				),
				Local Data Filter(
					Conditional,
					Add Filter(
						columns( :age ),
						Where( :age == Expr( selection ) )
					)
				)
	
			)
		)
	);

	fb = Report( gb )[FrameBox( 1 )];
	fb << Frame size( 250, 250 );
// show(fb << get size);
	gb << save presentation( fn, Append );
);

Web( fn );