表内のデータバーこんにちは、
Excel と同様の方法で、JMP データ テーブルにデータ バーを追加することは可能ですか? 最も近いのは列のカラー グラデーション プロパティですが、データ バーの方が望ましいです。
データの探索と可視化Re: 表内のデータバー最も簡単なのはTabulateを使うことです
または Table Box() と Col Plot Box()
Re: 表内のデータバー「 JMP データ テーブル内」とはまったく異なります ; )
Re: 表内のデータバーさまざまな表示ボックスを試してみて、<< get picture を使うこともできます。例えば、Big Class JMP Table の場合は、式（データ型：Expression）として以下を使用します。
Eval(
Eval Expr(
Graph Box(
Frame Size(Col Max(:weight) * 10, 300),
Y Scale(0, 100),
X Scale(0, Expr(Col Max(:weight))),
Fill Color("Red");
Rect(0, 100, Expr(:weight), 0, 1);
Text Color("Black");
Text Size(200);
Text(Center Justified, {Expr(:weight / 2), 20}, Expr(Char(:weight)));
)
)
) << get picture
最終的には次のようなものになります
Re: 表内のデータバーおお！
Re: 表内のデータバー見つけにくい：サプレッサー
doubleBufferとは何ですか？
Re: 表内のデータバーまた、バー内のテキストが不要な場合は、グラフボックスの代わりにスペーサーボックスを使用できます。以下は簡単で非常にハックな例です（もう少し時間をかけて考えたら、もっと良いバージョンを書きます）。
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
dt << New Column("R", Expression, None, Formula(
As Constant(
left_color = "Red";
right_color = "Green";
minval = Col Min(:Weight);
maxval = Col Max(:Weight);
scaling = (maxval - minval) / 300;
If(minval >= 0,
minval = 0;
);
If(maxval <= 0,
maxval = 0
);
);
If(:Weight >= 0,
right = :Weight;
right_filler = maxval - :Weight;
left_filler = Abs(minval);
left = 0;
,
left = Abs(:Weight);
left_filler = Abs(minval) - left;
right_filler = maxval;
right = 0;
);
H List Box(align("Center"),
Spacer Box(Size(1, 20), Color("Black")),
Spacer Box(Size(left_filler * scaling, 20), Color("White")),
Spacer Box(size(left * scaling, 20), color(left_color)),
Spacer Box(Size(1, 20), Color("Black")),
Spacer Box(size(right * scaling, 20), color(right_color)),
Spacer Box(Size(right_filler * scaling, 20), Color("White")),
Spacer Box(Size(1, 20), Color("Black"))
);
));
負の値の場合:
また、JMP にこのような機能を追加したい場合は、 JMPウィッシュリストに投稿してください。
Re: 表内のデータバーすごい、桁違いに速いですね！
Re: 表内のデータバー以前の投稿を編集するつもりでしたが、この新しいコミュニティレイアウトにより、ユーザーエクスペリエンスが以前よりも悪くなりました...そのため、新しいメッセージを作成します（JSLにネタバレタグを追加したかったのですが）
/*""" Create databar column function
Author: jthi
Creation Date: 2025-10-18
Creation JMP Version: JMP Pro 18.2.1
"""*/
Names Default To Here(1);
add_databar_column = function({dt, colname, leave_formula = 1}, {Default Local},
newcol = Eval(Substitute(
Expr(dt << New Column(colname || " Data Bar", Expression, None, Formula(
As Constant(
left_color = -15775706; // pinkish
right_color = -11393916; // light green
minval = Col Min(_colref_);//, Excluded());
maxval = Col Max(_colref_);//, Excluded());
If(minval >= 0,
minval = 0;
);
If(maxval <= 0,
maxval = 0
);
scaling = (maxval - minval) / 100;
);
If(_colref_ >= 0,
right = _colref_;
right_filler = maxval - _colref_;
left_filler = Abs(minval);
left = 0;
,
left = Abs(_colref_);
left_filler = Abs(minval) - left;
right_filler = maxval;
right = 0;
);
bb = Border Box(Top(2), Bottom(2), Sides(15),
H List Box(align("Center"),
Spacer Box(Size(left_filler / scaling, 13), Color("White")),
Spacer Box(size(left / scaling, 13), color(left_color)),
Spacer Box(size(right / scaling, 13), color(right_color)),
Spacer Box(Size(right_filler / scaling, 13), Color("White")),
),
<< Backgroundcolor("White")
);
))),
Expr(_colref_), Name Expr(AsColumn(dt, colname));
));
If(!leave_formula,
dt << Run Formulas;
newcol << Delete Formula;
);
newcol << Set Display Width(110);
return(newcol);
);
/*
// Example
dt = open("$SAMPLE_DATA/BabySleep.jmp");
add_databar_column(dt, "Awake");
add_databar_column(dt, "Asleep");
add_databar_column(dt, "Dif");
*/
