917797_es-ES

liliconcom

Cómo mostrar múltiples estadísticas de resumen en un gráfico para un único conjunto de puntos

Hola,

Estoy construyendo un gráfico usando un diagrama disperso.

Mis puntos se basan en las estadísticas "medias".

Me gustaría agregar etiquetas de estadísticas "media" y "N" a los mismos puntos.

Dado que la escala es muy diferente entre "media" y "N", agregar un segundo conjunto de los mismos puntos al gráfico oculta todas las diferencias de las estadísticas de "media".

¿Cómo puedo mostrar ambas estadísticas en el único conjunto de puntos "medios"?

Espero no tener que usar un script JSL si hay una forma sencilla de hacer esto.

Si tuviera que escribir un script, probé esto, pero las etiquetas "N" nunca aparecen, mientras que las etiquetas "medias" aparecen como se esperaba.

¿Puede alguien ayudar?

¡Muchas gracias!

Graph Builder(
	Variables( X( :p ), Y( :a ) ),
	Elements(
		Points(
			X,
			Y,
			Legend( 5 ),
			Summary Statistic( "Mean" ),
			Marker Size( 8 ),
			Marker Color( "Medium Blue" ),
			Label( "Label by Value" ),

		)
	),
	Elements(
		Text(
			X,
			Y,
			Summary Statistic( "N" ),
			Label( "Name and Value" ),
			Jitter( 0 ),
			Label Justification( "Right" ),
			Set Font Style( "Bold" ),
			Set Font Size( 12 )
		)
	),
	SendToReport( Dispatch( {}, "Graph Builder", OutlineBox, {Set Title( "Mean Points with N Labels" )} ) )
);

Edición de txnelson: se movió el código al cuadro de visualización JSL

Exploración y visualización de datosRe: Cómo mostrar múltiples estadísticas de resumen en un gráfico para un único conjunto de puntos

¿Qué tal el título/gráfico por factor?

Names Default to Here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Graph Builder(
	Size( 643, 335 ),
	Graph Spacing( 4 ),
	Variables( X( :age ), Y( :height ) ),
	Elements(
		Points( X, Y, Legend( 4 ), Summary Statistic( "Mean" ) ),
		Caption Box(
			X,
			Y,
			Legend( 5 ),
			Summary Statistic( "Mean" ),
			Summary Statistic 2( "N" ),
			Location( "Graph per factor" )
		)
	)
);

Re: Cómo mostrar múltiples estadísticas de resumen en un gráfico para un único conjunto de puntos

Utilice una columna para crear la etiqueta y úsela como Columna de forma

Names Default to Here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Column( "label",
	Character,
	Formula(
		Char( Round( Col Mean( :height, :age ) ) ) || "
" ||
		Char( Col Number( :height, :age ) )
	)
);

Graph Builder(
	Variables( X( :age ), Y( :height ) ),
	Elements(
		Points(
			X,
			Y,
			Legend( 3 ),
			Summary Statistic( "Mean" ),
			Set Shape Column( :label )
		),
		Points( X, Y, Legend( 4 ), Summary Statistic( "Mean" ) )
	),
	SendToReport(
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				4,
				Properties( 0, {Marker( "Circle" ), Marker Size( 30 )}, Item ID( "Mean", 1 ) )
			)}
		)
	)
);

Re: Cómo mostrar múltiples estadísticas de resumen en un gráfico para un único conjunto de puntos

Puedes apilar diferentes tipos de marcadores, como Barra/Flotante, Círculo y marcador con forma de marcador:
N: dentro del círculo
significa: a la derecha

Re: Cómo mostrar múltiples estadísticas de resumen en un gráfico para un único conjunto de puntos

¡Muchas gracias, hogi!

¡Esto es exactamente como lo imaginé!

¡¡¡Me alegraste el día!!!