908227_fr-FR

liliconcom

Barres de données dans le tableau

Salut,

Est-il possible d'ajouter des barres de données dans une table de données JMP, de la même manière que dans Excel ? La solution la plus proche que je connaisse est d'utiliser les propriétés de dégradé de couleurs dans les colonnes, mais les barres de données seraient préférables.

Exploration et visualisation des donnéesRe : Barres de données dans le tableau

Le plus simple serait d'utiliser Tabulate

ou Table Box() avec Col Plot Box()

Re : Barres de données dans le tableau

assez loin de " dans la table de données JMP " ; )

Re : Barres de données dans le tableau

Vous pouvez également tester différentes zones d'affichage, puis utiliser << obtenir une image. Par exemple, pour une table JMP de grande classe, utilisez la formule suivante (type de données Expression).

Eval(
	Eval Expr(
		Graph Box(
			Frame Size(Col Max(:weight) * 10, 300),
			Y Scale(0, 100),
			X Scale(0, Expr(Col Max(:weight))),
			Fill Color("Red");
			Rect(0, 100, Expr(:weight), 0, 1);
			Text Color("Black");
			Text Size(200);
			Text(Center Justified, {Expr(:weight / 2), 20}, Expr(Char(:weight)));
		)
	)
) << get picture

Vous vous retrouverez avec quelque chose comme

Re : Barres de données dans le tableau

Ouah!

Re : Barres de données dans le tableau

difficile à trouver : axes de suppression
qu'est-ce que doubleBuffer ?

Re: Barres de données dans le tableau

De plus, si vous n'avez pas besoin du texte à l'intérieur des barres, vous pouvez utiliser des espaces vides plutôt que des zones graphiques. Vous trouverez ci-dessous un exemple rapide et très astucieux (j'écrirai une version améliorée lorsque j'aurai un peu plus de temps pour y réfléchir).

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << New Column("R", Expression, None, Formula(
	As Constant(
		left_color = "Red";
		right_color = "Green";
		minval = Col Min(:Weight);
		maxval = Col Max(:Weight);
		
		scaling = (maxval - minval) / 300;
		
		If(minval >= 0,
			minval = 0;
		);
		If(maxval <= 0,
			maxval = 0
		);
	);
	
	If(:Weight >= 0,
		right = :Weight;
		right_filler = maxval - :Weight;
		left_filler = Abs(minval);
		left = 0;
	,
		left = Abs(:Weight);
		left_filler = Abs(minval) - left;
		right_filler = maxval;
		right = 0;
	);
	
	H List Box(align("Center"),
		Spacer Box(Size(1, 20), Color("Black")),
		Spacer Box(Size(left_filler * scaling, 20), Color("White")),
		Spacer Box(size(left * scaling, 20), color(left_color)),
		Spacer Box(Size(1, 20), Color("Black")),
		Spacer Box(size(right * scaling, 20), color(right_color)),
		Spacer Box(Size(right_filler * scaling, 20), Color("White")),
		Spacer Box(Size(1, 20), Color("Black"))
	);
));

Avec des valeurs négatives :

De plus, si vous souhaitez disposer d'une fonctionnalité comme celle-ci dans JMP, créez un message dans la liste de souhaits JMP .

Re : Barres de données dans le tableau

wow, beaucoup plus rapide !

Re : Barres de données dans le tableau

J'aurais édité mon message précédent, mais cette nouvelle mise en page de la communauté a rendu l'expérience utilisateur pire qu'avant... donc je vais créer un nouveau message (j'aurais aimé ajouter des balises spoiler au JSL)

/*""" Create databar column function

Author: jthi
Creation Date: 2025-10-18
Creation JMP Version: JMP Pro 18.2.1
	
"""*/

Names Default To Here(1); 

add_databar_column = function({dt, colname, leave_formula = 1}, {Default Local},
	newcol = Eval(Substitute(
		Expr(dt << New Column(colname || " Data Bar", Expression, None, Formula(
			As Constant(
				left_color = -15775706; // pinkish
				right_color = -11393916; // light green
				minval = Col Min(_colref_);//, Excluded());
				maxval = Col Max(_colref_);//, Excluded());

				If(minval >= 0,
					minval = 0;
				);
				If(maxval <= 0,
					maxval = 0
				);
				
				scaling = (maxval - minval) / 100;
				
			);
			
			If(_colref_ >= 0,
				right = _colref_;
				right_filler = maxval - _colref_;
				left_filler = Abs(minval);
				left = 0;
			,
				left = Abs(_colref_);
				left_filler = Abs(minval) - left;
				right_filler = maxval;
				right = 0;
			);
			
			bb = Border Box(Top(2), Bottom(2), Sides(15),
				H List Box(align("Center"),
					Spacer Box(Size(left_filler / scaling, 13), Color("White")),
					Spacer Box(size(left / scaling, 13), color(left_color)),
					Spacer Box(size(right / scaling, 13), color(right_color)),
					Spacer Box(Size(right_filler / scaling, 13), Color("White")),
				),
				<< Backgroundcolor("White")
			);			
		))),
		Expr(_colref_), Name Expr(AsColumn(dt, colname));
	));
	
	If(!leave_formula,
		dt << Run Formulas;
		newcol << Delete Formula;
	);
	
	newcol << Set Display Width(110);
	return(newcol);
);

/*
// Example
dt = open("$SAMPLE_DATA/BabySleep.jmp");

add_databar_column(dt, "Awake");
add_databar_column(dt, "Asleep");
add_databar_column(dt, "Dif");
*/