916315_zh-TW

liliconcom

我正在根據用戶輸入生成一個新列，需要將其移動。

我正在根據用戶輸入生成一個新列，需要使用腳本來移動它。請問有人可以幫我修改一下腳本嗎？

dt << New Column("Suspected "|| selectedCol,
	Formula(
		If(Contains(myValueList, char(as column(selectedCol))), 
			"Yes", 
			"No" 
		)
	)
);
Data Table( dt ) << Move Selected Columns( as column("Suspected "|| selectedCol), after( as column(selectedCol) ) );

基礎資料分析與建模回覆：我正在根據用戶輸入生成一個新列，需要將其移動

我透過將 As Column() 函數封裝在 Name Expr() 函數中，並將其放入清單中，使其能夠正常工作。

dt << Move Selected Columns(
	{Name Expr( As Column( "Suspected " || selectedCol ) )},
	After( As Column( selectedCol ) )
);

回覆：我正在根據用戶輸入生成一個新列，需要將其移動

這種方法也有效，只需將字串放在清單中，但 After() 必須有 As Column()。

dt << Move Selected Columns(
	{"Suspected " || selectedCol},
	After( As Column( selectedCol ) )
);

回覆：我正在根據用戶輸入生成一個新列，需要將其移動

以下是我讓它正常工作的方法。

dt << New Column( "Suspected " || selectedCol,
	Character,
	Formula(
		If( Contains( myValueList, Char( As Column( selectedCol ) ) ),
			"Yes",
			"No"
		)
	)
);
Eval(
	Parse(
		"dt << Move Selected Columns(:Suspected " || selectedCol || ", after( :" ||
		selectedCol || ") );"
	)
);

回覆：我正在根據用戶輸入生成一個新列，需要將其移動

我強烈建議您在列中新增表達式求值功能，以避免可能出現的問題（請比較我的公式和您的公式）。您也可以取得已建立列的引用，並將其與 < 一起使用。 <>

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

selectedCol = "age";
myValueList = {"12", "15"};

newcol = Eval(EvalExpr(
	dt << New Column("Suspected "|| selectedCol, Character, Nominal, Formula(
		If(Contains(Expr(myValueList), Char(Expr(NameExpr(As column(dt, selectedCol))))),
			"Yes", 
			"No"
		)
	));
));

dt << Move Selected Columns(
	newcol, After(Eval(selectedCol))
);