911200_it-IT

liliconcom

Struttura ad albero con piattaforma di gruppo

CIAO,

Non riesco ad accedere agli elementi nella struttura ad albero di una piattaforma ogni volta che specifico una variabile nell'argomento By. C'è qualcosa con la proprietà "Piattaforma di gruppo" a cui devo fare riferimento prima?

Ciò che voglio fare è cambiare lo stile della tablist in una casella combinata.

Grazie

Automazione e scriptingRe: Struttura ad albero con piattaforma di gruppo

Ciao @rcast15 ,

Non sono del tutto sicuro di cosa tu stia cercando. Puoi fornirmi maggiori dettagli in modo che sia più facile comprendere il dilemma che stai affrontando. Si tratta di un problema JSL? Quale piattaforma o analisi specifica stai utilizzando? Hai uno script o una tabella dati da condividere, o degli screenshot da condividere che possano aiutare a spiegare le cose?

Grazie!,

DS

Re: Struttura ad albero con piattaforma di gruppo

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);

report = Report(obj);

report[TabListBox(1)] << set style("combo");

Ecco un esempio di ciò che sto cercando di fare. Voglio scrivere lo stile della casella di controllo in combo, ma ricevo un errore. Immagino che abbia a che fare con la struttura ad albero a cui faccio riferimento.

Re: Struttura ad albero con piattaforma di gruppo

Poiché sono presenti più grafici multivariati, obj è una lista. Ho avuto successo seguendo questa strada:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );

Re: Struttura ad albero con piattaforma di gruppo

Grazie mille @mmarchandFSLR . Il codice funziona bene, tuttavia quando provo ad aggiungere l'output in qualsiasi punto di una nuova finestra ricevo un messaggio di errore. Vorrei inserire l'output in una casella di riepilogo a discesa (V) o (H) all'interno di una nuova finestra che sto creando. Qualche suggerimento?

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

// THIS WORKS
obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );


// DOES NOT WORK
obj_expr = Expr(
	obj = dt << Multivariate(
		Y( :x, :y ),
		Variance Estimation( "Row-wise" ),
		Scatterplot Matrix( 1 ),
		By( :Drug ),
		Group Options( Layout( "Arrange in Tabs" ) )
	);
	(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );
);

New Window( "Example", OB_1 = Outline Box( "Analysis", obj_expr ) );

Re: Struttura ad albero con piattaforma di gruppo

Puoi anche evitare di avere l'elenco degli oggetti utilizzando Group Options(Return Group(1)) che a volte può essere utile

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
obj = dt << Bivariate(
	X(:height), 
	Y(:weight), 
	By(:age), 
	Group Options(Return Group(1))
);
// show(obj); // Group Platform[]
obj << Layout("Arrange in Tabs");
Report(obj)[TabListBox(1)] << Set Style("Combo");

Re: Struttura ad albero con piattaforma di gruppo

Oh fantastico Jarmo! Non sapevo nemmeno che il gruppo di ritorno fosse un'opzione. Grazie.

-Roberto

Re: Struttura ad albero con piattaforma di gruppo

Inoltre, con il tuo approccio Expr(), qualcosa del genere dovrebbe funzionare

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	Report(obj)[TabListBox(1)] << Set Style("Combo");
);

nw = New Window("Example", OB_1 = Outline Box("Analysis", obj_expr));

Ma potresti anche considerare qualcosa come

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	
);

nw = New Window("Example", 
	OB_1 = Outline Box("Analysis", 
		multivar = obj_expr
	)
);
Report(multivar)[TabListBox(1)] << Set Style("Combo");