917797_it-IT

liliconcom

Come mostrare più statistiche di riepilogo in un grafico per un singolo set di punti

CIAO,

Sto costruendo un grafico utilizzando un diagramma sparso.

I miei punti si basano sulle statistiche "medie".

Vorrei aggiungere le etichette delle statistiche "media" e "N" agli stessi punti.

Poiché la scala è molto diversa tra "media" e "N", l'aggiunta di un secondo set di punti uguali al grafico nasconde tutte le differenze delle statistiche "medie".

Come posso mostrare entrambe le statistiche al singolo set di punti "medi"?

Spero di non dover usare uno script JSL se esiste un modo semplice per farlo.

Se devo scrivere uno script, ho provato questo, ma le etichette "N" non vengono mai visualizzate, mentre le etichette "mean" vengono visualizzate come previsto.

Qualcuno può aiutare?

Grazie mille!

Graph Builder(
	Variables( X( :p ), Y( :a ) ),
	Elements(
		Points(
			X,
			Y,
			Legend( 5 ),
			Summary Statistic( "Mean" ),
			Marker Size( 8 ),
			Marker Color( "Medium Blue" ),
			Label( "Label by Value" ),

		)
	),
	Elements(
		Text(
			X,
			Y,
			Summary Statistic( "N" ),
			Label( "Name and Value" ),
			Jitter( 0 ),
			Label Justification( "Right" ),
			Set Font Style( "Bold" ),
			Set Font Size( 12 )
		)
	),
	SendToReport( Dispatch( {}, "Graph Builder", OutlineBox, {Set Title( "Mean Points with N Labels" )} ) )
);

txnelson modifica: spostato il codice nella casella di visualizzazione JSL

Esplorazione e visualizzazione dei datiRe: Come mostrare più statistiche riassuntive in un grafico per un singolo set di punti

Che ne dici di Didascalia/Grafico per fattore?

Names Default to Here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Graph Builder(
	Size( 643, 335 ),
	Graph Spacing( 4 ),
	Variables( X( :age ), Y( :height ) ),
	Elements(
		Points( X, Y, Legend( 4 ), Summary Statistic( "Mean" ) ),
		Caption Box(
			X,
			Y,
			Legend( 5 ),
			Summary Statistic( "Mean" ),
			Summary Statistic 2( "N" ),
			Location( "Graph per factor" )
		)
	)
);

Re: Come mostrare più statistiche riassuntive in un grafico per un singolo set di punti

Utilizzare una colonna per creare l'etichetta e utilizzarla come colonna di forma

Names Default to Here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Column( "label",
	Character,
	Formula(
		Char( Round( Col Mean( :height, :age ) ) ) || "
" ||
		Char( Col Number( :height, :age ) )
	)
);

Graph Builder(
	Variables( X( :age ), Y( :height ) ),
	Elements(
		Points(
			X,
			Y,
			Legend( 3 ),
			Summary Statistic( "Mean" ),
			Set Shape Column( :label )
		),
		Points( X, Y, Legend( 4 ), Summary Statistic( "Mean" ) )
	),
	SendToReport(
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				4,
				Properties( 0, {Marker( "Circle" ), Marker Size( 30 )}, Item ID( "Mean", 1 ) )
			)}
		)
	)
);

Re: Come mostrare più statistiche riassuntive in un grafico per un singolo set di punti

puoi impilare diversi tipi di marcatori, come Barra/Float, Cerchio e marcatore con forma di marcatore:
N: dentro il cerchio
significa: a destra

Re: Come mostrare più statistiche riassuntive in un grafico per un singolo set di punti

Grazie mille, hogi!

È esattamente come lo avevo immaginato!

Mi hai rallegrato la giornata!!!