911200_fr-FR

liliconcom

Structure arborescente avec plateforme de groupe

Salut,

Je n'arrive pas à accéder aux éléments de l'arborescence d'une plateforme lorsque je spécifie une variable dans l'argument « Par ». Dois-je d'abord faire référence à la propriété « Group Platform » ?

Ce que je souhaite faire, c'est changer le style de la liste déroulante en une boîte combo.

Merci

Automatisation et scriptageRe: Structure arborescente avec plateforme de groupe

Salut @rcast15 ,

Je ne comprends pas bien votre problème. Pourriez-vous me donner plus de détails afin que je comprenne mieux votre situation ? S'agit-il d'un problème lié à JSL ? Quelle plateforme ou analyse utilisez-vous précisément ? Avez-vous un script, un tableau de données ou des captures d'écran à partager pour illustrer votre propos ?

Merci!,

DS

Re: Structure arborescente avec plateforme de groupe

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);

report = Report(obj);

report[TabListBox(1)] << set style("combo");

Voici un exemple de ce que j'essaie de faire. Je souhaite appliquer un script au style de la boîte à onglets pour créer une liste déroulante, mais je rencontre une erreur. Je suppose que cela est lié à la structure arborescente à laquelle je fais référence.

Re: Structure arborescente avec plateforme de groupe

Comme il y a plusieurs graphiques multivariés, obj est une liste. J'ai obtenu de bons résultats en procédant ainsi :

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );

Re: Structure arborescente avec plateforme de groupe

Merci beaucoup @mmarchandFSLR . Le code fonctionne bien, mais lorsque j'essaie d'afficher le résultat dans une nouvelle fenêtre, j'obtiens un message d'erreur. Je souhaite l'afficher dans une liste déroulante (V ou H) à l'intérieur de cette nouvelle fenêtre. Auriez-vous une idée ?

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Drug.jmp" );

// THIS WORKS
obj = dt << Multivariate(
	Y( :x, :y ),
	Variance Estimation( "Row-wise" ),
	Scatterplot Matrix( 1 ),
	By( :Drug ),
	Group Options( Layout( "Arrange in Tabs" ) )
);
(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );


// DOES NOT WORK
obj_expr = Expr(
	obj = dt << Multivariate(
		Y( :x, :y ),
		Variance Estimation( "Row-wise" ),
		Scatterplot Matrix( 1 ),
		By( :Drug ),
		Group Options( Layout( "Arrange in Tabs" ) )
	);
	(Get Window( obj[1] ) << XPath( "//TabListBox" ))[1] << Set Style( "Combo" );
);

New Window( "Example", OB_1 = Outline Box( "Analysis", obj_expr ) );

Re: Structure arborescente avec plateforme de groupe

Vous pouvez également éviter d'avoir la liste des objets en utilisant Group Options(Return Group(1)), ce qui peut parfois s'avérer utile.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
obj = dt << Bivariate(
	X(:height), 
	Y(:weight), 
	By(:age), 
	Group Options(Return Group(1))
);
// show(obj); // Group Platform[]
obj << Layout("Arrange in Tabs");
Report(obj)[TabListBox(1)] << Set Style("Combo");

Re: Structure arborescente avec plateforme de groupe

Oh génial Jarmo ! Je ne savais même pas que le groupe de retour était une option. Merci

-Robert

Re: Structure arborescente avec plateforme de groupe

De plus, concernant votre approche Expr(), quelque chose comme ceci devrait fonctionner.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	Report(obj)[TabListBox(1)] << Set Style("Combo");
);

nw = New Window("Example", OB_1 = Outline Box("Analysis", obj_expr));

Mais vous pourriez aussi envisager quelque chose comme

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Drug.jmp");

obj_expr = Expr(
	obj = dt << Multivariate(
		Y(:x, :y),
		Variance Estimation("Row-wise"),
		Scatterplot Matrix(1),
		By(:Drug),
		Group Options(Return Group(1), Layout("Arrange in Tabs"))
	);
	
);

nw = New Window("Example", 
	OB_1 = Outline Box("Analysis", 
		multivar = obj_expr
	)
);
Report(multivar)[TabListBox(1)] << Set Style("Combo");