906221_ko-KR

liliconcom

이변량 프로파일러 기억 설정 동적 용어 값 변수

안녕하세요 여러분,

스크립팅에 대한 도움을 주시면 정말 감사하겠습니다.

영어: 열 대화 상자에서 두 개의 열을 가져오는 이변량 적합 스크립트를 작업 중입니다. 일부 기억된 설정이 이미 로드된 프로파일러를 로드하려고 합니다. 제가 겪고 있는 문제는 프로파일러의 용어 값 내에서 열 이름을 참조/대체하는 올바른 방법을 찾을 수 없다는 것입니다. 아래 예제 코드에서 열에 대한 하드코딩된 참조를 그대로 두었고 스크립트는 작동하지만 스크립트가 다른 열 이름에 유연해야 합니다. 비슷한 문제가 있는 사용자를 찾았지만 그들에게 효과가 있었던 솔루션을 내 예제에 적용하는 데 실패했습니다. Profiler: 용어 값 스크립트에서 변수 사용이 작동하지 않음을 참조하세요. 지금까지 표현식을 작성하고 용어를 대체하는 경험은 수식 열로 제한되어 있었기 때문에 이 문제는 저에게는 약간 과했습니다.

이 문제를 해결하는 데 도움을 주시면 정말 감사하겠습니다.

감사합니다,

카탈

New Table( "Example",
	Add Rows( 10 ),
	New Column( "X",
		Numeric,
		"Continuous",
		Format( "Best", 15 ),
		Set Values( [20, 40, 60, 80, 100, 120, 140, 160, 180, 200] )
	),
	New Column( "Y",
		Numeric,
		"Continuous",
		Format( "Best", 15 ),
		Set Values( [1, 2, 3, 4, 5, 6, 7, 8, 9, 10] )
	)
); 

// Open dialog to select columns
dlg = Column Dialog(
    colX = Col List( "X",
        Min Col( 1 ), 
        Max Col( 1 ),
    ),
    colY = Col List( "Y",
        Min Col( 1 ), 
        Max Col( 1 ),
    ),
);

// Store list of selected columns
Eval List( Remove( dlg, -1 ) );

// Launch platform: Bivariate
report = Bivariate( 
	Y( colY[1] ) , 
	X( colX[1] ), 
		Fit Polynomial(	1,
		{Profiler(
			1,
			Confidence Intervals( 1 ),	
			Term Value( "X"n( 30, Lock( 0 ), Show( 1 ) ) ), // Need to replace with dynamic reference
			Remember Settings( "1-Month", Differences Report( 0 ) ),
			Term Value( "X"n( 60, Lock( 0 ), Show( 1 ) ) ), // Need to replace with dynamic reference
			Remember Settings( "2-Months" ),
			Term Value( "X"n( 90, Lock( 0 ), Show( 1 ) ) ), // Need to replace with dynamic reference
			Remember Settings( "3-Months", Differences Report( 1 ) ),
			Term Value( "X"n( 90, Lock( 0 ), Show( 1 ) ) ) // Need to replace with dynamic reference
		)}
	)
);

자동화 및 스크립팅Re: 이변량 프로파일러 기억 설정 동적 용어 값 변수

이런 식으로 하면 될 것 같아요

Names Default To Here(1);

dt = New Table("Example",
	Add Rows(10),
	New Column("X",
		Numeric,
		"Continuous",
		Format("Best", 15),
		Set Values([20, 40, 60, 80, 100, 120, 140, 160, 180, 200])
	),
	New Column("Y",
		Numeric,
		"Continuous",
		Format("Best", 15),
		Set Values([1, 2, 3, 4, 5, 6, 7, 8, 9, 10])
	)
); 

dlg = Column Dialog(
	colX = Col List("X", Min Col(1), Max Col(1), ),
	colY = Col List("Y", Min Col(1), Max Col(1), ),

);
Eval List(Remove(dlg, -1));

report = Eval(Substitute(
	Expr(dt << Bivariate(
		Y(colY[1]),
		X(colX[1]),
		Fit Polynomial(
			1,
			{Profiler(
				1,
				Confidence Intervals(1),
				Term Value(_x_(30, Lock(0), Show(1))),
				Remember Settings("1-Month", Differences Report(0)),
				Term Value(_x_(60, Lock(0), Show(1))),
				Remember Settings("2-Months"),
				Term Value(_x_(90, Lock(0), Show(1))),
				Remember Settings("3-Months", Differences Report(1)),
				Term Value(_x_(90, Lock(0), Show(1)))
			)}
		)
	)),
	Expr(_x_), Name Expr(AsColumn(dt, colX[1]));
));

Re: 이변량 프로파일러 기억 설정 동적 용어 값 변수

완벽하게 작동합니다. 고맙습니다 , Jarmo!