906221_de-DE

liliconcom

Bivariate Profiler Gespeicherte Einstellungen Dynamische Termwertvariablen

Hallo zusammen,

Ich wäre für Hilfe beim Skripting sehr dankbar.

Ich arbeite an einem Skript zur bivariaten Anpassung, das zwei Spalten aus einem Spaltendialog übernimmt. Ich möchte einen Profiler laden, der bereits einige gespeicherte Einstellungen geladen hat. Mein Problem ist, dass ich nicht die richtige Möglichkeit finde, den Spaltennamen innerhalb des Termwerts des Profilers zu referenzieren/ersetzen. Im Beispielcode unten habe ich die fest codierten Referenzen auf die Spalte belassen und das Skript funktioniert, aber das Skript muss flexibel mit verschiedenen Spaltennamen umgehen können. Ich habe einen Benutzer mit einem ähnlichen Problem gefunden, aber es ist mir nicht gelungen, die Lösung, die bei ihm funktioniert hat, auf mein Beispiel zu übertragen, siehe Profiler: Verwenden von Variablen im Termwertskript funktioniert nicht . Meine bisherigen Erfahrungen mit dem Schreiben von Ausdrücken und dem Ersetzen von Termen beschränken sich auf Formelspalten, daher war dieses Problem für mich etwas zu viel.

Für jede Hilfe bei der Behebung dieses Problems wäre ich sehr dankbar.

Mit freundlichen Grüße,

Cathal

New Table( "Example",
	Add Rows( 10 ),
	New Column( "X",
		Numeric,
		"Continuous",
		Format( "Best", 15 ),
		Set Values( [20, 40, 60, 80, 100, 120, 140, 160, 180, 200] )
	),
	New Column( "Y",
		Numeric,
		"Continuous",
		Format( "Best", 15 ),
		Set Values( [1, 2, 3, 4, 5, 6, 7, 8, 9, 10] )
	)
); 

// Open dialog to select columns
dlg = Column Dialog(
    colX = Col List( "X",
        Min Col( 1 ), 
        Max Col( 1 ),
    ),
    colY = Col List( "Y",
        Min Col( 1 ), 
        Max Col( 1 ),
    ),
);

// Store list of selected columns
Eval List( Remove( dlg, -1 ) );

// Launch platform: Bivariate
report = Bivariate( 
	Y( colY[1] ) , 
	X( colX[1] ), 
		Fit Polynomial(	1,
		{Profiler(
			1,
			Confidence Intervals( 1 ),	
			Term Value( "X"n( 30, Lock( 0 ), Show( 1 ) ) ), // Need to replace with dynamic reference
			Remember Settings( "1-Month", Differences Report( 0 ) ),
			Term Value( "X"n( 60, Lock( 0 ), Show( 1 ) ) ), // Need to replace with dynamic reference
			Remember Settings( "2-Months" ),
			Term Value( "X"n( 90, Lock( 0 ), Show( 1 ) ) ), // Need to replace with dynamic reference
			Remember Settings( "3-Months", Differences Report( 1 ) ),
			Term Value( "X"n( 90, Lock( 0 ), Show( 1 ) ) ) // Need to replace with dynamic reference
		)}
	)
);

Automatisierung und SkriptingBetreff: Bivariate Profiler – Gespeicherte Einstellungen – Dynamische Termwertvariablen

Ich denke, so etwas könnte funktionieren

Names Default To Here(1);

dt = New Table("Example",
	Add Rows(10),
	New Column("X",
		Numeric,
		"Continuous",
		Format("Best", 15),
		Set Values([20, 40, 60, 80, 100, 120, 140, 160, 180, 200])
	),
	New Column("Y",
		Numeric,
		"Continuous",
		Format("Best", 15),
		Set Values([1, 2, 3, 4, 5, 6, 7, 8, 9, 10])
	)
); 

dlg = Column Dialog(
	colX = Col List("X", Min Col(1), Max Col(1), ),
	colY = Col List("Y", Min Col(1), Max Col(1), ),

);
Eval List(Remove(dlg, -1));

report = Eval(Substitute(
	Expr(dt << Bivariate(
		Y(colY[1]),
		X(colX[1]),
		Fit Polynomial(
			1,
			{Profiler(
				1,
				Confidence Intervals(1),
				Term Value(_x_(30, Lock(0), Show(1))),
				Remember Settings("1-Month", Differences Report(0)),
				Term Value(_x_(60, Lock(0), Show(1))),
				Remember Settings("2-Months"),
				Term Value(_x_(90, Lock(0), Show(1))),
				Remember Settings("3-Months", Differences Report(1)),
				Term Value(_x_(90, Lock(0), Show(1)))
			)}
		)
	)),
	Expr(_x_), Name Expr(AsColumn(dt, colX[1]));
));

Betreff: Bivariate Profiler – Gespeicherte Einstellungen – Dynamische Termwertvariablen

Das funktioniert perfekt. Danke , Jarmo!