908227_es-ES

liliconcom

Barras de datos en la tabla

Hola,

¿Es posible agregar barras de datos a una tabla de datos de JMP, de forma similar a Excel? Lo más cercano que puedo hacer es usar propiedades de degradado de color en columnas, pero sería preferible usar barras de datos.

Exploración y visualización de datosRe: Barras de datos en la tabla

Lo más fácil sería utilizar Tabular

o Table Box() con Col Plot Box()

Re: Barras de datos en la tabla

bastante lejos de " en la tabla de datos JMP "; )

Re: Barras de datos en la tabla

También puedes experimentar con diferentes cuadros de visualización y usar << obtener imagen. Por ejemplo, para una tabla JMP de clase grande, usa la siguiente fórmula (tipo de dato Expresión):

Eval(
	Eval Expr(
		Graph Box(
			Frame Size(Col Max(:weight) * 10, 300),
			Y Scale(0, 100),
			X Scale(0, Expr(Col Max(:weight))),
			Fill Color("Red");
			Rect(0, 100, Expr(:weight), 0, 1);
			Text Color("Black");
			Text Size(200);
			Text(Center Justified, {Expr(:weight / 2), 20}, Expr(Char(:weight)));
		)
	)
) << get picture

Terminarás con algo como

Re: Barras de datos en la tabla

¡Guau!

Re: Barras de datos en la tabla

Difícil de encontrar: supresores
¿Qué es doubleBuffer?

Re: Barras de datos en la tabla

Además, si no necesitas el texto dentro de las barras, puedes usar cuadros espaciadores en lugar de cuadros gráficos. A continuación, se muestra un ejemplo rápido y bastante complejo (escribiré una versión mejorada cuando tenga un poco más de tiempo para pensarlo).

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << New Column("R", Expression, None, Formula(
	As Constant(
		left_color = "Red";
		right_color = "Green";
		minval = Col Min(:Weight);
		maxval = Col Max(:Weight);
		
		scaling = (maxval - minval) / 300;
		
		If(minval >= 0,
			minval = 0;
		);
		If(maxval <= 0,
			maxval = 0
		);
	);
	
	If(:Weight >= 0,
		right = :Weight;
		right_filler = maxval - :Weight;
		left_filler = Abs(minval);
		left = 0;
	,
		left = Abs(:Weight);
		left_filler = Abs(minval) - left;
		right_filler = maxval;
		right = 0;
	);
	
	H List Box(align("Center"),
		Spacer Box(Size(1, 20), Color("Black")),
		Spacer Box(Size(left_filler * scaling, 20), Color("White")),
		Spacer Box(size(left * scaling, 20), color(left_color)),
		Spacer Box(Size(1, 20), Color("Black")),
		Spacer Box(size(right * scaling, 20), color(right_color)),
		Spacer Box(Size(right_filler * scaling, 20), Color("White")),
		Spacer Box(Size(1, 20), Color("Black"))
	);
));

Con valores negativos:

Además, si desea tener una función como esta en JMP, cree una publicación en la Lista de deseos de JMP .

Re: Barras de datos en la tabla

¡Vaya! ¡Muchos órdenes de magnitud más rápido!

Re: Barras de datos en la tabla

Habría editado mi publicación anterior, pero este nuevo diseño de la comunidad ha empeorado la experiencia del usuario de lo que era antes... así que crearé un nuevo mensaje (me hubiera gustado agregar etiquetas de spoiler al JSL)

/*""" Create databar column function

Author: jthi
Creation Date: 2025-10-18
Creation JMP Version: JMP Pro 18.2.1
	
"""*/

Names Default To Here(1); 

add_databar_column = function({dt, colname, leave_formula = 1}, {Default Local},
	newcol = Eval(Substitute(
		Expr(dt << New Column(colname || " Data Bar", Expression, None, Formula(
			As Constant(
				left_color = -15775706; // pinkish
				right_color = -11393916; // light green
				minval = Col Min(_colref_);//, Excluded());
				maxval = Col Max(_colref_);//, Excluded());

				If(minval >= 0,
					minval = 0;
				);
				If(maxval <= 0,
					maxval = 0
				);
				
				scaling = (maxval - minval) / 100;
				
			);
			
			If(_colref_ >= 0,
				right = _colref_;
				right_filler = maxval - _colref_;
				left_filler = Abs(minval);
				left = 0;
			,
				left = Abs(_colref_);
				left_filler = Abs(minval) - left;
				right_filler = maxval;
				right = 0;
			);
			
			bb = Border Box(Top(2), Bottom(2), Sides(15),
				H List Box(align("Center"),
					Spacer Box(Size(left_filler / scaling, 13), Color("White")),
					Spacer Box(size(left / scaling, 13), color(left_color)),
					Spacer Box(size(right / scaling, 13), color(right_color)),
					Spacer Box(Size(right_filler / scaling, 13), Color("White")),
				),
				<< Backgroundcolor("White")
			);			
		))),
		Expr(_colref_), Name Expr(AsColumn(dt, colname));
	));
	
	If(!leave_formula,
		dt << Run Formulas;
		newcol << Delete Formula;
	);
	
	newcol << Set Display Width(110);
	return(newcol);
);

/*
// Example
dt = open("$SAMPLE_DATA/BabySleep.jmp");

add_databar_column(dt, "Awake");
add_databar_column(dt, "Asleep");
add_databar_column(dt, "Dif");
*/