916315_fr-FR

liliconcom

Je génère une nouvelle colonne en fonction des données saisies par l'utilisateur et je dois la déplacer

Je crée une nouvelle colonne à partir des données saisies par l'utilisateur et je dois la déplacer via un script. Quelqu'un pourrait-il m'aider à corriger mon script ?

dt << New Column("Suspected "|| selectedCol,
	Formula(
		If(Contains(myValueList, char(as column(selectedCol))), 
			"Yes", 
			"No" 
		)
	)
);
Data Table( dt ) << Move Selected Columns( as column("Suspected "|| selectedCol), after( as column(selectedCol) ) );

Analyse et modélisation de données de baseRe: Je génère une nouvelle colonne à partir des données saisies par l'utilisateur et je dois la déplacer

Je parviens à le faire fonctionner en encadrant As Column() dans un Name Expr() et en l'insérant dans une liste.

dt << Move Selected Columns(
	{Name Expr( As Column( "Suspected " || selectedCol ) )},
	After( As Column( selectedCol ) )
);

Re: Je génère une nouvelle colonne à partir des données saisies par l'utilisateur et je dois la déplacer

Cette méthode fonctionne également avec uniquement la chaîne de caractères dans une liste, mais la méthode After() doit avoir As Column().

dt << Move Selected Columns(
	{"Suspected " || selectedCol},
	After( As Column( selectedCol ) )
);

Re: Je génère une nouvelle colonne à partir des données saisies par l'utilisateur et je dois la déplacer

Voici comment j'ai réussi à le faire fonctionner

dt << New Column( "Suspected " || selectedCol,
	Character,
	Formula(
		If( Contains( myValueList, Char( As Column( selectedCol ) ) ),
			"Yes",
			"No"
		)
	)
);
Eval(
	Parse(
		"dt << Move Selected Columns(:Suspected " || selectedCol || ", after( :" ||
		selectedCol || ") );"
	)
);

Re: Je génère une nouvelle colonne à partir des données saisies par l'utilisateur et je dois la déplacer

Je vous recommande fortement d'ajouter une évaluation d'expression à votre colonne pour éviter d'éventuels problèmes (comparez ma formule à la vôtre). Vous pouvez également obtenir une référence à la colonne créée et l'utiliser avec < <>

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

selectedCol = "age";
myValueList = {"12", "15"};

newcol = Eval(EvalExpr(
	dt << New Column("Suspected "|| selectedCol, Character, Nominal, Formula(
		If(Contains(Expr(myValueList), Char(Expr(NameExpr(As column(dt, selectedCol))))),
			"Yes", 
			"No"
		)
	));
));

dt << Move Selected Columns(
	newcol, After(Eval(selectedCol))
);