911200_ja-JP

liliconcom

グループプラットフォームのツリー構造

こんにちは、

By引数に変数を指定しても、プラットフォームのツリー構造内の項目にアクセスできないようです。「Group Platform」プロパティで最初に参照する必要があるものはありますか？

私がやりたいのは、タブリストのスタイルをコンボ ボックスに変更することです。

ありがとう

自動化とスクリプトグループプラットフォームのツリー構造について

こんにちは@rcast15さん、

何を求めているのかよく分かりません。もう少し詳しく教えていただけると、お困りの点が理解しやすくなります。これはJSLの問題でしょうか？具体的にはどのようなプラットフォームや分析ツールをお使いですか？スクリプトやデータテーブル、あるいはスクリーンショットなど、説明に役立つものがあれば教えていただけますか？

ありがとう！、

DS

グループプラットフォームのツリー構造について

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);

report = Report(obj);

report[TabListBox(1)] << set style("combo");

私がやろうとしていることの例を以下に示します。タブボックスのスタイルをコンボボックスのスクリプトに書きたいのですが、エラーが発生します。参照しているツリー構造に関係しているのではないかと考えています。

グループプラットフォームのツリー構造について

多変量プロットが複数あるため、objはリストです。私は以下の方法で成功しました。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );

グループプラットフォームのツリー構造について

@mmarchandFSLRさん、本当にありがとうございます。コードはうまく動作するのですが、出力を新しいウィンドウの任意の場所に追加しようとするとエラーメッセージが表示されます。出力を、作成中の新しいウィンドウ内のVまたはHのリストボックスに追加したいのですが、何か良い方法はありますか？

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

// THIS WORKS
obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );


// DOES NOT WORK
obj_expr = Expr(
	obj = dt << Multivariate(
		Y( :x, :y ),
		Variance Estimation( "Row-wise" ),
		Scatterplot Matrix( 1 ),
		By( :Drug ),
		Group Options( Layout( "Arrange in Tabs" ) )
	);
	(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );
);

New Window( "Example", OB_1 = Outline Box( "Analysis", obj_expr ) );

グループプラットフォームのツリー構造について

また、グループオプション(グループを返す(1))を使用すると、オブジェクトのリストを表示しないようにすることもできます。これは、時々役立ちます。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
obj = dt << Bivariate(
	X(:height), 
	Y(:weight), 
	By(:age), 
	Group Options(Return Group(1))
);
// show(obj); // Group Platform[]
obj << Layout("Arrange in Tabs");
Report(obj)[TabListBox(1)] << Set Style("Combo");

グループプラットフォームのツリー構造について

ああ、Jarmoさん、すごいですね！リターングループが選択肢にあるなんて知りませんでした。ありがとう

-ロバート

グループプラットフォームのツリー構造について

また、Expr()アプローチでは、次のようなものが機能するはずです

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	Report(obj)[TabListBox(1)] << Set Style("Combo");
);

nw = New Window("Example", OB_1 = Outline Box("Analysis", obj_expr));

しかし、次のようなことも考えられます

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	
);

nw = New Window("Example", 
	OB_1 = Outline Box("Analysis", 
		multivar = obj_expr
	)
);
Report(multivar)[TabListBox(1)] << Set Style("Combo");