908227_de-DE

liliconcom

Datenbalken in der Tabelle

Hallo,

ist es möglich, Datenbalken in JMP-Datentabellen auf ähnliche Weise wie in Excel hinzuzufügen? Am nächsten kommen mir die Farbverlaufseigenschaften in Spalten, aber Datenbalken wären vorzuziehen.

Datenexploration und -visualisierungBetreff: Datenbalken in der Tabelle

Am einfachsten wäre es, Tabulate zu verwenden

oder Table Box() mit Col Plot Box()

Betreff: Datenbalken in der Tabelle

ziemlich weit entfernt von " in JMP-Datentabelle " ; )

Betreff: Datenbalken in der Tabelle

Sie können auch mit verschiedenen Anzeigefeldern experimentieren und dann << Bild abrufen verwenden. Beispielsweise für eine große JMP-Tabelle mit der folgenden Formel (Datentyp „Ausdruck“):

Eval(
	Eval Expr(
		Graph Box(
			Frame Size(Col Max(:weight) * 10, 300),
			Y Scale(0, 100),
			X Scale(0, Expr(Col Max(:weight))),
			Fill Color("Red");
			Rect(0, 100, Expr(:weight), 0, 1);
			Text Color("Black");
			Text Size(200);
			Text(Center Justified, {Expr(:weight / 2), 20}, Expr(Char(:weight)));
		)
	)
) << get picture

Sie erhalten am Ende etwas wie

Betreff: Datenbalken in der Tabelle

Wow!

Betreff: Datenbalken in der Tabelle

schwer zu finden: Unterdrückungsachsen
Was ist DoubleBuffer?

Betreff: Datenbalken in der Tabelle

Wenn Sie den Text in den Balken nicht benötigen, können Sie anstelle von Graph Boxen auch Spacer Boxen verwenden. Unten finden Sie ein kurzes und sehr einfaches Beispiel (ich werde eine bessere Version schreiben, wenn ich etwas mehr Zeit zum Nachdenken habe).

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << New Column("R", Expression, None, Formula(
	As Constant(
		left_color = "Red";
		right_color = "Green";
		minval = Col Min(:Weight);
		maxval = Col Max(:Weight);
		
		scaling = (maxval - minval) / 300;
		
		If(minval >= 0,
			minval = 0;
		);
		If(maxval <= 0,
			maxval = 0
		);
	);
	
	If(:Weight >= 0,
		right = :Weight;
		right_filler = maxval - :Weight;
		left_filler = Abs(minval);
		left = 0;
	,
		left = Abs(:Weight);
		left_filler = Abs(minval) - left;
		right_filler = maxval;
		right = 0;
	);
	
	H List Box(align("Center"),
		Spacer Box(Size(1, 20), Color("Black")),
		Spacer Box(Size(left_filler * scaling, 20), Color("White")),
		Spacer Box(size(left * scaling, 20), color(left_color)),
		Spacer Box(Size(1, 20), Color("Black")),
		Spacer Box(size(right * scaling, 20), color(right_color)),
		Spacer Box(Size(right_filler * scaling, 20), Color("White")),
		Spacer Box(Size(1, 20), Color("Black"))
	);
));

Bei negativen Werten:

Wenn Sie eine solche Funktion in JMP haben möchten, erstellen Sie außerdem einen Beitrag zur JMP-Wunschliste .

Betreff: Datenbalken in der Tabelle

wow, um viele Größenordnungen schneller!

Betreff: Datenbalken in der Tabelle

Ich hätte meinen früheren Beitrag bearbeitet, aber dieses neue Community-Layout hat die Benutzererfahrung schlechter gemacht als zuvor ... also werde ich eine neue Nachricht erstellen (ich hätte dem JSL gerne Spoiler-Tags hinzugefügt).

/*""" Create databar column function

Author: jthi
Creation Date: 2025-10-18
Creation JMP Version: JMP Pro 18.2.1
	
"""*/

Names Default To Here(1); 

add_databar_column = function({dt, colname, leave_formula = 1}, {Default Local},
	newcol = Eval(Substitute(
		Expr(dt << New Column(colname || " Data Bar", Expression, None, Formula(
			As Constant(
				left_color = -15775706; // pinkish
				right_color = -11393916; // light green
				minval = Col Min(_colref_);//, Excluded());
				maxval = Col Max(_colref_);//, Excluded());

				If(minval >= 0,
					minval = 0;
				);
				If(maxval <= 0,
					maxval = 0
				);
				
				scaling = (maxval - minval) / 100;
				
			);
			
			If(_colref_ >= 0,
				right = _colref_;
				right_filler = maxval - _colref_;
				left_filler = Abs(minval);
				left = 0;
			,
				left = Abs(_colref_);
				left_filler = Abs(minval) - left;
				right_filler = maxval;
				right = 0;
			);
			
			bb = Border Box(Top(2), Bottom(2), Sides(15),
				H List Box(align("Center"),
					Spacer Box(Size(left_filler / scaling, 13), Color("White")),
					Spacer Box(size(left / scaling, 13), color(left_color)),
					Spacer Box(size(right / scaling, 13), color(right_color)),
					Spacer Box(Size(right_filler / scaling, 13), Color("White")),
				),
				<< Backgroundcolor("White")
			);			
		))),
		Expr(_colref_), Name Expr(AsColumn(dt, colname));
	));
	
	If(!leave_formula,
		dt << Run Formulas;
		newcol << Delete Formula;
	);
	
	newcol << Set Display Width(110);
	return(newcol);
);

/*
// Example
dt = open("$SAMPLE_DATA/BabySleep.jmp");

add_databar_column(dt, "Awake");
add_databar_column(dt, "Asleep");
add_databar_column(dt, "Dif");
*/