911582_zh-TW

liliconcom

過程能力不符合項到符合項

你好。

我正在使用過程能力分析來產生報告中的圖表。

其中一個匯總表是關於「不符合」的，它也可以用來表示故障率。

我希望產生一個直接顯示產量資料的表格，而不是從「不合格品」表格解讀資料。是否可以透過 JMP 的預設選項直接實現這一點？

品質與工藝工程回覆：過程能力不符合項到符合項

建立一個公式列，用於計算感興趣的參數的收益率。

如果（參數在規範中），則 yield = 1，否則 yield = 0

然後建立一個總計表，計算產量列的平均值。

回覆：過程能力不符合項到符合項

謝謝。我原本希望避免手動建立產量列，但看來這是唯一的方法。雖然這並非我理想的解決方案，但它簡單直接。

回覆：過程能力不符合項到符合項

在資料表中操作是最簡單的選擇，但如果您願意使用一些 JSL，您可以修改不合格項表格框，使其也包含良率百分比（儘管在不合格項中包含良率百分比可能有點奇怪），或者為合格項添加單獨的大綱框+表格框（放置可能比較麻煩）。

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
obj = dt << Process Capability(
	Process Variables(:PNP1),
	Individual Detail Reports(1),
	{:PNP1 << Process Capability Analysis(Nonconformance(1))}
);


tb = Report(obj)["Nonconformance", TableBox(1)];
obsperc = tb[Number Col Box("Observed %")] << get as matrix;
yieldperc = J(3, 1, 100) - obsperc;
(Report(obj)["Nonconformance", TableBox(1)]) << Append(
	Number Col Box("Yield %", yieldperc, << Set Format("Fixed Dec", 9, 4))
);

回覆：過程能力不符合項到符合項

實際上，這個問題經常被問到，所以這篇文章對很多人都會有幫助。

腳本會提示您選擇具有 spec 屬性的欄位。因此，您需要在運行腳本之前確保已設定 spec 屬性。腳本也會產生一個圖表，匯總按分組變數劃分的每個列的符合規範率。

Names Default To Here( 1 );
dt = Current Data Table();

dlg = Column Dialog(
	spec_cols = ColList( "Spec Columns", MinCol( 1 ), MaxCol( 1000 ) ),
	group_cols = ColList( "Group Columns", MinCol( 1 ), MaxCol( 20 ) )
);
If( dlg["Button"] != 1,
	Beep();
	Throw();
);
col_list = dlg["spec_cols"];
group_list = dlg["group_cols"];

for (i=1, i <= nitems(col_list), i++,
	col_name = col_list[i] << Get Name;
	specproperty = col_list[i] << Get Property( "Spec limits" );
	
	if( (contains(char(specproperty), "LSL") > 0) & (contains(char(specproperty), "USL") > 0),
		Eval(Eval Expr(
		dt << New Column( col_name || " In Spec", Numeric, "Continuous", Format( "Best", 12 ),
		Formula(if((Expr(col_list[i]) > Expr(specproperty["LSL"])) & (Expr(col_list[i]) < Expr(specproperty["USL"])), 1, 0 )))
		));	
	);
	if( (contains(char(specproperty), "LSL") == 0) & (contains(char(specproperty), "USL") > 0),
		Eval(Eval Expr(
		dt << New Column( col_name || " In Spec", Numeric, "Continuous", Format( "Best", 12 ),
		Formula(if(Expr(col_list[i]) < Expr(specproperty["USL"]), 1, 0 )))
		));
	);
	if( (contains(char(specproperty), "LSL") > 0) & (contains(char(specproperty), "USL") == 0),
		Eval(Eval Expr(
		dt << New Column( col_name || " In Spec", Numeric, "Continuous", Format( "Best", 12 ),
		Formula(if(Expr(col_list[i]) > Expr(specproperty["LSL"]), 1, 0 )))
		));
	);	
);

cols = dt << Get Column Names();
inspec_cols = {};
for (i=1, i <= nitems(cols), i++,
	if (Contains(cols[i], "In Spec"),
		Insert Into(inspec_cols, cols[i])
	);
);

dt << Group Columns("In Spec Cols", inspec_cols);

dt_inspec_stack = dt << Stack(
	columns( Column Group( "In Spec Cols" ) ),
	Source Label Column( "Spec Columns" ),
	Stacked Data Column( "In Spec" ),
	Drop All Other Columns( 1 ),
	"Non-stacked columns"n( Keep( group_list ) ),
	Output Table("Stack of In Spec Columns")
);

summary_group = {};
for (i=1, i <= nitems(group_list), i++,
	col_name = group_list[i] << Get Name;
	Insert Into(summary_group, col_name);
);
Insert Into(summary_group,"Spec Columns");

dt_inspec_summary = dt_inspec_stack << Summary(
	Group( summary_group ),
	Mean( :In Spec ),
	Freq( "None" ),
	Weight( "None" ),
	output table name(
		"Summary of In Spec Columns"
	)
);

dt_inspec_summary << New Column("CI", Numeric, "Continuous", Format("Best",12),
	Formula(Root( (:"Mean(In Spec)"n * (1 - :"Mean(In Spec)"n)) / :N Rows ) * 1.96)
);

dt_inspec_summary << Graph Builder(
	Size( 1280, 720 ),
	Show Control Panel( 0 ),
	Variables(
		X( :Spec Columns ),
		Y( :"Mean(In Spec)"n ),
		Group X( :Reactor ),
		Interval( :CI )
	),
	Elements(
		Points( X, Y, Legend( 5 ), Error Interval( "Custom Interval" ) ),
		Line( X, Y, Legend( 6 ) )
	),
	SendToReport(
		Dispatch( {}, "Mean(In Spec)", ScaleBox,
			{Format( "Percent", 12, 0 ), Min( 0 ), Inc( 0.2 ), Minor Ticks( 1 ),
			Label Row( {Show Major Grid( 1 ), Show Minor Grid( 1 )} )}
		),
		Dispatch( {}, "Graph Builder", FrameBox, {Reference Line Order( 3 )} ),
		Dispatch( {}, "Graph Builder", FrameBox( 2 ), {Reference Line Order( 3 )} ),
		Dispatch( {}, "Graph Builder", FrameBox( 3 ), {Reference Line Order( 3 )} )
	)
);

回覆：過程能力不符合項到符合項

你好，

這些都是很好的答案，但我還想告訴大家，從 JMP 19 開始，製程能力平台和分銷平台中的流程能力分析新增了一個選項，讓您可以自動將包含「符合規格」指標公式的欄位儲存到資料表中。請參閱此處的 JMP 文件： 儲存「符合規格」指標公式。

您可以在「製程能力」平台的紅色三角形選單下的「儲存」子選單選項中找到該選項。

在分銷平台的流程能力分析報告中，您可以在「流程能力」紅色三角形選單下找到此選項。

一旦掌握了「符合規範」指標的公式，分析和操作就變得很容易了。希望這對您有所幫助。

勞拉

回覆：過程能力不符合項到符合項

感謝@Laura_Lancaster指出這一點。如果流程篩選也能提供這個選項，並且增加一列來顯示綜合所有合格指標列所得出的整體合格率，那就太好了。