911200_zh-TW

liliconcom

樹狀結構與群組平台

你好，

當我在 By 參數中指定變數時，似乎無法存取平台樹狀結構中的項目。是不是我必須先引用“Group Platform”屬性？

我想把表格清單的樣式改成組合框。

謝謝

自動化和腳本編寫回覆：有群組平台的樹狀結構

嗨@rcast15 ，

我不太確定您具體想要了解什麼。能否提供更多細節，以便我更能理解您遇到的問題？這是 JSL 的問題嗎？您使用的是哪個平台或分析工具？您是否可以分享腳本、數據表或螢幕截圖來幫助解釋問題？

謝謝！ ，

DS

回覆：有群組平台的樹狀結構

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);

report = Report(obj);

report[TabListBox(1)] << set style("combo");

以下是我想要實現的功能範例。我想透過腳本將選項卡框的樣式變更為組合框，但遇到了錯誤。我懷疑這與我引用的樹狀結構有關。

回覆：有群組平台的樹狀結構

由於存在多個多元圖，因此 obj 是一個清單。我採用這種方法取得了成功：

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );

回覆：有群組平台的樹狀結構

非常感謝@mmarchandFSLR 。程式碼運作良好，但是當我嘗試將輸出新增到新視窗的任何位置時，都會出現錯誤訊息。我想把輸出放在我創建的新視窗的 V 或 H 列錶框中。請問有什麼辦法嗎？

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

// THIS WORKS
obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );


// DOES NOT WORK
obj_expr = Expr(
	obj = dt << Multivariate(
		Y( :x, :y ),
		Variance Estimation( "Row-wise" ),
		Scatterplot Matrix( 1 ),
		By( :Drug ),
		Group Options( Layout( "Arrange in Tabs" ) )
	);
	(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );
);

New Window( "Example", OB_1 = Outline Box( "Analysis", obj_expr ) );

回覆：有群組平台的樹狀結構

您也可以使用 Group Options(Return Group(1)) 來避免產生物件列表，有時會很有用。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
obj = dt << Bivariate(
	X(:height), 
	Y(:weight), 
	By(:age), 
	Group Options(Return Group(1))
);
// show(obj); // Group Platform[]
obj << Layout("Arrange in Tabs");
Report(obj)[TabListBox(1)] << Set Style("Combo");

回覆：有群組平台的樹狀結構

哦，太棒了，Jarmo！我之前都不知道還有分組退貨這個選項。謝謝！

羅伯特

回覆：有群組平台的樹狀結構

另外，對於你的 Expr() 方法，類似這樣的程式碼應該可以工作。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	Report(obj)[TabListBox(1)] << Set Style("Combo");
);

nw = New Window("Example", OB_1 = Outline Box("Analysis", obj_expr));

但你也可以考慮類似這樣的方法

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	
);

nw = New Window("Example", 
	OB_1 = Outline Box("Analysis", 
		multivar = obj_expr
	)
);
Report(multivar)[TabListBox(1)] << Set Style("Combo");