911448_es-ES

liliconcom

Cambiar la transparencia del área con JSL

Hola,

Estoy ajustando un modelo mediante una variable de agrupación y guardando las fórmulas de predicción e intervalo en mi tabla. Luego, coloco el valor Y original, el valor Y predicho y los límites de control inferior y superior en el eje Y y creo un gráfico con la variable de agrupación utilizando la función Wrap (ver el código a continuación para un ejemplo).

Lo que necesito es poder ajustar la transparencia de mi área a un valor específico mediante un script. Sé que puedo hacer clic derecho en la leyenda y modificarla, pero esto es para un script que recibe datos del usuario, así que no puedo usar las funciones habituales de "Enviar a informe" y "Distribuir", donde especifico las columnas de forma estática.

<BR />Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Diamonds Data.jmp" );


mod = Fit Model(
	Y( :Price ),
	By( :Color ),
	Effects( :Depth ),
	Personality( "Standard Least Squares" ),
	Emphasis( "Effect Screening" ),
	Run(
		:Price << {Summary of Fit( 0 ), Analysis of Variance( 0 ), Parameter Estimates( 1 ),
		Sorted Estimates( 0 ), Plot Actual by Predicted( 1 ), Plot Regression( 0 ),
		Plot Residual by Predicted( 1 )}
	)
);

mod << prediction and interval formulas;

Graph Builder(
	Size( 1163, 748 ),
	Show Control Panel( 0 ),
	Show Legend( 0 ),
	Variables(
		X( :Depth ),
		Y( :Price ),
		Y( :Pred Formula Price By Color, Position( 1 ) ),
		Y( :Lower 95% Mean Price By Color, Position( 1 ) ),
		Y( :Upper 95% Mean Price By Color, Position( 1 ) ),
		Wrap( :Color ),
		Overlay( :Color )
	),
	Elements(
		Points( X, Y( 1 ), Legend( 7 ) ),
		Line( X, Y( 2 ), Legend( 9 ) ),
		Area( X, Y( 3 ), Y( 4 ), Legend( 10 ), Area Style( "Range" ), Transparency(0.25) )
	)
);

Automatización y scriptingRe: Cambiar la transparencia del área con JSL

Puedes buscar PolySegs y luego ajustar su transparencia.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Diamonds Data.jmp");


mod = dt << Fit Model(
	Y(:Price),
	By(:Color),
	Effects(:Depth),
	Personality("Standard Least Squares"),
	Emphasis("Effect Screening"),
	Run(
		:Price << {Summary of Fit(0), Analysis of Variance(0), Parameter Estimates(1),
		Sorted Estimates(0), Plot Actual by Predicted(1), Plot Regression(0),
		Plot Residual by Predicted(1)}
	)
);

mod << prediction and interval formulas;

gb = dt << Graph Builder(
	Size(1163, 748),
	Show Control Panel(0),
	Show Legend(0),
	Variables(
		X(:Depth),
		Y(:Price),
		Y(:Pred Formula Price By Color, Position(1)),
		Y(:Lower 95% Mean Price By Color, Position(1)),
		Y(:Upper 95% Mean Price By Color, Position(1)),
		Wrap(:Color),
		Overlay(:Color)
	),
	Elements(
		Points(X, Y(1), Legend(7)),
		Line(X, Y(2), Legend(9)),
		Area(X, Y(3), Y(4), Legend(10), Area Style("Range"))
	)
);

fbs = Report(gb) << XPath("//FrameBox");
For Each({fb}, fbs,
	ps = fb << Find Seg(PolySeg(1));
	If(!IsEmpty(ps),
		ps << Transparency(0.25);
	);
);