913503_zh-TW

liliconcom

如何為長條圖新增/自訂邊框（輪廓）

JMP社群的各位朋友，大家好！

我想在長條圖的每個長條圖周圍添加輪廓/邊框，並自訂其寬度。如何在 JMP 中實現？

如下圖所示，我想在每個條形周圍添加邊框或輪廓。

我聽說過一種變通方法，即透過疊加兩個柱狀圖來模擬輪廓。但是，這種方法似乎無法自訂輪廓的寬度。
是否可以透過圖表建構器介面或編輯腳本，為每個長條圖添加輪廓，並獨立更改其顏色和寬度？

我目前使用的是 JMP 學生版 19。

先感謝您的幫忙！

基礎資料分析與建模數據探索與視覺化回覆：如何為長條圖新增/自訂邊框（輪廓）

我認為使用第二個長條圖應該是一個可行的解決方案，但這需要一些工作，因為您需要建立額外的列來確保高度正確，然後再調整寬度比例。這種方法已經成功實現。

這裡有一個範例腳本，您可以運行它，然後探索圖表是如何構建的（條形圖的順序已更改，寬度比例已修改，顏色已更改等等…）

看更多...

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << New Column("Mean[height][age]",
	Numeric,
	"Continuous",
	Formula(Col Mean(:height, :age) + 1)
);

gb = dt << Graph Builder(
	Size(656, 549),
	Show Control Panel(0),
	Variables(
		X(:age),
		Y(:height),
		Y(:"Mean[height][age]"n, Position(1)),
		Overlay(:age)
	),
	Elements(
		Bar(X, Y(1), Legend(6), Bar Style("Stacked")),
		Bar(X, Y(2), Legend(7), Bar Style("Stacked"))
	),
	SendToReport(
		Dispatch({}, "400", ScaleBox,
			{Legend Model(
				7,
				Base(0, 0, 0, Item ID("12", 1)),
				Base(1, 0, 1, Item ID("13", 1)),
				Base(2, 0, 2, Item ID("14", 1)),
				Base(3, 0, 3, Item ID("15", 1)),
				Base(4, 0, 4, Item ID("16", 1)),
				Base(5, 0, 5, Item ID("17", 1)),
				Type Properties(0, "Bar", {Fill Color(0)}),
				Properties(0, {Fill Color(0)}, Item ID("12", 1)),
				Properties(1, {Fill Color(0)}, Item ID("13", 1)),
				Properties(2, {Fill Color(0)}, Item ID("14", 1)),
				Properties(3, {Fill Color(0)}, Item ID("15", 1)),
				Properties(4, {Fill Color(0)}, Item ID("16", 1)),
				Properties(5, {Fill Color(0)}, Item ID("17", 1))
			)}
		),
		Dispatch({}, "Graph Builder", FrameBox,
			{Reorder Segs({1, 2, 4}), DispatchSeg(
				BarSeg(1),
				{Set Width Proportion(0.7)}
			)}
		),
		Dispatch({}, "400", LegendBox,
			{Legend Position({6, [0, 1, 2, 3, 4, 5], 7, [-1, -1, -1, -1, -1, -1]})}
		)
	)
);

回覆：如何為長條圖新增/自訂邊框（輪廓）

@jthi 的方案很好。我傾向於使用 JMP 的圖形基元，它可以直接繪製線條和矩形，並且可以設定顏色和粗細。

有關如何執行此操作的文件和範例，請參閱腳本索引和腳本指南中的「新增圖形腳本」。

回覆：如何為長條圖新增/自訂邊框（輪廓）

其他（不錯的）選擇包括：

• 使用圖形腳本時，您需要知道圖表中有多少個長條圖，而我認為您無法從 BarSeg 物件中獲取此資訊。因此，在圖表中添加輔助標記會更容易一些（該標記可以從最終圖表中隱藏）。
• 使用標記繪製表達式。雖然需要添加標記，實現起來也更複雜，但它很可能是一種更穩健的選擇。

我現在沒時間把這些選項都寫下來，但它們確實存在。

回覆：如何為長條圖新增/自訂邊框（輪廓）

有時間創建圖形腳本

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(656, 549),
	Show Control Panel(0),
	Variables(X(:age), Y(:height)),
	Elements(
		Bar(X, Y, Legend(4)),
		Points(X, Y, Legend(5), Summary Statistic("Mean"))
	),
	SendToReport(
		Dispatch({}, "400", ScaleBox,
			{Legend Model(
				5,
				Type Properties(0, "Marker", {Transparency(0)}),
				Properties(0, {Transparency(0)}, Item ID("Mean", 1))
			)}
		)
	)
);

fb = Report(gb)[FrameBox(1)];

fb << Add Graphics Script(Function({this}, // can be laggy as it is a graphic script with a loop
	ms = this << Find Seg(MarkerSeg(1));
	xs = ms << Get X Values;
	ys = ms << Get Y Values;
	sideshift = 0.27;
	
	For(i = 1, i <= N Items(xs), i++,
		Pen Size(10); // Width of the line
		Pen Color("Black");
		Rect(xs[i] - sideshift, ys[i], xs[i] + sideshift, -1, 0);
	);
));

這裡是 Marker Draw Expr

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(656, 549),
	Show Control Panel(0),
	Variables(X(:age), Y(:height)),
	Elements(
		Bar(X, Y, Legend(4)),
		Points(X, Y, Legend(5), Summary Statistic("Mean"))
	),
	SendToReport(
		Dispatch({}, "400", ScaleBox,
			{Legend Model(
				5,
				Type Properties(0, "Marker", {Transparency(0)}),
				Properties(0, Item ID("Mean", 1))
			)}
		)
	)
);

fb = Report(gb)[FrameBox(1)];
seg = (fb << FindSeg(Marker Seg(1)));
seg << Set Marker Draw Expr(
	Function({this seg, this row, x, y, size, row state},
		Pen Size(10); // Width of the line
		Pen Color("Black");
		Rect(x - 0.27, y, x + 0.27, -1, 0);
	)
);

回覆：如何為長條圖新增/自訂邊框（輪廓）

@jthi ,

在我的 JMP 19 安裝中，「標記繪製表達式」範例無法正常運作。標記的透明度預設值似乎被設定為 0。下面的簡單變更可以讓矩形正確顯示。

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(656, 549),
	Show Control Panel(0),
	Variables(X(:age), Y(:height)),
	Elements(
		Bar(X, Y, Legend(4)),
		Points(X, Y, Legend(5), Summary Statistic("Mean"))
	),
	SendToReport(
		Dispatch({}, "400", ScaleBox,
			{Legend Model(
				5,
				Type Properties(0, "Marker", {Transparency(0)}),
				Properties(0, Item ID("Mean", 1))
			)}
		)
	)
);

fb = Report(gb)[FrameBox(1)];
seg = (fb << FindSeg(Marker Seg(1)));
seg << Set Marker Draw Expr(
	Function({this seg, this row, x, y, size, row state},
	show(x,y);
		Pen Size(10); // Width of the line
		Pen Color("Black");
		transparency(1); // Needed for JMP 19
		Rect(x - 0.27, y, x + 0.27, -1, 0);
	)
);

回覆：如何為長條圖新增/自訂邊框（輪廓）

如果您覺得細線作為邊框可以接受，那就非常簡單：只需添加第二個條形圖，並將pattern 設定為「none」 ，然後將顏色調整為例如黑色。

   
Names Default to Here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Graph Builder(
	Size( 469, 365 ),
	Summary Statistic( "Median" ),
	Variables( X( :age ), Y( :height ), Overlay( :sex ), Color( :sex ) ),
	Elements(
		Bar( X, Y, Bar Style( "Stacked" ) ),
		Bar( X, Y, Legend( 2 ), Bar Style( "Stacked" ) )
	),
	SendToReport(
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				2,
				Properties(
					0,
					{Fill Color( 0 ), Fill Pattern( "none" )},
					Item ID( "F", 1 )
				),
				Properties(
					1,
					{Fill Color( 0 ), Fill Pattern( "none" )},
					Item ID( "M", 1 )
				)
			)}
		)
	)
);

回覆：如何為長條圖新增/自訂邊框（輪廓）

@txnelson

非常感謝您的詳細回复，這對我很有幫助。但我還有一件事想請教。

當我使用“設定標記繪製表達式”繪製條形邊框時，它會繪製在頂層。
因此，當我新增誤差線或單一資料點（透過點圖）時，自訂邊框會繪製在它們上面。
有沒有辦法控制邊框的繪製順序（圖層），使其顯示在資料點的後面？

對於高度客製化的圖形繪製，人們通常會使用 R 等腳本語言，還是 GraphPad Prism 等專用軟體？

回覆：如何為長條圖新增/自訂邊框（輪廓）

您可以調整各個元素的順序：
在圖表中點擊右鍵並更改順序：

如果只有一種地塊類型，那就增加 20 個地塊並進行自訂。

圖形建構器的靈活性和強度遠遠超過人們乍看之下的想像。訣竅在於：
從非常簡單的拖放操作到高度自訂的圖表，實現了平滑過渡。
使用Set Marker Draw Expr，您已經體驗到了一個非常複雜的功能——但它還有更多功能。
無需使用其他繪圖工具。

回覆：如何為長條圖新增/自訂邊框（輪廓）

使用新的邊框和誤差線繪製圖表。然後右鍵單擊圖表並選擇“自訂”。這將彈出一個對話框，您可以在其中選擇誤差線並將其移動到最前面。關閉對話框，然後點擊紅色三角形並選擇“儲存腳本”。之後，您可以查看產生的腳本，以了解如何使用 JSL 將誤差線移到最前面。