911200_zh-CN

liliconcom

树状结构与群组平台

你好，

当我在 By 参数中指定变量时，似乎无法访问平台树状结构中的项目。是不是我必须先引用“Group Platform”属性？

我想把表格列表的样式改成组合框。

谢谢

自动化和脚本编写回复：带有群组平台的树状结构

嗨@rcast15 ，

我不太确定您具体想要了解什么。能否提供更多细节，以便我更好地理解您遇到的问题？这是 JSL 的问题吗？您使用的是哪个平台或分析工具？您是否可以分享脚本、数据表或屏幕截图来帮助解释问题？

谢谢！，

DS

回复：带有群组平台的树状结构

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);

report = Report(obj);

report[TabListBox(1)] << set style("combo");

以下是我想要实现的功能示例。我想通过脚本将选项卡框的样式更改为组合框，但遇到了错误。我怀疑这与我引用的树状结构有关。

回复：带有群组平台的树状结构

由于存在多个多元图，因此 obj 是一个列表。我采用这种方法取得了成功：

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );

回复：带有群组平台的树状结构

非常感谢@mmarchandFSLR 。代码运行良好，但是当我尝试将输出添加到新窗口的任何位置时，都会出现错误信息。我想把输出放在我创建的新窗口的 V 或 H 列表框中。请问有什么办法吗？

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

// THIS WORKS
obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );


// DOES NOT WORK
obj_expr = Expr(
	obj = dt << Multivariate(
		Y( :x, :y ),
		Variance Estimation( "Row-wise" ),
		Scatterplot Matrix( 1 ),
		By( :Drug ),
		Group Options( Layout( "Arrange in Tabs" ) )
	);
	(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );
);

New Window( "Example", OB_1 = Outline Box( "Analysis", obj_expr ) );

回复：带有群组平台的树状结构

您还可以使用 Group Options(Return Group(1)) 来避免生成对象列表，这有时会很有用。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
obj = dt << Bivariate(
	X(:height), 
	Y(:weight), 
	By(:age), 
	Group Options(Return Group(1))
);
// show(obj); // Group Platform[]
obj << Layout("Arrange in Tabs");
Report(obj)[TabListBox(1)] << Set Style("Combo");

回复：带有群组平台的树状结构

哦，太棒了，Jarmo！我之前都不知道还有分组退货这个选项。谢谢！

罗伯特

回复：带有群组平台的树状结构

另外，对于你的 Expr() 方法，类似这样的代码应该可以工作。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	Report(obj)[TabListBox(1)] << Set Style("Combo");
);

nw = New Window("Example", OB_1 = Outline Box("Analysis", obj_expr));

但你也可以考虑类似这样的方法

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	
);

nw = New Window("Example", 
	OB_1 = Outline Box("Analysis", 
		multivar = obj_expr
	)
);
Report(multivar)[TabListBox(1)] << Set Style("Combo");