923117_zh-TW

liliconcom

如何使用 JMP 中的 JSL 實現遊標指向網頁上顯示內容的效果？

感謝各位專家！

http://worldmap.ifnews.com/chinamap/china/fmap

h = [=>];
h["User-Agent"] = "Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/143.0.0.0 Safari/537.36";
h["Accept"] = "application/json, text/javascript, */*; q=0.01";
h["Referer"] = "http://worldmap.ifnews.com/chinamap/china/fmap";
h["X-Requested-With"] = "XMLHttpRequest";
u = "http://worldmap.ifnews.com/chinamap/china/financialData?type=all";
rs = New HTTP Request(URL(u), Method("GET"), Headers(h));
rr = rs << Send;
If( !Is Missing( rr ),
	txt = Blob To Char( rr );
	dt = JSON To Data Table( txt );
	dt << Set Name( "map" );
	dt:price << Data Type( Numeric ) << Modeling Type( Continuous );
	dt:priceLimit << Data Type( Numeric ) << Modeling Type( Continuous );
	dt:changeAmount << Data Type( Numeric ) << Modeling Type( Continuous );
	dt:countryCName << Set Property( "Map Role", {Map Role( NameName, Map Name( "World", "Countries" ) )} );
	dt << Graph Builder(
		Size( 800, 600 ),
		Show Control Panel( 0 ),
		Variables( Shape( :countryCName ), Color( :priceLimit ) ),
		Elements( Map Shapes( Legend( 5 ) ) ),
		SendToReport(
			Dispatch(
				{},
				"400",
				ScaleBox,
				{Legend Model(
					5,
					Properties(
						0,
						{gradient(
							{Color Theme( "Red to Green" ), 
							Reverse Gradient( 1 )} 
						)},
						Item ID( "priceLimit", 1 )
					)
				)}
			)
		)
	);
);

自動化和腳本編寫回覆：MP軟體的JSL如何在網頁上實現這種效果

哪種效果？哪些網頁？

回覆：MP軟體的JSL如何在網頁上實現這種效果

如何使用 JMP 中的 JSL 實現遊標指向網頁上顯示內容的效果？
http://worldmap.ifnews.com/chinamap/china/fmap

當遊標指向地圖上的某個國家範圍時，就會彈出資料。
謝謝！

回覆：MP軟體的JSL如何在網頁上實現這種效果

在 JMP 中，此功能是透過懸停標籤實現的：

如果您需要更快的更新速度，並且可能不喜歡懸停標籤框的外觀，那麼您可以使用捕鼠器。
更多詳情請參閱@Craige_Hales對類似問題的回答：
https://community.jmp.com/t5/Discussions/Can-JMP-graphics-have-this-effect/mp/810221/highlight/true#M99217

回覆：MP軟體的JSL如何在網頁上實現這種效果

或者，您可以編輯 HoverLabel 的「圖片」腳本，以觸發您想要的任何動作：

打開網頁
- 在圖表中顯示更多信息
- 另開一個地塊…

更多詳情請見此貼文：
回覆：滑鼠懸停時的操作？ - 使用修飾鍵：backhand_index_pointing_right::white_square_button:

這種方法的優點：
懸停標籤能夠識別滑鼠目前所在國家/地區，無需查找：

:Country[local:_firstrow]

回覆：MP軟體的JSL如何在網頁上實現這種效果

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/World Demographics.jmp" );

mapxy = Open( "$MAPS/World-XY.jmp" );
mapname = Open( "$MAPS/World-Name.jmp" );
mapname << New Column( "X", Format( "Longitude DDD", "PUNDIR", 14, 4 ) );
mapname << New Column( "Y", Format( "Latitude DDD", "PUNDIR", 14, 4 ) );

For Each( {rw}, Index( 1, N Rows( mapname ) ),
	shapeID = mapName:ShapeID[rw];
	rws = mapxy << get rows where( :ShapeID == shapeID & :PartID == 1 );
	xs = mapxy[rws, "X"];
	ys = mapxy[rws, "Y"];
	{x, y} = Polygon Centroid( xs, ys );
	mapname:x[rw] = x;
	mapname:y[rw] = y;
);

dt << Update( With( mapname ), Match Columns( :Territory = :Region ), Add Columns from Update Table( :X, :Y ) );

New Namespace(
	"hover"
);
hover:GDP = 0;
hover:x = 0;
hover:y = 0;
gb = Graph Builder(
	Variables( Color( :GDP per Capita ), Shape( :Territory ) ),
	Elements( Map Shapes() ),
	SendToReport(
		Dispatch( {}, "", ScaleBox,
			{Format( "Longitude DDD", "PUNDIR", 16 ), Min( 0 ), Max( 30 )}
		),
		Dispatch( {}, "", ScaleBox( 2 ),
			{Format( "Latitude DDD", "PUNDIR", 16, 0 ), Min( 40 ), Max( 50 )}
		),
		Dispatch( {}, "Graph Builder", FrameBox,
			{Set Graphlet(
				Picture(
					hover:GDP = :GDP per Capita[local:_firstrow];
					hover:x = :X[local:_firstrow];
					hover:y = :y[local:_firstrow];
//approach1: select the current country and trigger an update -> nice, but draggy
//local:_dataTable << Clear Select << select rows(local:_firstrow);
					gb << inval;
					gb << updatewindow;

		
				)
			)}
		)
	)
);

fb1 = Report( gb )[FrameBox( 1 )];
fb1 << addgraphicsscript(
	x = hover:x;
	y = hover:y;
	Text( center justified, {hover:x, hover:y}, "GDP:  " || Char( Round( hover:GDP ) ) );
);

懸停標籤是否知道滑鼠的目前位置？
遺憾的是，本地:_xaxis/_yaxis=0 。

作為一種變通方法，我採用了這種方法。
https://community.jmp.com/t5/Discussions/exporting-x-amp-y-values-coordinates-from-graph-builder-once-jmp/mp/193660/highlight/true#M41407 @johnmoore計算國家的質心 - 顯示 GDP。

作為替代方案，可以使用 Mousetrap（除了 Hover Label 變通方法之外）來取得滑鼠的位置。
缺點：互動性較差，因為使用者必須按下滑鼠按鈕。

回覆：MP軟體的JSL如何在網頁上實現這種效果

感謝各位專家！