911582_zh-CN

liliconcom

过程能力不符合项到符合项

你好。

我正在使用过程能力分析来生成报告中的图表。

其中一个汇总表是关于“不符合项”的，它也可以用来表示故障率。

我希望生成一个直接显示产量数据的表格，而不是从“不合格品”表格中解读数据。是否可以通过 JMP 的默认选项直接实现这一点？

质量与工艺工程回复：过程能力不符合项到符合项

创建一个公式列，用于计算感兴趣的参数的收益率。

如果（参数在规范中），则 yield = 1，否则 yield = 0

然后创建一个汇总表，计算产量列的平均值。

回复：过程能力不符合项到符合项

谢谢。我原本希望避免手动创建产量列，但看来这是唯一的办法。虽然这并非我理想的解决方案，但它简单直接。

回复：过程能力不符合项到符合项

在数据表中操作是最简单的选择，但如果您愿意使用一些 JSL，您可以修改不合格项表格框，使其也包含良率百分比（尽管在不合格项中包含良率百分比可能有点奇怪），或者为合格项添加单独的大纲框+表格框（放置可能比较麻烦）。

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
obj = dt << Process Capability(
	Process Variables(:PNP1),
	Individual Detail Reports(1),
	{:PNP1 << Process Capability Analysis(Nonconformance(1))}
);


tb = Report(obj)["Nonconformance", TableBox(1)];
obsperc = tb[Number Col Box("Observed %")] << get as matrix;
yieldperc = J(3, 1, 100) - obsperc;
(Report(obj)["Nonconformance", TableBox(1)]) << Append(
	Number Col Box("Yield %", yieldperc, << Set Format("Fixed Dec", 9, 4))
);

回复：过程能力不符合项到符合项

实际上，这个问题经常被问到，所以这篇文章对很多人都会有帮助。

脚本会提示您选择具有 spec 属性的列。因此，您需要在运行脚本之前确保已设置 spec 属性。脚本还会生成一个图表，汇总按分组变量划分的每列的符合规范率。

Names Default To Here( 1 );
dt = Current Data Table();

dlg = Column Dialog(
	spec_cols = ColList( "Spec Columns", MinCol( 1 ), MaxCol( 1000 ) ),
	group_cols = ColList( "Group Columns", MinCol( 1 ), MaxCol( 20 ) )
);
If( dlg["Button"] != 1,
	Beep();
	Throw();
);
col_list = dlg["spec_cols"];
group_list = dlg["group_cols"];

for (i=1, i <= nitems(col_list), i++,
	col_name = col_list[i] << Get Name;
	specproperty = col_list[i] << Get Property( "Spec limits" );
	
	if( (contains(char(specproperty), "LSL") > 0) & (contains(char(specproperty), "USL") > 0),
		Eval(Eval Expr(
		dt << New Column( col_name || " In Spec", Numeric, "Continuous", Format( "Best", 12 ),
		Formula(if((Expr(col_list[i]) > Expr(specproperty["LSL"])) & (Expr(col_list[i]) < Expr(specproperty["USL"])), 1, 0 )))
		));	
	);
	if( (contains(char(specproperty), "LSL") == 0) & (contains(char(specproperty), "USL") > 0),
		Eval(Eval Expr(
		dt << New Column( col_name || " In Spec", Numeric, "Continuous", Format( "Best", 12 ),
		Formula(if(Expr(col_list[i]) < Expr(specproperty["USL"]), 1, 0 )))
		));
	);
	if( (contains(char(specproperty), "LSL") > 0) & (contains(char(specproperty), "USL") == 0),
		Eval(Eval Expr(
		dt << New Column( col_name || " In Spec", Numeric, "Continuous", Format( "Best", 12 ),
		Formula(if(Expr(col_list[i]) > Expr(specproperty["LSL"]), 1, 0 )))
		));
	);	
);

cols = dt << Get Column Names();
inspec_cols = {};
for (i=1, i <= nitems(cols), i++,
	if (Contains(cols[i], "In Spec"),
		Insert Into(inspec_cols, cols[i])
	);
);

dt << Group Columns("In Spec Cols", inspec_cols);

dt_inspec_stack = dt << Stack(
	columns( Column Group( "In Spec Cols" ) ),
	Source Label Column( "Spec Columns" ),
	Stacked Data Column( "In Spec" ),
	Drop All Other Columns( 1 ),
	"Non-stacked columns"n( Keep( group_list ) ),
	Output Table("Stack of In Spec Columns")
);

summary_group = {};
for (i=1, i <= nitems(group_list), i++,
	col_name = group_list[i] << Get Name;
	Insert Into(summary_group, col_name);
);
Insert Into(summary_group,"Spec Columns");

dt_inspec_summary = dt_inspec_stack << Summary(
	Group( summary_group ),
	Mean( :In Spec ),
	Freq( "None" ),
	Weight( "None" ),
	output table name(
		"Summary of In Spec Columns"
	)
);

dt_inspec_summary << New Column("CI", Numeric, "Continuous", Format("Best",12),
	Formula(Root( (:"Mean(In Spec)"n * (1 - :"Mean(In Spec)"n)) / :N Rows ) * 1.96)
);

dt_inspec_summary << Graph Builder(
	Size( 1280, 720 ),
	Show Control Panel( 0 ),
	Variables(
		X( :Spec Columns ),
		Y( :"Mean(In Spec)"n ),
		Group X( :Reactor ),
		Interval( :CI )
	),
	Elements(
		Points( X, Y, Legend( 5 ), Error Interval( "Custom Interval" ) ),
		Line( X, Y, Legend( 6 ) )
	),
	SendToReport(
		Dispatch( {}, "Mean(In Spec)", ScaleBox,
			{Format( "Percent", 12, 0 ), Min( 0 ), Inc( 0.2 ), Minor Ticks( 1 ),
			Label Row( {Show Major Grid( 1 ), Show Minor Grid( 1 )} )}
		),
		Dispatch( {}, "Graph Builder", FrameBox, {Reference Line Order( 3 )} ),
		Dispatch( {}, "Graph Builder", FrameBox( 2 ), {Reference Line Order( 3 )} ),
		Dispatch( {}, "Graph Builder", FrameBox( 3 ), {Reference Line Order( 3 )} )
	)
);

回复：过程能力不符合项到符合项

你好，

这些都是很好的答案，但我还想告诉大家，从 JMP 19 开始，过程能力平台和分销平台中的过程能力分析新增了一个选项，允许您自动将包含“符合规格”指标公式的列保存到数据表中。请参阅此处的 JMP 文档： 保存“符合规格”指标公式。

您可以在“过程能力”平台的红色三角形菜单下的“保存”子菜单选项中找到该选项。

在分销平台的流程能力分析报告中，您可以在“流程能力”红色三角形菜单下找到此选项。

一旦掌握了“符合规范”指标的公式，分析和操作就变得很容易了。希望这对您有所帮助。

劳拉

回复：过程能力不符合项到符合项

感谢@Laura_Lancaster指出这一点。如果流程筛选也能提供这个选项，并且增加一列来显示综合所有合格指标列得出的总体合格率，那就太好了。