908227_it-IT

liliconcom

Barre dati nella tabella

CIAO,

È possibile aggiungere barre dati in una tabella dati JMP, in modo simile a quanto avviene in Excel? La soluzione più vicina è la proprietà "Sfumatura di colore" nelle colonne, ma preferirei le barre dati.

Esplorazione e visualizzazione dei datiRe: Barre dati nella tabella

Il modo più semplice sarebbe usare Tabulate

o Table Box() con Col Plot Box()

Re: Barre dati nella tabella

abbastanza lontano da " nella tabella dati JMP " ; )

Re: Barre dati nella tabella

Potresti anche provare a sperimentare diverse caselle di visualizzazione e poi usare << Get Picture. Ad esempio, per una tabella JMP di grandi dimensioni, usa la seguente formula (tipo di dati Espressione):

Eval(
	Eval Expr(
		Graph Box(
			Frame Size(Col Max(:weight) * 10, 300),
			Y Scale(0, 100),
			X Scale(0, Expr(Col Max(:weight))),
			Fill Color("Red");
			Rect(0, 100, Expr(:weight), 0, 1);
			Text Color("Black");
			Text Size(200);
			Text(Center Justified, {Expr(:weight / 2), 20}, Expr(Char(:weight)));
		)
	)
) << get picture

Finirai con qualcosa del tipo

Re: Barre dati nella tabella

Oh!

Re: Barre dati nella tabella

difficile da trovare: soppressori
cos'è doubleBuffer?

Re: Barre dati nella tabella

Inoltre, se non hai bisogno del testo all'interno delle barre, puoi usare le caselle spaziatrici invece delle caselle grafiche. Di seguito un esempio rapido e molto pratico (ne scriverò una versione migliore quando avrò un po' più di tempo per pensarci).

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << New Column("R", Expression, None, Formula(
	As Constant(
		left_color = "Red";
		right_color = "Green";
		minval = Col Min(:Weight);
		maxval = Col Max(:Weight);
		
		scaling = (maxval - minval) / 300;
		
		If(minval >= 0,
			minval = 0;
		);
		If(maxval <= 0,
			maxval = 0
		);
	);
	
	If(:Weight >= 0,
		right = :Weight;
		right_filler = maxval - :Weight;
		left_filler = Abs(minval);
		left = 0;
	,
		left = Abs(:Weight);
		left_filler = Abs(minval) - left;
		right_filler = maxval;
		right = 0;
	);
	
	H List Box(align("Center"),
		Spacer Box(Size(1, 20), Color("Black")),
		Spacer Box(Size(left_filler * scaling, 20), Color("White")),
		Spacer Box(size(left * scaling, 20), color(left_color)),
		Spacer Box(Size(1, 20), Color("Black")),
		Spacer Box(size(right * scaling, 20), color(right_color)),
		Spacer Box(Size(right_filler * scaling, 20), Color("White")),
		Spacer Box(Size(1, 20), Color("Black"))
	);
));

Con valori negativi:

Inoltre, se desideri avere una funzionalità come questa in JMP, crea un post nella Lista dei desideri di JMP .

Re: Barre dati nella tabella

wow, molti ordini di grandezza più veloce!

Re: Barre dati nella tabella

Avrei modificato il mio post precedente, ma questo nuovo layout della community ha peggiorato l'esperienza utente rispetto a prima... quindi creerò un nuovo messaggio (avrei voluto aggiungere tag spoiler al JSL)

/*""" Create databar column function

Author: jthi
Creation Date: 2025-10-18
Creation JMP Version: JMP Pro 18.2.1
	
"""*/

Names Default To Here(1); 

add_databar_column = function({dt, colname, leave_formula = 1}, {Default Local},
	newcol = Eval(Substitute(
		Expr(dt << New Column(colname || " Data Bar", Expression, None, Formula(
			As Constant(
				left_color = -15775706; // pinkish
				right_color = -11393916; // light green
				minval = Col Min(_colref_);//, Excluded());
				maxval = Col Max(_colref_);//, Excluded());

				If(minval >= 0,
					minval = 0;
				);
				If(maxval <= 0,
					maxval = 0
				);
				
				scaling = (maxval - minval) / 100;
				
			);
			
			If(_colref_ >= 0,
				right = _colref_;
				right_filler = maxval - _colref_;
				left_filler = Abs(minval);
				left = 0;
			,
				left = Abs(_colref_);
				left_filler = Abs(minval) - left;
				right_filler = maxval;
				right = 0;
			);
			
			bb = Border Box(Top(2), Bottom(2), Sides(15),
				H List Box(align("Center"),
					Spacer Box(Size(left_filler / scaling, 13), Color("White")),
					Spacer Box(size(left / scaling, 13), color(left_color)),
					Spacer Box(size(right / scaling, 13), color(right_color)),
					Spacer Box(Size(right_filler / scaling, 13), Color("White")),
				),
				<< Backgroundcolor("White")
			);			
		))),
		Expr(_colref_), Name Expr(AsColumn(dt, colname));
	));
	
	If(!leave_formula,
		dt << Run Formulas;
		newcol << Delete Formula;
	);
	
	newcol << Set Display Width(110);
	return(newcol);
);

/*
// Example
dt = open("$SAMPLE_DATA/BabySleep.jmp");

add_databar_column(dt, "Awake");
add_databar_column(dt, "Asleep");
add_databar_column(dt, "Dif");
*/