911200_es-ES

liliconcom

Estructura de árbol con plataforma de grupo

Hola,

No consigo acceder a los elementos de la estructura de árbol de una plataforma cuando especifico una variable en el argumento "By". ¿Hay alguna propiedad "Group Platform" a la que deba hacer referencia primero?

Lo que quiero hacer es cambiar el estilo de la lista desplegable a un cuadro combinado.

Gracias

Automatización y scriptingRe: Estructura de árbol con plataforma de grupo

Hola @rcast15 ,

No entiendo muy bien qué es lo que buscas. ¿Podrías darme más detalles para que sea más fácil comprender el problema? ¿Es un problema de JSL? ¿Qué plataforma o análisis específico estás usando? ¿Tienes algún script, tabla de datos o capturas de pantalla que puedas compartir para aclarar la situación?

¡Gracias!,

DS

Re: Estructura de árbol con plataforma de grupo

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);

report = Report(obj);

report[TabListBox(1)] << set style("combo");

Aquí tenéis un ejemplo de lo que intento hacer. Quiero personalizar el estilo del cuadro de pestañas para convertirlo en un menú desplegable, pero me da un error. Supongo que tiene que ver con la estructura de árbol a la que hago referencia.

Re: Estructura de árbol con plataforma de grupo

Dado que existen múltiples gráficos multivariados, obj es una lista. Este método me funcionó:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );

Re: Estructura de árbol con plataforma de grupo

Muchas gracias @mmarchandFSLR . El código funciona bien, pero al intentar agregar la salida en una nueva ventana, aparece un error. Quiero mostrar la salida en un cuadro de lista vertical (V o H) dentro de una nueva ventana que estoy creando. ¿Alguna sugerencia?

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

// THIS WORKS
obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );


// DOES NOT WORK
obj_expr = Expr(
	obj = dt << Multivariate(
		Y( :x, :y ),
		Variance Estimation( "Row-wise" ),
		Scatterplot Matrix( 1 ),
		By( :Drug ),
		Group Options( Layout( "Arrange in Tabs" ) )
	);
	(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );
);

New Window( "Example", OB_1 = Outline Box( "Analysis", obj_expr ) );

Re: Estructura de árbol con plataforma de grupo

También puede evitar tener la lista de objetos utilizando Group Options(Return Group(1)), lo cual a veces puede resultar útil.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
obj = dt << Bivariate(
	X(:height), 
	Y(:weight), 
	By(:age), 
	Group Options(Return Group(1))
);
// show(obj); // Group Platform[]
obj << Layout("Arrange in Tabs");
Report(obj)[TabListBox(1)] << Set Style("Combo");

Re: Estructura de árbol con plataforma de grupo

¡Genial, Jarmo! No sabía que el grupo de retorno fuera una opción. Gracias.

-Robert

Re: Estructura de árbol con plataforma de grupo

Además, con respecto a tu enfoque con Expr(), algo como esto debería funcionar.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	Report(obj)[TabListBox(1)] << Set Style("Combo");
);

nw = New Window("Example", OB_1 = Outline Box("Analysis", obj_expr));

Pero también podrías considerar algo como

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	
);

nw = New Window("Example", 
	OB_1 = Outline Box("Analysis", 
		multivar = obj_expr
	)
);
Report(multivar)[TabListBox(1)] << Set Style("Combo");