906221_it-IT

liliconcom

Impostazioni memorizzate del profiler bivariato Variabili di valore del termine dinamico

Ciao a tutti,

Apprezzerei molto un aiuto con la scrittura di alcuni script.

Sto lavorando a uno script di adattamento bivariato che prende due colonne da una finestra di dialogo delle colonne. Voglio caricare un profiler che abbia già alcune impostazioni memorizzate. Il problema che ho è che non riesco a trovare il modo giusto per fare riferimento/sostituire il nome della colonna all'interno del valore del termine del profiler. Nel codice di esempio seguente ho lasciato i riferimenti hardcoded alla colonna e lo script funziona, ma ho bisogno che lo script sia flessibile con nomi di colonna diversi. Ho trovato un utente con un problema simile, ma non sono riuscito ad adattare la soluzione che ha funzionato per lui al mio esempio, vedi Profiler: l'utilizzo di variabili nello script del valore del termine non funziona . La mia esperienza finora con la scrittura di espressioni e la sostituzione dei termini è stata limitata alle colonne formula, quindi questo problema è stato un po' eccessivo per me.

Ogni aiuto per correggere questo problema sarà molto apprezzato.

Cordiali saluti,

Cathal

New Table( "Example",
	Add Rows( 10 ),
	New Column( "X",
		Numeric,
		"Continuous",
		Format( "Best", 15 ),
		Set Values( [20, 40, 60, 80, 100, 120, 140, 160, 180, 200] )
	),
	New Column( "Y",
		Numeric,
		"Continuous",
		Format( "Best", 15 ),
		Set Values( [1, 2, 3, 4, 5, 6, 7, 8, 9, 10] )
	)
); 

// Open dialog to select columns
dlg = Column Dialog(
    colX = Col List( "X",
        Min Col( 1 ), 
        Max Col( 1 ),
    ),
    colY = Col List( "Y",
        Min Col( 1 ), 
        Max Col( 1 ),
    ),
);

// Store list of selected columns
Eval List( Remove( dlg, -1 ) );

// Launch platform: Bivariate
report = Bivariate( 
	Y( colY[1] ) , 
	X( colX[1] ), 
		Fit Polynomial(	1,
		{Profiler(
			1,
			Confidence Intervals( 1 ),	
			Term Value( "X"n( 30, Lock( 0 ), Show( 1 ) ) ), // Need to replace with dynamic reference
			Remember Settings( "1-Month", Differences Report( 0 ) ),
			Term Value( "X"n( 60, Lock( 0 ), Show( 1 ) ) ), // Need to replace with dynamic reference
			Remember Settings( "2-Months" ),
			Term Value( "X"n( 90, Lock( 0 ), Show( 1 ) ) ), // Need to replace with dynamic reference
			Remember Settings( "3-Months", Differences Report( 1 ) ),
			Term Value( "X"n( 90, Lock( 0 ), Show( 1 ) ) ) // Need to replace with dynamic reference
		)}
	)
);

Automazione e scriptingRe: Impostazioni memorizzate del profiler bivariato Variabili di valore del termine dinamico

Penso che qualcosa del genere potrebbe funzionare

Names Default To Here(1);

dt = New Table("Example",
	Add Rows(10),
	New Column("X",
		Numeric,
		"Continuous",
		Format("Best", 15),
		Set Values([20, 40, 60, 80, 100, 120, 140, 160, 180, 200])
	),
	New Column("Y",
		Numeric,
		"Continuous",
		Format("Best", 15),
		Set Values([1, 2, 3, 4, 5, 6, 7, 8, 9, 10])
	)
); 

dlg = Column Dialog(
	colX = Col List("X", Min Col(1), Max Col(1), ),
	colY = Col List("Y", Min Col(1), Max Col(1), ),

);
Eval List(Remove(dlg, -1));

report = Eval(Substitute(
	Expr(dt << Bivariate(
		Y(colY[1]),
		X(colX[1]),
		Fit Polynomial(
			1,
			{Profiler(
				1,
				Confidence Intervals(1),
				Term Value(_x_(30, Lock(0), Show(1))),
				Remember Settings("1-Month", Differences Report(0)),
				Term Value(_x_(60, Lock(0), Show(1))),
				Remember Settings("2-Months"),
				Term Value(_x_(90, Lock(0), Show(1))),
				Remember Settings("3-Months", Differences Report(1)),
				Term Value(_x_(90, Lock(0), Show(1)))
			)}
		)
	)),
	Expr(_x_), Name Expr(AsColumn(dt, colX[1]));
));

Re: Impostazioni memorizzate del profiler bivariato Variabili di valore del termine dinamico

Funziona perfettamente. Grazie Jarmo!