911200_ko-KR

liliconcom

그룹 플랫폼이 있는 트리 구조

안녕,

By 인수에 변수를 지정할 때마다 플랫폼의 트리 구조에 있는 항목에 접근할 수 없는 것 같습니다. "그룹 플랫폼" 속성에서 먼저 참조해야 할 항목이 있나요?

제가 하고 싶은 것은 탭 목록의 스타일을 콤보 상자로 바꾸는 것입니다.

감사해요

자동화 및 스크립팅Re: 그룹 플랫폼을 사용한 트리 구조

안녕하세요 @rcast15 ,

원하시는 게 무엇인지 잘 모르겠습니다. 겪고 계신 딜레마를 더 쉽게 이해할 수 있도록 좀 더 자세히 설명해 주시겠어요? JSL 문제인가요? 어떤 플랫폼이나 분석을 사용하고 계신가요? 설명에 도움이 될 만한 스크립트나 데이터 테이블, 또는 스크린샷을 공유해 주실 수 있나요?

감사해요!,

디에스

Re: 그룹 플랫폼을 사용한 트리 구조

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);

report = Report(obj);

report[TabListBox(1)] << set style("combo");

제가 하려는 작업의 예는 다음과 같습니다. 탭 상자의 스타일을 콤보로 스크립팅하고 싶은데 오류가 발생합니다. 제가 참조하는 트리 구조와 관련이 있는 것 같습니다.

Re: 그룹 플랫폼을 사용한 트리 구조

다변량 플롯이 여러 개 있으므로 obj는 리스트입니다. 저는 다음 경로로 성공했습니다.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );

Re: 그룹 플랫폼을 사용한 트리 구조

@mmarchandFSLR 님, 정말 감사합니다. 코드는 잘 작동하지만, 새 창의 아무 곳에나 출력을 추가하려고 하면 오류 메시지가 나타납니다. 새로 만드는 창 안의 V 또는 H 목록 상자에 출력을 넣고 싶은데, 어떻게 해야 할까요?

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

// THIS WORKS
obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );


// DOES NOT WORK
obj_expr = Expr(
	obj = dt << Multivariate(
		Y( :x, :y ),
		Variance Estimation( "Row-wise" ),
		Scatterplot Matrix( 1 ),
		By( :Drug ),
		Group Options( Layout( "Arrange in Tabs" ) )
	);
	(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );
);

New Window( "Example", OB_1 = Outline Box( "Analysis", obj_expr ) );

Re: 그룹 플랫폼을 사용한 트리 구조

때때로 유용할 수 있는 그룹 옵션(반환 그룹(1))을 사용하여 개체 목록을 피할 수도 있습니다.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
obj = dt << Bivariate(
	X(:height), 
	Y(:weight), 
	By(:age), 
	Group Options(Return Group(1))
);
// show(obj); // Group Platform[]
obj << Layout("Arrange in Tabs");
Report(obj)[TabListBox(1)] << Set Style("Combo");

Re: 그룹 플랫폼을 사용한 트리 구조

오, 멋진 자모! 단체 예약이 가능한지 몰랐네요. 감사합니다.

-로버트

Re: 그룹 플랫폼을 사용한 트리 구조

또한 Expr() 접근 방식을 사용하면 이와 비슷한 것이 작동해야 합니다.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	Report(obj)[TabListBox(1)] << Set Style("Combo");
);

nw = New Window("Example", OB_1 = Outline Box("Analysis", obj_expr));

하지만 다음과 같은 것도 고려할 수 있습니다.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	
);

nw = New Window("Example", 
	OB_1 = Outline Box("Analysis", 
		multivar = obj_expr
	)
);
Report(multivar)[TabListBox(1)] << Set Style("Combo");