916315_zh-CN

liliconcom

我正在根据用户输入生成一个新列，需要将其移动。

我正在根据用户输入生成一个新列，需要使用脚本来移动它。请问有人可以帮我修改一下脚本吗？

dt << New Column("Suspected "|| selectedCol,
	Formula(
		If(Contains(myValueList, char(as column(selectedCol))), 
			"Yes", 
			"No" 
		)
	)
);
Data Table( dt ) << Move Selected Columns( as column("Suspected "|| selectedCol), after( as column(selectedCol) ) );

基础数据分析与建模回复：我正在根据用户输入生成一个新列，需要将其移动

我通过将 As Column() 函数封装在 Name Expr() 函数中，并将其放入列表中，使其能够正常工作。

dt << Move Selected Columns(
	{Name Expr( As Column( "Suspected " || selectedCol ) )},
	After( As Column( selectedCol ) )
);

回复：我正在根据用户输入生成一个新列，需要将其移动

这种方法也有效，只需将字符串放在列表中，但 After() 必须有 As Column()。

dt << Move Selected Columns(
	{"Suspected " || selectedCol},
	After( As Column( selectedCol ) )
);

回复：我正在根据用户输入生成一个新列，需要将其移动

以下是我让它正常工作的方法。

dt << New Column( "Suspected " || selectedCol,
	Character,
	Formula(
		If( Contains( myValueList, Char( As Column( selectedCol ) ) ),
			"Yes",
			"No"
		)
	)
);
Eval(
	Parse(
		"dt << Move Selected Columns(:Suspected " || selectedCol || ", after( :" ||
		selectedCol || ") );"
	)
);

回复：我正在根据用户输入生成一个新列，需要将其移动

我强烈建议您在列中添加表达式求值功能，以避免可能出现的问题（请对比我的公式和您的公式）。您还可以获取对已创建列的引用，并将其与 < 一起使用。 <>

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

selectedCol = "age";
myValueList = {"12", "15"};

newcol = Eval(EvalExpr(
	dt << New Column("Suspected "|| selectedCol, Character, Nominal, Formula(
		If(Contains(Expr(myValueList), Char(Expr(NameExpr(As column(dt, selectedCol))))),
			"Yes", 
			"No"
		)
	));
));

dt << Move Selected Columns(
	newcol, After(Eval(selectedCol))
);