916315_it-IT

liliconcom

Sto generando una nuova colonna in base a un input utente e ho bisogno di spostarla

Sto generando una nuova colonna in base a un input utente e ho bisogno di spostarla tramite script. Qualcuno può aiutarmi a correggere il mio script?

dt << New Column("Suspected "|| selectedCol,
	Formula(
		If(Contains(myValueList, char(as column(selectedCol))), 
			"Yes", 
			"No" 
		)
	)
);
Data Table( dt ) << Move Selected Columns( as column("Suspected "|| selectedCol), after( as column(selectedCol) ) );

Analisi e modellazione dei dati di baseRe: Sto generando una nuova colonna in base a un input utente e ho bisogno di spostarla

Sono riuscito a farlo funzionare racchiudendo As Column() in un Name Expr() e inserendolo in un elenco.

dt << Move Selected Columns(
	{Name Expr( As Column( "Suspected " || selectedCol ) )},
	After( As Column( selectedCol ) )
);

Re: Sto generando una nuova colonna in base a un input utente e ho bisogno di spostarla

Questo metodo funziona anche solo con la stringa in un elenco, ma After() deve avere As Column().

dt << Move Selected Columns(
	{"Suspected " || selectedCol},
	After( As Column( selectedCol ) )
);

Re: Sto generando una nuova colonna in base a un input utente e ho bisogno di spostarla

Ecco come l'ho fatto funzionare

dt << New Column( "Suspected " || selectedCol,
	Character,
	Formula(
		If( Contains( myValueList, Char( As Column( selectedCol ) ) ),
			"Yes",
			"No"
		)
	)
);
Eval(
	Parse(
		"dt << Move Selected Columns(:Suspected " || selectedCol || ", after( :" ||
		selectedCol || ") );"
	)
);

Re: Sto generando una nuova colonna in base a un input utente e ho bisogno di spostarla

Ti consiglio vivamente di aggiungere la valutazione dell'espressione alla tua colonna per evitare possibili problemi (confronta l'aspetto della mia formula con quello della tua). Puoi anche ottenere un riferimento alla colonna creata e utilizzarlo con < <>

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

selectedCol = "age";
myValueList = {"12", "15"};

newcol = Eval(EvalExpr(
	dt << New Column("Suspected "|| selectedCol, Character, Nominal, Formula(
		If(Contains(Expr(myValueList), Char(Expr(NameExpr(As column(dt, selectedCol))))),
			"Yes", 
			"No"
		)
	));
));

dt << Move Selected Columns(
	newcol, After(Eval(selectedCol))
);