그래프 빌더 동적 자막안녕하세요, 제 그래프의 부제목을 min(:Year)과 max(:Year)로 설정하고 부제목에 사용하는 방법을 아시는 분 계신가요? 예를 들어 최소 연도가 2018년이고 최대 연도가 2025년이면 부제목은 "2018 - 2025"가 됩니다.
자동화 및 스크립팅Re: 그래프 빌더 동적 자막로컬 데이터 필터에서 최소/최대값을 구하나요? 아니면 전체 데이터 세트에서 구하나요?
데이터 필터에 대해서는 https://marketplace.jmp.com/appdetails/그래프+빌더+툴바 를 참조하세요.
단축키 중 하나를 사용하면 데이터 필터 설정을 제목(부제가 아님)으로 사용할 수 있습니다.
Re: 그래프 빌더 동적 자막자막을 조정하려면 C:\Users\_사용자 이름_\AppData\Roaming\JMP\JMP\Addins\hogi.GraphBuilderToolbar\resetAxisLabels.jsl 로 이동하세요.
그리고 36번째 줄을 다음으로 변경합니다.
gb[Text Edit Box( 2 )] << Set Text( title ); // was Text Edit Box( 1 )
Re: 그래프 빌더 동적 자막그리고 표의 데이터를 기반으로 하면 다음과 같습니다.
Names Default to Here(1);
dt = Open( "$SAMPLE_DATA/US Regional Population.jmp" );
:Year << data type(numeric);
Graph Builder(
Show Subtitle( 1 ),
Variables( X( :Year ), Y( :Population ), Overlay( :Region ) ),
Elements( Line( X, Y ) )
);
dt << select where (:year < 1950 ) << exclude(1) << select where(0);
// ---------------
myRows=where(dt, not (excluded()));
min = Char(min (dt[myRows,"Year"]));
max = Char(min (dt[myRows,"year"]));
((Current Report() << XPath( "//OutlineBox[@helpKey='Data Filter']" )) << get scriptable object) << Show Subtitle( 1 ) ;
current report()[Text Edit Box( 2 )] << Set Text( min || " — " || max );
Re: 그래프 빌더 동적 자막"동적" 자막에 대해 말씀하시는 건가요? 로컬 데이터 필터를 사용할 때를 말씀하시는 건가요? 로컬 데이터 필터에 << 필터 변경 처리기 만들기"를 추가하는 스크립트를 사용해야 합니다.
이 예제가 얼마나 강력한지는 확실하지 않지만 << 필터 변경 핸들러를 사용하는 방법에 대한 아이디어를 제공합니다.
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Show Subtitle(1),
Variables(X(:weight), Y(:height), Overlay(:sex)),
Elements(Points(X, Y, Legend(9)), Line Of Fit(X, Y, Legend(11))),
Local Data Filter(Add Filter(columns(:height)))
);
// Reference to filter
ob_filter = (gb << Top Parent) << XPath("//OutlineBox[@helpKey='Data Filter']");
ob_filter = ob_filter[1];
ldf = ob_filter << Get Scriptable Object;
f = Function({a},
dt = gb << Get Data Table;
w = ldf << Get where clause;
If(Is missing(w),
minval = Col Min(:height);
maxval = Col Max(:height);
,
Substitute Into(w, "Select ", "Get Rows ");
r = Eval(EvalExpr(Send(dt, Expr(Parse(w)))));
minval = Min(dt[r, "height"]);
maxval = Max(dt[r, "height"]);
);
title = Eval Insert("^minval^ < height: < ^maxval^");
gb << Dispatch({}, "graph 1 title", TextEditBox, {Set Text(title)});
);
rs = ldf << Make Filter Change Handler(f);
f(0); // run once
Re: 그래프 빌더 동적 자막관련 토론 - 유사한 솔루션 포함:
로컬 데이터 필터에서 항목 선택(다중 선택 포함)을 기반으로 "그래프 제목"을 동적으로 업데이트하는 것이 가능합니까?
스크립팅이 필요 없이 JMP에 이 기능을 추가하고 싶습니다.
제목 자동 채우기 - 그래프 빌더
로컬 데이터 필터: 선택 항목을 그래프 제목으로 사용하는 옵션
아이디어: 사용자는 제목에 추가되는 데이터 필터 항목을 지정할 수 있습니다.
Re: 그래프 빌더 동적 자막안녕하세요, 혼란을 드려 죄송합니다. 좀 더 구체적으로 말씀드렸어야 했는데 죄송합니다. 전체 데이터 세트를 기준으로 말씀드렸습니다. 데이터 세트가 업데이트됨에 따라 자막에도 해당 날짜가 업데이트되기를 바랍니다.
Re: 그래프 빌더 동적 자막이와 같이?
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/US Regional Population.jmp" );
dt:Year << Data Type( "Numeric" );
dt << Graph Builder(
Show Control Panel( 0 ),
Show Subtitle( 1 ),
Variables( X( :Year ), Y( :Population ), Overlay( :Region ) ),
Elements( Points( X, Y, Legend( 18 ) ) ),
SendToReport(
Dispatch( {}, "graph 1 title", TextEditBox,
{Set Text( Char( Col Min( :Year ) ) || " - " || Char( Col Max( :Year ) ) )}
)
)
);
Re: 그래프 빌더 동적 자막정말 잘 됐어요! 정말 감사합니다!
