916315_de-DE

liliconcom

Ich generiere eine neue Spalte basierend auf einer Benutzereingabe und muss diese verschieben.

Ich generiere eine neue Spalte basierend auf einer Benutzereingabe und muss diese Spalte per Skript verschieben. Kann mir jemand bei der Fehlerbehebung in meinem Skript helfen?

dt << New Column("Suspected "|| selectedCol,
	Formula(
		If(Contains(myValueList, char(as column(selectedCol))), 
			"Yes", 
			"No" 
		)
	)
);
Data Table( dt ) << Move Selected Columns( as column("Suspected "|| selectedCol), after( as column(selectedCol) ) );

Grundlagen der Datenanalyse und ModellierungBetreff: Ich generiere eine neue Spalte basierend auf einer Benutzereingabe und muss diese verschieben.

Ich kann es zum Laufen bringen, indem ich As Column() in einen Name Expr() einschließe und ihn in eine Liste einfüge.

dt << Move Selected Columns(
	{Name Expr( As Column( "Suspected " || selectedCol ) )},
	After( As Column( selectedCol ) )
);

Betreff: Ich generiere eine neue Spalte basierend auf einer Benutzereingabe und muss diese verschieben.

Diese Methode funktioniert auch, wenn nur die Zeichenkette in einer Liste vorhanden ist, aber die After()-Funktion muss As Column() enthalten.

dt << Move Selected Columns(
	{"Suspected " || selectedCol},
	After( As Column( selectedCol ) )
);

Betreff: Ich generiere eine neue Spalte basierend auf einer Benutzereingabe und muss diese verschieben.

So habe ich es zum Laufen gebracht

dt << New Column( "Suspected " || selectedCol,
	Character,
	Formula(
		If( Contains( myValueList, Char( As Column( selectedCol ) ) ),
			"Yes",
			"No"
		)
	)
);
Eval(
	Parse(
		"dt << Move Selected Columns(:Suspected " || selectedCol || ", after( :" ||
		selectedCol || ") );"
	)
);

Betreff: Ich generiere eine neue Spalte basierend auf einer Benutzereingabe und muss diese verschieben.

Ich empfehle dringend, Ihrer Spalte eine Formelauswertung hinzuzufügen, um mögliche Probleme zu vermeiden (vergleichen Sie meine Formel mit Ihrer). Sie können auch auf die erstellte Spalte verweisen und diese mit < verwenden. <>

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

selectedCol = "age";
myValueList = {"12", "15"};

newcol = Eval(EvalExpr(
	dt << New Column("Suspected "|| selectedCol, Character, Nominal, Formula(
		If(Contains(Expr(myValueList), Char(Expr(NameExpr(As column(dt, selectedCol))))),
			"Yes", 
			"No"
		)
	));
));

dt << Move Selected Columns(
	newcol, After(Eval(selectedCol))
);