911200_de-DE

liliconcom

Baumstruktur mit Gruppenplattform

Hallo,

Ich kann scheinbar nicht auf Elemente in der Baumstruktur einer Plattform zugreifen, wenn ich eine Variable im Argument „By“ angebe. Muss ich zuerst auf die Eigenschaft „Group Platform“ zugreifen?

Ich möchte den Stil der Tabliste in eine Kombinationsbox ändern.

Danke

Automatisierung und SkripterstellungBetreff: Baumstruktur mit Gruppenplattform

Hallo @rcast15 ,

Ich bin mir nicht ganz sicher, was Sie genau erreichen möchten. Könnten Sie bitte weitere Details angeben, damit ich Ihr Problem besser verstehen kann? Handelt es sich um ein JSL-Problem? Welche Plattform oder Analysemethode verwenden Sie konkret? Haben Sie ein Skript, eine Datentabelle oder Screenshots, die Sie teilen können, um das Problem zu verdeutlichen?

Danke!,

DS

Betreff: Baumstruktur mit Gruppenplattform

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);

report = Report(obj);

report[TabListBox(1)] << set style("combo");

Hier ist ein Beispiel für mein Vorhaben. Ich möchte den Stil der Tab-Box in eine Combo-Box umwandeln, erhalte aber eine Fehlermeldung. Ich vermute, es liegt an der Baumstruktur, auf die ich mich beziehe.

Betreff: Baumstruktur mit Gruppenplattform

Da mehrere multivariate Diagramme vorliegen, ist obj eine Liste. Ich hatte Erfolg mit folgendem Ansatz:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );

Betreff: Baumstruktur mit Gruppenplattform

Vielen Dank @mmarchandFSLR . Der Code funktioniert einwandfrei, allerdings erhalte ich eine Fehlermeldung, wenn ich versuche, die Ausgabe in einem neuen Fenster anzuzeigen. Ich möchte die Ausgabe in einer V- oder H-Liste in einem neu erstellten Fenster platzieren. Haben Sie eine Idee, woran das liegen könnte?

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

// THIS WORKS
obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );


// DOES NOT WORK
obj_expr = Expr(
	obj = dt << Multivariate(
		Y( :x, :y ),
		Variance Estimation( "Row-wise" ),
		Scatterplot Matrix( 1 ),
		By( :Drug ),
		Group Options( Layout( "Arrange in Tabs" ) )
	);
	(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );
);

New Window( "Example", OB_1 = Outline Box( "Analysis", obj_expr ) );

Betreff: Baumstruktur mit Gruppenplattform

Sie können die Liste der Objekte auch vermeiden, indem Sie `Group Options(Return Group(1))` verwenden, was manchmal nützlich sein kann.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
obj = dt << Bivariate(
	X(:height), 
	Y(:weight), 
	By(:age), 
	Group Options(Return Group(1))
);
// show(obj); // Group Platform[]
obj << Layout("Arrange in Tabs");
Report(obj)[TabListBox(1)] << Set Style("Combo");

Betreff: Baumstruktur mit Gruppenplattform

Oh, super, Jarmo! Ich wusste gar nicht, dass die Rückgabegruppe eine Option ist. Danke!

-Robert

Betreff: Baumstruktur mit Gruppenplattform

Bezüglich Ihres Expr()-Ansatzes sollte etwa Folgendes funktionieren.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	Report(obj)[TabListBox(1)] << Set Style("Combo");
);

nw = New Window("Example", OB_1 = Outline Box("Analysis", obj_expr));

Man könnte aber auch so etwas in Betracht ziehen wie:

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	
);

nw = New Window("Example", 
	OB_1 = Outline Box("Analysis", 
		multivar = obj_expr
	)
);
Report(multivar)[TabListBox(1)] << Set Style("Combo");