Hallo.
Ich verwende die Prozessfähigkeitsanalyse, um Diagramme für meine Berichte zu erstellen.
Eine der Übersichtstabellen bezieht sich auf „Nichtkonformität“ und kann auch zur Darstellung der Ausfallrate verwendet werden.
Ich möchte eine Tabelle erstellen, die die Ertragszahlen direkt anzeigt, anstatt sie aus der Fehlertabelle abzuleiten. Gibt es eine Möglichkeit, dies direkt mit den Standardoptionen von JMP zu erreichen?
Erstellen Sie eine Formelspalte, die die Erträge für die relevanten Parameter berechnet.
Wenn (Parameter in Spezifikation) dann Ausbeute = 1 sonst Ausbeute = 0
Erstellen Sie anschließend eine Übersichtstabelle, die den Mittelwert der Ertragsspalten berechnet.
Danke. Ich hatte gehofft, die manuelle Erstellung einer Ertragsspalte vermeiden zu können, aber anscheinend ist das der einzige Weg. Es ist nicht ganz das, was ich mir vorgestellt habe, aber es ist einfach und direkt.
Die einfachste Option ist die Verwendung einer Datentabelle. Wenn Sie jedoch bereit sind, etwas JSL zu verwenden, könnten Sie das Feld für die Nichtkonformitätstabelle so bearbeiten, dass es auch die Ausbeute in Prozent enthält (wobei die Ausbeute in der Nichtkonformitätstabelle etwas ungewöhnlich wirken könnte) oder separate Umrissfelder und Tabellenfelder für die Konformität hinzufügen (die Platzierung kann jedoch etwas umständlich sein).
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
obj = dt << Process Capability(
Process Variables(:PNP1),
Individual Detail Reports(1),
{:PNP1 << Process Capability Analysis(Nonconformance(1))}
);
tb = Report(obj)["Nonconformance", TableBox(1)];
obsperc = tb[Number Col Box("Observed %")] << get as matrix;
yieldperc = J(3, 1, 100) - obsperc;
(Report(obj)["Nonconformance", TableBox(1)]) << Append(
Number Col Box("Yield %", yieldperc, << Set Format("Fixed Dec", 9, 4))
);
Diese Frage taucht tatsächlich häufig auf, daher wird dies für viele hilfreich sein.
Das Skript fordert Sie auf, die Spalten mit der Eigenschaft „spec“ auszuwählen. Stellen Sie daher sicher, dass die Eigenschaft „spec“ vor der Ausführung festgelegt ist. Es erstellt außerdem ein Diagramm, das die Werte innerhalb der Spezifikation für jede Spalte, aufgeteilt nach Gruppierungsvariablen, zusammenfasst.
Names Default To Here( 1 );
dt = Current Data Table();
dlg = Column Dialog(
spec_cols = ColList( "Spec Columns", MinCol( 1 ), MaxCol( 1000 ) ),
group_cols = ColList( "Group Columns", MinCol( 1 ), MaxCol( 20 ) )
);
If( dlg["Button"] != 1,
Beep();
Throw();
);
col_list = dlg["spec_cols"];
group_list = dlg["group_cols"];
for (i=1, i <= nitems(col_list), i++,
col_name = col_list[i] << Get Name;
specproperty = col_list[i] << Get Property( "Spec limits" );
if( (contains(char(specproperty), "LSL") > 0) & (contains(char(specproperty), "USL") > 0),
Eval(Eval Expr(
dt << New Column( col_name || " In Spec", Numeric, "Continuous", Format( "Best", 12 ),
Formula(if((Expr(col_list[i]) > Expr(specproperty["LSL"])) & (Expr(col_list[i]) < Expr(specproperty["USL"])), 1, 0 )))
));
);
if( (contains(char(specproperty), "LSL") == 0) & (contains(char(specproperty), "USL") > 0),
Eval(Eval Expr(
dt << New Column( col_name || " In Spec", Numeric, "Continuous", Format( "Best", 12 ),
Formula(if(Expr(col_list[i]) < Expr(specproperty["USL"]), 1, 0 )))
));
);
if( (contains(char(specproperty), "LSL") > 0) & (contains(char(specproperty), "USL") == 0),
Eval(Eval Expr(
dt << New Column( col_name || " In Spec", Numeric, "Continuous", Format( "Best", 12 ),
Formula(if(Expr(col_list[i]) > Expr(specproperty["LSL"]), 1, 0 )))
));
);
);
cols = dt << Get Column Names();
inspec_cols = {};
for (i=1, i <= nitems(cols), i++,
if (Contains(cols[i], "In Spec"),
Insert Into(inspec_cols, cols[i])
);
);
dt << Group Columns("In Spec Cols", inspec_cols);
dt_inspec_stack = dt << Stack(
columns( Column Group( "In Spec Cols" ) ),
Source Label Column( "Spec Columns" ),
Stacked Data Column( "In Spec" ),
Drop All Other Columns( 1 ),
"Non-stacked columns"n( Keep( group_list ) ),
Output Table("Stack of In Spec Columns")
);
summary_group = {};
for (i=1, i <= nitems(group_list), i++,
col_name = group_list[i] << Get Name;
Insert Into(summary_group, col_name);
);
Insert Into(summary_group,"Spec Columns");
dt_inspec_summary = dt_inspec_stack << Summary(
Group( summary_group ),
Mean( :In Spec ),
Freq( "None" ),
Weight( "None" ),
output table name(
"Summary of In Spec Columns"
)
);
dt_inspec_summary << New Column("CI", Numeric, "Continuous", Format("Best",12),
Formula(Root( (:"Mean(In Spec)"n * (1 - :"Mean(In Spec)"n)) / :N Rows ) * 1.96)
);
dt_inspec_summary << Graph Builder(
Size( 1280, 720 ),
Show Control Panel( 0 ),
Variables(
X( :Spec Columns ),
Y( :"Mean(In Spec)"n ),
Group X( :Reactor ),
Interval( :CI )
),
Elements(
Points( X, Y, Legend( 5 ), Error Interval( "Custom Interval" ) ),
Line( X, Y, Legend( 6 ) )
),
SendToReport(
Dispatch( {}, "Mean(In Spec)", ScaleBox,
{Format( "Percent", 12, 0 ), Min( 0 ), Inc( 0.2 ), Minor Ticks( 1 ),
Label Row( {Show Major Grid( 1 ), Show Minor Grid( 1 )} )}
),
Dispatch( {}, "Graph Builder", FrameBox, {Reference Line Order( 3 )} ),
Dispatch( {}, "Graph Builder", FrameBox( 2 ), {Reference Line Order( 3 )} ),
Dispatch( {}, "Graph Builder", FrameBox( 3 ), {Reference Line Order( 3 )} )
)
);
Hallo,
Das sind alles gute Antworten, aber ich möchte noch darauf hinweisen, dass es ab JMP 19 eine neue Option in der Prozessfähigkeitsplattform und in der Prozessfähigkeitsanalyse innerhalb der Vertriebsplattform gibt. Diese ermöglicht es, Spalten mit In-Spec-Indikatorformeln automatisch in der Datentabelle zu speichern. Die JMP-Dokumentation finden Sie hier: In-Spec-Indikatorformeln speichern.
Sie finden die Option in der Plattform Process Capability unter dem roten Dreiecksmenü und dem Untermenü „Speichern“.
Im Prozessfähigkeitsanalysebericht der Distributionsplattform finden Sie diese Option im Menü „Prozessfähigkeit“ (rotes Dreieck).
Sobald Sie die Formeln für die In-Spec-Indikatoren haben, lassen sie sich leicht analysieren und bearbeiten. Ich hoffe, das hilft Ihnen weiter.
Laura
Danke für den Hinweis, @Laura_Lancaster . Es wäre äußerst hilfreich, diese Option auch in der Prozessprüfung verfügbar zu haben und eine Spalte anzuzeigen, die die Gesamtquote der spezifikationskonformen Abläufe unter Berücksichtigung aller Indikatorenspalten angibt.
